Puppet Class: coturn
- Defined in:
- manifests/init.pp
Summary
Install and configure CoturnOverview
Install and configure Coturn
86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 |
# File 'manifests/init.pp', line 86
class coturn (
Stdlib::Fqdn $realm = $facts['networking']['fqdn'],
Array[Stdlib::IP::Address] $listening_ips = [],
Stdlib::Port $listening_port = 3478,
Stdlib::Port $tls_listening_port = 5349,
Optional[Stdlib::Absolutepath] $cert = undef,
Optional[Stdlib::Absolutepath] $private_key = undef,
Boolean $fingerprint = false,
Boolean $lt_cred_mech = false, # Only on Coturn below v4.5.0.8
Boolean $use_auth_secret = false,
Optional[String[1]] $static_auth_secret = undef,
Integer[0] $total_quota = 0,
Integer[0] $bps_capacity = 0,
Integer[0] $stale_nonce = 600,
Boolean $no_stdout_log = false,
Boolean $no_loopback_peers = false, # Only on Coturn below v4.5.1.0!
Boolean $no_multicast_peers = false,
Boolean $dh2066 = true,
Boolean $tlsv1 = false,
Boolean $tlsv1_1 = false,
Boolean $tlsv1_2 = true,
String[1] $proc_user = 'turnserver',
String[1] $proc_group = 'turnserver',
Boolean $simple_log = true,
Optional[Variant[Stdlib::Absolutepath,Enum['syslog','stdout']]] $log_file = '/var/log/coturn/turnserver.log',
String[1] $cipher_list = 'ECDH+AESGCM:ECDH+CHACHA20:DH+AESGCM:ECDH+AES256:DH+AES256:ECDH+AES128:DH+AES:RSA+AESGCM:RSA+AES:!aNULL:!MD5:!DSS',
) {
$_coturn_package = 'coturn' # Ubuntu 18.04 ==> Coturn v4.5.0.7
$_coturn_config = '/etc/turnserver.conf'
$_coturn_sqlitedbpath = '/var/lib/turn'
if ( $cert and ! $private_key ) or ( ! $cert and $private_key ) {
fail('With TLS a certificate and a private key are both required.')
}
package { $_coturn_package:
ensure => present,
}
# Config file
file { $_coturn_config :
ensure => file,
mode => '0600',
owner => $proc_user,
group => $proc_group,
content => epp('coturn/turnserver.conf.epp'),
require => Package[$_coturn_package],
notify => Service['coturn'],
}
# SYS-V init scripts are yet shiped with deb package
file { ['/etc/default/coturn', '/etc/init.d/coturn']:
ensure => absent,
}
# By default users are stored in sqlite database
# the turnserver must access to database file
file { $_coturn_sqlitedbpath:
ensure => directory,
mode => '0700',
owner => $proc_user,
group => $proc_group,
}
-> file { "${_coturn_sqlitedbpath}/turndb":
ensure => file,
owner => $proc_user,
group => $proc_group,
}
if $facts['os']['release']['major'] == '18.04' {
# No systemd unit shiped at all
systemd::unit_file { 'coturn.service':
content => epp('coturn/coturn.service.ubuntu1804.epp'),
}
Systemd::Unit_file['coturn.service'] ~> Service['coturn']
} else {
# Systemd unit shiped but we need to manage some settings with dropin file
systemd::dropin_file { 'coturn.conf':
unit => 'coturn.service',
content => epp('coturn/coturn_dropin.epp'),
}
Systemd::Dropin_file['coturn.conf'] ~> Service['coturn']
}
if assert_type(Stdlib::Absolutepath, $log_file) {
file { dirname($log_file):
ensure => directory,
mode => '0700',
owner => $proc_user,
group => $proc_group,
}
}
service { 'coturn':
ensure => running,
enable => true,
require => [
Package[$_coturn_package],
File[$_coturn_config],
]
}
}
|