Defined Type: aem::service

Defined in:
manifests/service.pp

Overview

Defines: aem::service

Used to create service definitions for AEM instances.

Based on Elastic Search service management.

Parameters:

  • ensure (Any) (defaults to: 'present')
  • group (Any) (defaults to: 'aem')
  • home (Any) (defaults to: undef)
  • status (Any) (defaults to: 'enabled')
  • user (Any) (defaults to: 'aem')
  • service_options (Any) (defaults to: { 'TimeoutStopSec' => '4min', 'KillSignal' => 'SIGCONT', 'PrivateTmp' => true }) 


7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
 
# File 'manifests/service.pp', line 7

define aem::service (
  $ensure           = 'present',
  $group            = 'aem',
  $home             = undef,
  $status           = 'enabled',
  $user             = 'aem',
  $service_options  = { 'TimeoutStopSec' => '4min', 'KillSignal' => 'SIGCONT', 'PrivateTmp' => true }

) {

  if $home == undef {
    fail('Home directory must be specified.')
  }

  validate_absolute_path($home)

  case $::operatingsystem {
    'CentOS', 'Fedora', 'RedHat' : {

      if versioncmp($::operatingsystemmajrelease, '7') >= 0 {
        $provider      = 'systemd'
      } else {
        $provider      = 'init'
      }
    }
    'Amazon' : {
      $provider = 'init'
    }
    'Debian': {

      if versioncmp($::operatingsystemmajrelease, '8') >= 0 {
        $provider      = 'systemd'
      } else {
        $provider      = 'init'
      }
    }
    'Ubuntu': {

      if versioncmp($::operatingsystemmajrelease, '15') >= 0 {
        $provider      = 'systemd'
      } else {
        $provider      = 'init'
      }
    }
    default: {
      fail("'${module_name}' provides no service parameters for '${::operatingsystem}'")
    }
  }

  case $provider {
    'init' : {
      aem::service::init { $name :
        ensure => $ensure,
        status => $status,
        group  => $group,
        home   => $home,
        user   => $user,
      }
    }
    'systemd' : {
      aem::service::systemd { $name :
        ensure          => $ensure,
        status          => $status,
        group           => $group,
        home            => $home,
        user            => $user,
        service_options => $service_options
      }
    }
    default : {
      fail("Unknown service provider: ${provider}")
    }
  }

}