Puppet Class: spark::common::config

Defined in:
manifests/common/config.pp

Overview

Class spark::common::config

Common configuration for Apache Spark.



5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
 
# File 'manifests/common/config.pp', line 5

class spark::common::config {
  include ::stdlib
  if $spark::yarn_enable or $spark::hdfs_hostname {
    contain hadoop::common::config
    contain hadoop::common::hdfs::config
  }

  ensure_packages($spark::packages['common'])

  $hdfs_hostname = $spark::hdfs_hostname
  $historyserver_hostname = $spark::historyserver_hostname
  $master_hostname = $spark::master_hostname
  $master_port = $spark::master_port
  $master_ui_port = $spark::master_ui_port
  $worker_port = $spark::worker_port
  $worker_ui_port = $spark::worker_ui_port
  $jar_enable = $spark::jar_enable
  $yarn_enable = $spark::yarn_enable

  file{"${spark::confdir}/spark-defaults.conf":
    owner   => 'root',
    group   => 'root',
    mode    => '0644',
    content => template('spark/spark-defaults.conf.erb'),
    alias   => 'spark-defaults.conf',
    require => Package[$spark::packages['common']],
  }

  file{"${spark::defaultdir}/spark":
    owner   => 'root',
    group   => 'root',
    mode    => '0644',
    content => template('spark/env.erb'),
    alias   => 'spark-env',
    require => Package[$spark::packages['common']],
  }

  $confdir = $spark::confdir
  $environment = $spark::environment
  augeas{"${confdir}/spark-env.sh":
    lens    => 'Shellvars.lns',
    incl    => "${confdir}/spark-env.sh",
    changes => template('spark/spark-env.sh.augeas.erb'),
  }

}