Puppet Class: icinga2::feature::idopgsql

Defined in:
manifests/feature/idopgsql.pp

Overview

== Class: icinga2::feature::idopgsql

This module configures the Icinga 2 feature ido-pgsql.

=== Parameters

[*ensure*] Set to present enables the feature ido-pgsql, absent disables it. Defaults to present.

[*host*] PostgreSQL database host address. Defaults to 'localhost'.

[*port*] PostgreSQL database port. Defaults to '5432'.

[*user*] PostgreSQL database user with read/write permission to the icinga database. Defaults to 'icinga'.

[*password*] PostgreSQL database user's password.

[*database*] PostgreSQL database name. Defaults to 'icinga'.

[*table_prefix*] PostgreSQL database table prefix. Icinga defaults to "icinga_".

[*instance_name*] Unique identifier for the local Icinga 2 instance. Icinga defaults to "default".

[*instance_description*] Description of the Icinga 2 instance.

[*enable_ha*] Enable the high availability functionality. Only valid in a cluster setup. Icinga defaults to 'true'.

[*failover_timeout*] Set the failover timeout in a HA cluster. Must not be lower than 60s. Icinga defaults to '60s'.

[*cleanup*] Hash with items for historical table cleanup.

[*categories*] Array of information types that should be written to the database.

[*import_schema*] Whether to import the PostgreSQL schema or not. Defaults to 'false'.

=== Examples

The ido-pgsql featue requires an existing database and a user with permissions. To install a database server, create databases and manage user permissions we recommend the puppetlabs-postgresql module. Here's an example how you create a PostgreSQL database with the corresponding user with permissions by usng the puppetlabs-postgresql module:

include icinga2 include postgresql::server

postgresql::server::db { 'icinga2': user => 'icinga2', password => postgresql_password('icinga2', 'supersecret'), }

class{ 'icinga2::feature::idopgsql': user => "icinga2", password => "supersecret", database => "icinga2", import_schema => true, require => Postgresql::Server::Db['icinga2'] }

Parameters:

  • password (String)
  • ensure (Enum['absent', 'present']) (defaults to: present)
  • host (Stdlib::Host) (defaults to: 'localhost')
  • port (Stdlib::Port::Unprivileged) (defaults to: 5432)
  • user (String) (defaults to: 'icinga')
  • database (String) (defaults to: 'icinga')
  • table_prefix (Optional[String]) (defaults to: undef)
  • instance_name (Optional[String]) (defaults to: undef)
  • instance_description (Optional[String]) (defaults to: undef)
  • enable_ha (Optional[Boolean]) (defaults to: undef)
  • failover_timeout (Optional[Icinga2::Interval]) (defaults to: undef)
  • cleanup (Optional[Hash]) (defaults to: undef)
  • categories (Optional[Array]) (defaults to: undef)
  • import_schema (Boolean) (defaults to: false)


74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
# File 'manifests/feature/idopgsql.pp', line 74

class icinga2::feature::idopgsql(
  String                         $password,
  Enum['absent', 'present']      $ensure               = present,
  Stdlib::Host                   $host                 = 'localhost',
  Stdlib::Port::Unprivileged     $port                 = 5432,
  String                         $user                 = 'icinga',
  String                         $database             = 'icinga',
  Optional[String]               $table_prefix         = undef,
  Optional[String]               $instance_name        = undef,
  Optional[String]               $instance_description = undef,
  Optional[Boolean]              $enable_ha            = undef,
  Optional[Icinga2::Interval]    $failover_timeout     = undef,
  Optional[Hash]                 $cleanup              = undef,
  Optional[Array]                $categories           = undef,
  Boolean                        $import_schema        = false,
) {

  if ! defined(Class['::icinga2']) {
    fail('You must include the icinga2 base class before using any icinga2 feature class!')
  }

  $conf_dir               = $::icinga2::globals::conf_dir
  $ido_pgsql_package_name = $::icinga2::globals::ido_pgsql_package_name
  $ido_pgsql_schema       = $::icinga2::globals::ido_pgsql_schema
  $manage_package         = $::icinga2::manage_package
  $_notify                = $ensure ? {
    'present' => Class['::icinga2::service'],
    default   => undef,
  }

  $attrs = {
    host                  => $host,
    port                  => $port,
    user                  => $user,
    password              => $password,
    database              => $database,
    table_prefix          => $table_prefix,
    instance_name         => $instance_name,
    instance_description  => $instance_description,
    enable_ha             => $enable_ha,
    failover_timeout      => $failover_timeout,
    cleanup               => $cleanup,
    categories            => $categories,
  }

  # install additional package
  if $ido_pgsql_package_name and $manage_package {
    if $::osfamily == 'debian' {
      ensure_resources('file', { '/etc/dbconfig-common' => { ensure => directory } })
      file { "/etc/dbconfig-common/${ido_pgsql_package_name}.conf":
        ensure  => file,
        content => "dbc_install='false'\ndbc_upgrade='false'\ndbc_remove='false'\n",
        mode    => '0600',
        before  => Package[$ido_pgsql_package_name],
      }
    } # Debian

    package { $ido_pgsql_package_name:
      ensure => installed,
      before => Icinga2::Feature['ido-pgsql'],
    }
  }

  # import db schema
  if $import_schema {
    if $ido_pgsql_package_name and $manage_package {
      Package[$ido_pgsql_package_name] -> Exec['idopgsql-import-schema']
    }
    exec { 'idopgsql-import-schema':
      user        => 'root',
      path        => $::path,
      environment => ["PGPASSWORD=${password}"],
      command     => "psql -h '${host}' -U '${user}' -p '${port}' -d '${database}' -w -f \"${ido_pgsql_schema}\"",
      unless      => "psql -h '${host}' -U '${user}' -p '${port}' -d '${database}' -w -c 'select version from icinga_dbversion'",
    }
  }

  # create object
  icinga2::object { 'icinga2::object::IdoPgsqlConnection::ido-pgsql':
    object_name => 'ido-pgsql',
    object_type => 'IdoPgsqlConnection',
    attrs       => delete_undef_values($attrs),
    attrs_list  => keys($attrs),
    target      => "${conf_dir}/features-available/ido-pgsql.conf",
    order       => 10,
    notify      => $_notify,
  }

  # import library
  concat::fragment { 'icinga2::feature::ido-pgsql':
    target  => "${conf_dir}/features-available/ido-pgsql.conf",
    content => "library \"db_ido_pgsql\"\n\n",
    order   => '05',
  }

  icinga2::feature { 'ido-pgsql':
    ensure  => $ensure,
  }
}