3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
|
# File 'manifests/package/redhat.pp', line 3
class nginx::package::redhat (
Variant[Boolean, Enum['absent']] $sslverify = $nginx::yum_repo_sslverify,
) {
$package_name = $nginx::package_name
$package_source = $nginx::package_source
$package_ensure = $nginx::package_ensure
$package_flavor = $nginx::package_flavor
$passenger_package_ensure = $nginx::passenger_package_ensure
$passenger_package_name = $nginx::passenger_package_name
$manage_repo = $nginx::manage_repo
$purge_passenger_repo = $nginx::purge_passenger_repo
#Install the CentOS-specific packages on that OS, otherwise assume it's a RHEL
#clone and provide the Red Hat-specific package. This comes into play when not
#on RHEL or CentOS and $manage_repo is set manually to 'true'.
$_os = $facts['os']['name'] ? {
'CentOS' => 'centos',
'VirtuozzoLinux' => 'centos',
'OracleLinux' => 'centos',
default => 'rhel'
}
$reload_command = $facts['os']['release']['major'] ? {
'7' => 'yum clean all',
default => 'dnf clean all',
}
if $manage_repo {
exec { 'yum-clean-b114182':
command => $reload_command,
path => '/bin:/usr/bin',
refreshonly => true,
}
case $package_source {
'nginx', 'nginx-stable': {
yumrepo { 'nginx-release':
baseurl => "https://nginx.org/packages/${_os}/${facts['os']['release']['major']}/\$basearch/",
descr => 'nginx repo',
enabled => '1',
gpgcheck => '1',
priority => '1',
gpgkey => 'https://nginx.org/keys/nginx_signing.key',
sslverify => $sslverify,
before => Package['nginx'],
notify => Exec['yum-clean-b114182'],
module_hotfixes => '1',
}
if $purge_passenger_repo {
yumrepo { 'passenger':
ensure => absent,
before => Package['nginx'],
notify => Exec['yum-clean-b114182'],
}
}
}
'nginx-mainline': {
yumrepo { 'nginx-release':
baseurl => "https://nginx.org/packages/mainline/${_os}/${facts['os']['release']['major']}/\$basearch/",
descr => 'nginx repo',
enabled => '1',
gpgcheck => '1',
priority => '1',
gpgkey => 'https://nginx.org/keys/nginx_signing.key',
sslverify => $sslverify,
before => Package['nginx'],
notify => Exec['yum-clean-b114182'],
module_hotfixes => '1',
}
if $purge_passenger_repo {
yumrepo { 'passenger':
ensure => absent,
before => Package['nginx'],
notify => Exec['yum-clean-b114182'],
}
}
}
'passenger': {
# Also note: Since 6.0.5 there are no nginx packages in the phusion EL7 repository, and nginx packages are expected to come from epel instead
yumrepo { 'passenger':
baseurl => "https://oss-binaries.phusionpassenger.com/yum/passenger/el/${facts['os']['release']['major']}/\$basearch",
descr => 'passenger repo',
enabled => '1',
gpgcheck => '0',
repo_gpgcheck => '1',
priority => '1',
gpgkey => 'https://oss-binaries.phusionpassenger.com/auto-software-signing-gpg-key.txt',
before => Package['nginx'],
notify => Exec['yum-clean-b114182'],
module_hotfixes => '1',
}
yumrepo { 'nginx-release':
ensure => absent,
before => Package['nginx'],
notify => Exec['yum-clean-b114182'],
}
package { $passenger_package_name:
ensure => $passenger_package_ensure,
require => Yumrepo['passenger'],
}
}
'openresty': {
$_os_resty = $facts['os']['name'] ? {
'CentOS' => 'centos',
'Rocky' => 'rocky',
default => 'rhel'
}
$repo_gpgkey = $facts['os']['release']['major'] ? {
'9' => 'https://openresty.org/package/pubkey2.gpg',
default => 'https://openresty.org/package/pubkey.gpg',
}
# https://openresty.org/en/linux-packages.html
yumrepo { 'openresty':
baseurl => "https://openresty.org/package/${_os_resty}/\$releasever/\$basearch",
descr => "Official OpenResty Open Source Repository for ${facts['os']['name']}",
skip_if_unavailable => '0',
enabled => '1',
gpgcheck => '1',
repo_gpgcheck => '0',
gpgkey => $repo_gpgkey,
sslverify => $sslverify,
before => Package['nginx'],
notify => Exec['yum-clean-b114182'],
module_hotfixes => '1',
}
if $purge_passenger_repo {
yumrepo { 'passenger':
ensure => absent,
before => Package['nginx'],
notify => Exec['yum-clean-b114182'],
}
}
}
default: {
fail("\$package_source must be 'nginx-stable', 'nginx-mainline', 'openresty' or 'passenger'. It was set to '${package_source}'")
}
}
}
package { 'nginx':
ensure => $package_ensure,
name => $package_name,
}
}
|