Puppet Class: kafka::mirror::service

Defined in:
manifests/mirror/service.pp

Summary

This class handles the Kafka (mirror) service.

Overview

Parameters:

  • manage_service (Boolean) (defaults to: $kafka::mirror::manage_service)
  • service_ensure (Enum['running', 'stopped']) (defaults to: $kafka::mirror::service_ensure)
  • service_name (String[1]) (defaults to: $kafka::mirror::service_name)
  • user_name (String[1]) (defaults to: $kafka::mirror::user_name)
  • group_name (String[1]) (defaults to: $kafka::mirror::group_name)
  • config_dir (Stdlib::Absolutepath) (defaults to: $kafka::mirror::config_dir)
  • log_dir (Stdlib::Absolutepath) (defaults to: $kafka::mirror::log_dir)
  • bin_dir (Stdlib::Absolutepath) (defaults to: $kafka::mirror::bin_dir)
  • service_requires (Array[String[1]]) (defaults to: $kafka::mirror::service_requires)
  • limit_nofile (Optional[String[1]]) (defaults to: $kafka::mirror::limit_nofile)
  • limit_core (Optional[String[1]]) (defaults to: $kafka::mirror::limit_core)
  • env (Hash) (defaults to: $kafka::mirror::env)
  • consumer_config (Hash[String[1],String[1]]) (defaults to: $kafka::mirror::consumer_config)
  • producer_config (Hash[String[1],String[1]]) (defaults to: $kafka::mirror::producer_config)
  • service_config (Hash[String[1],String[1]]) (defaults to: $kafka::mirror::service_config)
  • heap_opts (String[1]) (defaults to: $kafka::mirror::heap_opts)
  • jmx_opts (String[1]) (defaults to: $kafka::mirror::jmx_opts)
  • log4j_opts (String[1]) (defaults to: $kafka::mirror::log4j_opts) 


6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
 
# File 'manifests/mirror/service.pp', line 6

class kafka::mirror::service (
  Boolean $manage_service                    = $kafka::mirror::manage_service,
  Enum['running', 'stopped'] $service_ensure = $kafka::mirror::service_ensure,
  String[1] $service_name                    = $kafka::mirror::service_name,
  String[1] $user_name                       = $kafka::mirror::user_name,
  String[1] $group_name                      = $kafka::mirror::group_name,
  Stdlib::Absolutepath $config_dir           = $kafka::mirror::config_dir,
  Stdlib::Absolutepath $log_dir              = $kafka::mirror::log_dir,
  Stdlib::Absolutepath $bin_dir              = $kafka::mirror::bin_dir,
  Array[String[1]] $service_requires         = $kafka::mirror::service_requires,
  Optional[String[1]] $limit_nofile          = $kafka::mirror::limit_nofile,
  Optional[String[1]] $limit_core            = $kafka::mirror::limit_core,
  Hash $env                                  = $kafka::mirror::env,
  Hash[String[1],String[1]] $consumer_config = $kafka::mirror::consumer_config,
  Hash[String[1],String[1]] $producer_config = $kafka::mirror::producer_config,
  Hash[String[1],String[1]] $service_config  = $kafka::mirror::service_config,
  String[1] $heap_opts                       = $kafka::mirror::heap_opts,
  String[1] $jmx_opts                        = $kafka::mirror::jmx_opts,
  String[1] $log4j_opts                      = $kafka::mirror::log4j_opts,
) {
  assert_private()

  if $manage_service {
    $env_defaults = {
      'KAFKA_HEAP_OPTS'  => $heap_opts,
      'KAFKA_JMX_OPTS'   => $jmx_opts,
      'KAFKA_LOG4J_OPTS' => $log4j_opts,
    }
    $environment = deep_merge($env_defaults, $env)

    if $facts['service_provider'] == 'systemd' {
      include systemd

      file { "/etc/systemd/system/${service_name}.service":
        ensure  => file,
        mode    => '0644',
        content => template('kafka/unit.erb'),
      }

      file { "/etc/init.d/${service_name}":
        ensure => absent,
      }

      File["/etc/systemd/system/${service_name}.service"]
      ~> Service[$service_name]
    } else {
      file { "/etc/init.d/${service_name}":
        ensure  => file,
        mode    => '0755',
        content => template('kafka/init.erb'),
        before  => Service[$service_name],
      }
    }

    service { $service_name:
      ensure     => $service_ensure,
      enable     => true,
      hasstatus  => true,
      hasrestart => true,
    }
  }
}