Defined Type: dispatcher::farm
- Defined in:
- manifests/farm.pp
Summary
Installs and configures an AEM Dispatcher farm instance on your system.Overview
This will configure an AEM Dispatcher Farm instance on the node. Farms require a minimum set of configuation details to properly function. These are the ‘renderers`, `filters`, and `cache`. The remainder of the paramers have provided, reasonable defaults.
153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 |
# File 'manifests/farm.pp', line 153
define dispatcher::farm (
Array[Dispatcher::Farm::Renderer] $renderers = lookup("dispatcher::farm::${name}::renderers", Array[Dispatcher::Farm::Renderer], 'deep'),
Array[Dispatcher::Farm::Filter] $filters = lookup("dispatcher::farm::${name}::filters", Array[Dispatcher::Farm::Filter], 'deep'),
Dispatcher::Farm::Cache $cache = lookup("dispatcher::farm::${name}::cache", Dispatcher::Farm::Cache, 'deep'),
Enum['absent', 'present'] $ensure = lookup("dispatcher::farm::${name}::ensure", Enum['absent', 'present'], 'first', 'present'),
Integer[0] $priority = lookup("dispatcher::farm::${name}::priority", Integer[0], 'first', 0),
Array[String] $virtualhosts = lookup("dispatcher::farm::${name}::virtualhosts", Array[String], 'deep', [$name]),
Array[String] $clientheaders = lookup("dispatcher::farm::${name}::clientheaders", Array[String], 'deep', []),
Optional[Dispatcher::Farm::SessionManagement]
$sessionmanagement = lookup("dispatcher::farm::${name}::sessionmanagement", Optional[Dispatcher::Farm::SessionManagement], 'first', undef),
Optional[Dispatcher::Farm::VanityUrls] $vanity_urls = lookup("dispatcher::farm::${name}::vanity_urls", Optional[Dispatcher::Farm::VanityUrls], 'first', undef),
Boolean $propagate_synd_post = lookup("dispatcher::farm::${name}::propagate_synd_post", Boolean, 'first', false),
Optional[Dispatcher::Farm::AuthChecker] $auth_checker = lookup("dispatcher::farm::${name}::auth_checker", Optional[Dispatcher::Farm::AuthChecker], 'deep', undef),
Optional[Array[Dispatcher::Farm::StatisticsCategory]]
$statistics_categories = lookup("dispatcher::farm::${name}::statistics_categories", Optional[Array[Dispatcher::Farm::StatisticsCategory]], 'deep', undef),
Optional[Dispatcher::Farm::StickyConnection]
$sticky_connections = lookup("dispatcher::farm::${name}::sticky_connections", Optional[Dispatcher::Farm::StickyConnection], 'deep', undef),
Optional[String[1]] $health_check = lookup("dispatcher::farm::${name}::health_check", Optional[String[1]], 'first', undef),
Optional[Integer[0]] $retry_delay = lookup("dispatcher::farm::${name}::retry_delay", Optional[Integer[0]], 'first', undef),
Optional[Integer[0]] $number_of_retries = lookup("dispatcher::farm::${name}::number_of_retries", Optional[Integer[0]], 'first', undef),
Optional[Integer[0]] $unavailable_penalty = lookup("dispatcher::farm::${name}::unavailable_penalty", Optional[Integer[0]], 'first', undef),
Boolean $failover = lookup("dispatcher::farm::${name}::failover", Boolean, 'first', false),
Boolean $secure = lookup("dispatcher::farm::${name}::secure", Boolean, 'first', false),
) {
# Check for Apache because it is used by parameter defaults
if !defined(Class['apache']) {
fail('You must include the Apache class before using any dispatcher class or resources.')
}
if $::osfamily == 'RedHat' or $::operatingsystem =~ /^[Aa]mazon$/ {
$_farm_path = $::apache::mod_dir
} elsif $::osfamily == 'Debian' {
$_farm_path = $::apache::mod_enable_dir
} else {
fail("Class['dispatcher']: Unsupported osfamily: ${::osfamily}")
}
if $priority < 10 {
$_priority = "0${priority}"
}
else {
$_priority = $priority
}
if ($cache['manage_docroot']) {
file { $cache['docroot'] :
owner => 'root',
group => $::apache::params::root_group,
}
if $facts['selinux_enforced'] {
File[$cache['docroot']] {
seltype => 'httpd_sys_rw_content_t',
}
}
}
if ($secure) {
$_secure_cache = lookup('dispatcher::farm::cache::secured', Hash, 'deep', {})
$_cache_tmp = {
'allowed_clients' => $cache['allowed_clients'] + $_secure_cache['allowed_clients']
}
$_cache = deep_merge($cache, $_cache_tmp)
$_secure_filters = lookup('dispatcher::farm::filters::secured', Array, 'deep', [])
$_filters = $_secure_filters + $filters
} else {
$_cache = $cache
$_filters = $filters
}
concat { "dispatcher.${_priority}-${name}.inc.any":
ensure => $ensure,
path => "${_farm_path}/dispatcher.${_priority}-${name}.inc.any",
owner => 'root',
group => $::apache::params::root_group,
mode => $::apache::params::file_mode,
order => 'numeric',
ensure_newline => true,
require => Package['httpd'],
notify => Class['apache::service'],
}
concat::fragment { "${name}-farm-header":
target => "dispatcher.${_priority}-${name}.inc.any",
order => 0,
content => template('dispatcher/farm/_file_header.erb')
}
if ($clientheaders.size > 0) {
concat::fragment { "${name}-farm-clientheaders":
target => "dispatcher.${_priority}-${name}.inc.any",
order => 10,
content => template('dispatcher/farm/_clientheaders.erb')
}
}
concat::fragment { "${name}-farm-virtualhosts":
target => "dispatcher.${_priority}-${name}.inc.any",
order => 20,
content => template('dispatcher/farm/_virtualhosts.erb')
}
if ($sessionmanagement) {
concat::fragment { "${name}-farm-sessionmanagement":
target => "dispatcher.${_priority}-${name}.inc.any",
order => 30,
content => template('dispatcher/farm/_sessionmanagement.erb')
}
}
concat::fragment { "${name}-farm-renders":
target => "dispatcher.${_priority}-${name}.inc.any",
order => 40,
content => template('dispatcher/farm/_renders.erb')
}
concat::fragment { "${name}-farm-filter":
target => "dispatcher.${_priority}-${name}.inc.any",
order => 50,
content => template('dispatcher/farm/_filter.erb')
}
if ($vanity_urls) {
concat::fragment { "${name}-farm-vanityurls":
target => "dispatcher.${_priority}-${name}.inc.any",
order => 60,
content => template('dispatcher/farm/_vanityurls.erb')
}
}
if ($propagate_synd_post) {
concat::fragment { "${name}-farm-propagatesyndpost":
target => "dispatcher.${_priority}-${name}.inc.any",
order => 70,
content => ' /propagateSyndPost "1"'
}
}
concat::fragment { "${name}-farm-cache":
target => "dispatcher.${_priority}-${name}.inc.any",
order => 80,
content => template('dispatcher/farm/_cache.erb')
}
if ($auth_checker) {
concat::fragment { "${name}-farm-authchecker":
target => "dispatcher.${_priority}-${name}.inc.any",
order => 90,
content => template('dispatcher/farm/_authchecker.erb')
}
}
if ($statistics_categories) {
concat::fragment { "${name}-farm-statisticscategories":
target => "dispatcher.${_priority}-${name}.inc.any",
order => 100,
content => template('dispatcher/farm/_statisticscategories.erb')
}
}
if ($sticky_connections) {
concat::fragment { "${name}-farm-stickyconnections":
target => "dispatcher.${_priority}-${name}.inc.any",
order => 110,
content => template('dispatcher/farm/_stickyconnections.erb')
}
}
if ($health_check) {
concat::fragment { "${name}-farm-healthcheck":
target => "dispatcher.${_priority}-${name}.inc.any",
order => 120,
content => " /health_check \"${health_check}\""
}
}
if ($retry_delay) {
concat::fragment { "${name}-farm-retrydelay":
target => "dispatcher.${_priority}-${name}.inc.any",
order => 130,
content => " /retryDelay \"${retry_delay}\""
}
}
if ($number_of_retries) {
concat::fragment { "${name}-farm-numberofretries":
target => "dispatcher.${_priority}-${name}.inc.any",
order => 140,
content => " /numberOfRetries \"${number_of_retries}\""
}
}
if ($unavailable_penalty) {
concat::fragment { "${name}-farm-unavailablepenalty":
target => "dispatcher.${_priority}-${name}.inc.any",
order => 150,
content => " /unavailablePenalty \"${unavailable_penalty}\""
}
}
if ($failover) {
concat::fragment { "${name}-farm-failover":
target => "dispatcher.${_priority}-${name}.inc.any",
order => 160,
content => ' /failover "1"'
}
}
concat::fragment { "${name}-farm-footer":
target => "dispatcher.${_priority}-${name}.inc.any",
order => 999,
content => '}'
}
}
|