Puppet Class: quagga

Defined in:
manifests/init.pp

Summary

Manages common option of quagga services

Overview

Parameters:

  • default_owner (String) —

    Specifies the default owner of quagga files.

  • default_group (String) —

    Specifies the default group of quagga files.

  • default_mode (String) —

    Specifies the default mode of quagga files.

  • default_content (String) —

    Specifies the default content of quagga files.

  • service_file (String) —

    The system configuration file on the filesyustem

  • service_file_manage (Boolean) —

    Enable or disable management of the system configuration file

  • packages (Hash) —

    Specifies which packages will be installed

  • config_dir (Stdlib::AbsolutePath) (defaults to: '/etc/quagga') —

    Directory in which the quagga configuration files reside

  • frr_mode_enable (Boolean) (defaults to: false) —

    Indicates whether this is a quagga or FRRouting based system

  • pim_settings (Quagga::Pim) —

    Hash containing all of the pim daemon configuration directives

  • ospf_settings (Quagga::Ospf) —

    Hash containing all of the ospf daemon configuration directives

  • bgp_settings (Quagga::Bgp) —

    Hash containing all of the bgp daemon configuration directives

  • zebra_settings (Quagga::Zebra) —

    Hash containing all of the zebra daemon configuration directives



29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
 
# File 'manifests/init.pp', line 29

class quagga (
  String $default_owner,
  String $default_group,
  String $default_mode,
  String $default_content,
  String $service_file,
  Boolean $service_file_manage,
  Hash $packages,
  Quagga::Pim $pim_settings,
  Quagga::Ospf $ospf_settings,
  Quagga::Bgp $bgp_settings,
  Quagga::Zebra $zebra_settings,
  Stdlib::AbsolutePath $config_dir = '/etc/quagga',
  Boolean $frr_mode_enable         = false,
) {
  $packages.each |String $package_name, Hash $package| {
    package { $package_name:
      * => $package,
    }
  }

  File {
    owner   => $default_owner,
    group   => $default_group,
    mode    => $default_mode,
    content => $default_content,
    replace => false,
    ensure  => present,
    require => Package[keys($packages)],
  }

  contain quagga::logging

  if $frr_mode_enable {
    $pim_params = $pim_settings + {
      'service_name' => 'frr',
    }
    $ospf_params = $ospf_settings + {
      'service_name' => 'frr',
    }
    $bgp_params = $bgp_settings + {
      'service_name' => 'frr',
    }
    $zebra_params = $zebra_settings + {
      'service_name' => 'frr',
    }
  } else {
    $pim_params = $pim_settings
    $ospf_params = $ospf_settings
    $bgp_params = $bgp_settings
    $zebra_params = $zebra_settings
  }

  # Child class inclusions
  class { 'quagga::pim':
    frr_mode_enable => $frr_mode_enable,
    *               => $pim_params,
  }
  contain quagga::pim
  class { 'quagga::ospf':
    frr_mode_enable => $frr_mode_enable,
    *               => $ospf_params,
  }
  contain quagga::ospf
  class { 'quagga::bgp':
    frr_mode_enable => $frr_mode_enable,
    *               => $bgp_params,
  }
  contain quagga::bgp
  class { 'quagga::zebra':
    frr_mode_enable => $frr_mode_enable,
    *               => $zebra_params,
  }
  contain quagga::zebra

  if $service_file_manage {
    if $frr_mode_enable {
      $frr_daemons_config = {
        'bgpd_enable' => $quagga::bgp::service_enable,
        'ospfd_enable' => $quagga::ospf::service_enable,
        'pimd_enable' => $quagga::pim::service_enable,
      }
      file { "${config_dir}/daemons":
        ensure  => 'file',
        owner   => $default_owner,
        group   => $default_group,
        mode    => '0750',
        replace => true,
        content => epp('quagga/frr.daemons.epp', $frr_daemons_config),
      }
      service { 'frr':
        ensure    => 'running',
        enable    => true,
        subscribe => [
          File["${config_dir}/daemons"],
          Package[keys($quagga::packages)],
        ],
      }
    } else {
      file { $service_file:
        owner   => 'root',
        group   => 'root',
        mode    => '0644',
        replace => true,
        content => epp('quagga/quagga.sysconfig.epp'),
      }
    }
  }
}