Defined Type: yum::versionlock

Defined in:
manifests/versionlock.pp

Overview

Define: yum::versionlock

This definition locks package from updates.

Parameters:

[*ensure*] - specifies if versionlock should be present, absent or exclude
[*path*]   - configuration of Yum plugin versionlock

Actions:

Requires:

RPM based system, Yum versionlock plugin

Sample usage:

yum::versionlock { '0:bash-4.1.2-9.el6_2.*':
  ensure  => present,
}

Parameters:

  • ensure (Any) (defaults to: present)
  • path (Any) (defaults to: '/etc/yum/pluginconf.d/versionlock.list') 


19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
 
# File 'manifests/versionlock.pp', line 19

define yum::versionlock (
  $ensure = present,
  $path   = '/etc/yum/pluginconf.d/versionlock.list'
) {
  require yum::plugin::versionlock

  if ($name =~ /^[0-9]+:.+\*$/) {
    $_name = $name
  } elsif ($name =~ /^[0-9]+:.+-.+-.+\./) {
    $_name= "${name}*"
  } else {
    fail('Package name must be formated as \'EPOCH:NAME-VERSION-RELEASE.ARCH\'')
  }

  case $ensure {
    present,absent,exclude: {
      if ($ensure == present) or ($ensure == absent) {
        file_line { "versionlock.list-${name}":
          ensure => $ensure,
          line   => $_name,
          path   => $path,
        }
      }

      if ($ensure == exclude) or ($ensure == absent) {
        file_line { "versionlock.list-!${name}":
          ensure => $ensure,
          line   => "!${_name}",
          path   => $path,
        }
      }
    }

    default: {
      fail("Invalid ensure state: ${ensure}")
    }
  }
}