Puppet Class: qualys_agent::package

Defined in:
manifests/package.pp

Summary

Manage the Qualys agent's package installation

Overview

Install or uninstall the Qualys agent package



5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
 
# File 'manifests/package.pp', line 5

class qualys_agent::package {

  if $qualys_agent::manage_package {
    # Force package remove if agent ensure is "absent"
    $ensure = $qualys_agent::ensure ? {
      present => $qualys_agent::package_ensure,
      absent  => 'absent',
    }

    package { 'qualys_agent':
      ensure => $ensure,
      name   => $qualys_agent::package_name,
    }
    # Do not create an ordering dependency if we are removing the agent
    $package_dep = $qualys_agent::ensure ? {
      present => Package['qualys_agent'],
      absent  => undef,
    }
  } else {
    $package_dep = undef
  }

  # Fix permissions on all paths used by the agent as the package does not do this on install
  $agent_paths = [
    '/usr/local/qualys',
    '/etc/qualys',
    '/var/spool/qualys',
  ]

  if $qualys_agent::ensure != 'absent' {
    file { $agent_paths :
      ensure  => 'directory',
      group   => $qualys_agent::group,
      owner   => $qualys_agent::owner,
      require => [$package_dep, $qualys_agent::user::user_dep, $qualys_agent::user::group_dep],
      recurse => true,
    }
    file { $qualys_agent::log_file_dir :
      ensure  => 'directory',
      group   => $qualys_agent::log_group_final,
      owner   => $qualys_agent::log_owner_final,
      require => $package_dep,
      recurse => false,
    }
  }
}