Puppet Class: hbase::common::daemons::config

Defined in:
manifests/common/daemons/config.pp

Overview

Class hbase::common::daemons::config

Configuration needed for all HBase daemons.



5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
 
# File 'manifests/common/daemons/config.pp', line 5

class hbase::common::daemons::config {
  contain hbase::common::keytab

  if "${::osfamily}/${::operatingsystem}" == 'RedHat/Fedora' {
    file { '/etc/security/limits.d/90-hbase.conf':
      owner  => 'root',
      group  => 'root',
      alias  => 'limits.conf',
      source => 'puppet:///modules/hbase/limits.conf',
    }
  }

  if $hbase::features["hbmanager"] {
    $backup_hostnames = $hbase::backup_hostnames
    $rest_hostnames = $hbase::rest_hostnames
    $thrift_hostnames = $hbase::thrift_hostnames
    $slaves = $hbase::slaves
    file { '/usr/local/sbin/hbmanager':
      owner   => 'root',
      group   => 'root',
      mode    => '0755',
      alias   => 'hbmanager',
      content => template('hbase/hbmanager.erb'),
    }
  }

  if $hbase::https {
    file { "${hbase::hbase_homedir}/hadoop.keytab":
      owner  => 'hbase',
      group  => 'hbase',
      mode   => '0600',
      source => '/etc/security/keytab/http.service.keytab',
    }
    file { "${hbase::hbase_homedir}/http-auth-signature-secret":
      owner  => 'hbase',
      group  => 'hbase',
      mode   => '0600',
      source => '/etc/security/http-auth-signature-secret',
    }
    file { "${hbase::hbase_homedir}/keystore.server":
      owner  => 'hbase',
      group  => 'hbase',
      mode   => '0600',
      source => $hbase::https_keystore,
    }

    if $hbase::acl {
      exec { 'setfacl-ssl-hbase':
        command => "setfacl -m u:hbase:r ${hbase::configdir_hadoop}/ssl-server.xml ${hbase::configdir_hadoop}/ssl-client.xml && touch ${hbase::hbase_homedir}/.puppet-ssl-facl",
        path    => '/sbin:/usr/sbin:/bin:/usr/bin',
        creates => "${hbase::hbase_homedir}/.puppet-ssl-facl",
        require => [
          File["${hbase::configdir_hadoop}/ssl-client.xml"],
          File["${hbase::configdir_hadoop}/ssl-server.xml"],
        ],
      }

      # ssl-client.xml and ssl-server.xml
      Class['hadoop::common::config'] -> Exec['setfacl-ssl-hbase']
    }
  }
}