Puppet Class: examdb

Defined in:
manifests/init.pp

Overview

Class: examdb

Setup exam database instance

Parameters

server_domain

the domain name of the server

Examples

class { 'examdb':
  server_domain => 'exams.example.com' ,
}

Authors

Pan Luo <pan.luo@ubc.ca>

Centre for Teaching, Learning and Technology, University of British Columbia

Parameters:

  • server_domain (Any) (defaults to: undef)
  • appname (Any) (defaults to: 'examdb')
  • appuser (Any) (defaults to: 'app')
  • project_name (Any) (defaults to: 'ubc/examdb')
  • doc_base (Any) (defaults to: '/www_data/app')
  • web_root (Any) (defaults to: 'web')
  • timezone (Any) (defaults to: 'Canada/Pacific')
  • ensure (Any) (defaults to: 'present')
  • host (Any) (defaults to: $fqdn)
  • port (Any) (defaults to: 80)
  • db_host (Any) (defaults to: 'localhost')
  • db_user (Any) (defaults to: 'examdb')
  • db_password (Any) (defaults to: 'examdb')
  • db_name (Any) (defaults to: 'examdb')
  • ssl (Any) (defaults to: false)
  • ssl_cert (Any) (defaults to: undef)
  • ssl_key (Any) (defaults to: undef)
  • ssl_port (Any) (defaults to: 443)
  • github_token (Any) (defaults to: undef)
  • writable_dirs (Any) (defaults to: undef) 


24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
 
# File 'manifests/init.pp', line 24

class examdb (
  $server_domain = undef,
  $appname = 'examdb',
  $appuser = 'app',
  $project_name = 'ubc/examdb',
  $doc_base = '/www_data/app',
  $web_root = 'web',
  $timezone = 'Canada/Pacific',
  $ensure = 'present',
  $host     = $fqdn,
  $port    = 80,
  $db_host = 'localhost',
  $db_user = 'examdb',
  $db_password = 'examdb',
  $db_name = 'examdb',
  $ssl = false,
  $ssl_cert = undef,
  $ssl_key = undef,
  $ssl_port = 443,
  $github_token = undef,
  $writable_dirs = undef,
) {
  include git

  case $::osfamily {
    'RedHat': {
      include epel
      $install_pear = false
      $install_php_dev = false
      case $::operatingsystemrelease {
        /^5.*/,/^6.*/: {
          include ius
          $php_package_prefix = 'php55u-'
          $composer_php_package = 'php55u-cli'
          $php_require = [Package['nginx'], Class['ius']]
          $manage_nodejs_repo = true
          $nodejs_require = [Yumrepo['epel']]
          $php_extensions_base = {
            'opcache' => {
              settings => {
                'OpCache/opcache.enable'        => '1',
                'OpCache/opcache.use_cwd'       => '1',
                'OpCache/opcache.save_comments' => '1',
                'OpCache/opcache.load_comments' => '1',
              }
            },
            'xml'        => {},
            'mcrypt'     => {},
            'pdo'        => {},
            'pecl-mongo' => {},
            'mbstring'   => {},
            'intl'       => {},
            'mysqlnd'    => {},
            'pecl-redis' => {},
          }
        }
        /^7.*/: {
          include epel
          $php_package_prefix = 'php-'
          $composer_php_package = 'php-cli'
          $php_require = [Package['nginx'], Yumrepo['epel']]
          $manage_nodejs_repo = false
          $nodejs_require = [Yumrepo['epel']]
          $php_extensions_base = {
            'pecl-zendopcache'=> {
              settings => {
                'OpCache/opcache.enable'        => '1',
                'OpCache/opcache.use_cwd'       => '1',
                'OpCache/opcache.save_comments' => '1',
                'OpCache/opcache.load_comments' => '1',
              }
            },
            'xml'        => {},
            'mcrypt'     => {},
            'pdo'        => {},
            'pecl-mongo' => {},
            'mbstring'   => {},
            'intl'       => {},
            'mysqlnd'    => {},
            'pecl-redis' => {},
          }
        }
        default: {
          fail("Unsupported platform: ${::operatingsystem} ${::operatingsystemrelease}")
        }
      }
      $php_extensions_dev = {
        'pecl-xdebug' => {},
      }
      $nginx_user  = $appuser
      $nginx_group = 'nginx'
    }
    'Debian': {
      case $::operatingsystemrelease {
        12.04: {
          $manage_nodejs_repo = true
          $install_pear = true
          $install_php_dev = true
          $php_extensions_base = {
            'mcrypt' => {},
            'curl'   => {},
            'xsl'    => {},
            'mysql'  => {},
            'redis'  => {
              provider => pecl,
            },
          }
        }
        default: {
          $manage_nodejs_repo = true
          $install_pear = false
          $install_php_dev = false
          $php_extensions_base = {
            'mcrypt' => {},
            'curl'   => {},
            'xsl'    => {},
            'mysql'  => {},
            'redis'  => {},
          }
        }
      }
      $php_package_prefix = undef
      $php_require = [Package['nginx']]
      $php_extensions_dev = {
        'xdebug' => {},
      }
      $nginx_user = $appuser
      $nginx_group = 'www-data'
    }
    default: {
      fail("Unsupported platform: ${::operatingsystem} ${::operatingsystemrelease}")
    }
  }

  $php_extensions = $environment ? {
    'production' => $php_extensions_base,
    default      => merge($php_extensions_base, $php_extensions_dev),
  }

  $dev = $environment ? {
    'production' => false,
    default      => true,
  }

  # we need an app user to run composer install as bower complains being running as root
  user { $appuser:
    ensure  => present,
    groups  => [$nginx_group],
    shell   => '/bin/bash',
    require => Package['nginx'],
  }

  # setup php
  class { 'php':
    ensure         => 'latest',
    fpm            => false,
    composer       => false,
    phpunit        => false,
    dev            => $install_php_dev,
    pear           => $install_pear,
    package_prefix => $php_package_prefix,
    extensions     => $php_extensions,
    require        => $php_require,
    settings       => {
        'Date/date.timezone' => $timezone,
        'PHP/upload_max_filesize' => '100MB',
    },
  } ->

  # install fpm and create app pool
  class { 'php::fpm':
    ensure => present,
    pools  => {},
  }

  php::fpm::pool { 'app':
    ensure => present,
    user   => $nginx_user,
    group  => $nginx_group,
  }

  # remove default pool
  php::fpm::pool { 'www':
    ensure => absent,
  }

  class { 'composer':
    php_package     => $composer_php_package,
    suhosin_enabled => false,
    github_token    => $github_token,
    require         => Class['php'],
  }

  # install application
  $base_dir = dirname($doc_base)
  exec { "create ${base_dir}":
    command => "mkdir -p ${base_dir}",
    creates => $base_dir,
    path    => '/usr/local/bin:/bin:/usr/bin:/usr/local/sbin:/usr/sbin:/sbin',
  }->

  file { $base_dir:
    ensure  => present,
    owner   => $appuser,
    mode    => '0755',
    require => User[$appuser],
  }->

  composer::project { $appname:
    project_name => $project_name,
    target_dir   => $doc_base,
    stability    => 'dev',
    keep_vcs     => true,
    dev          => $dev,
    user         => $appuser,
  }->

  composer::exec { "${appname}-install":
      cmd         => 'install',
      cwd         => $doc_base,
      scripts     => true,
      timeout     => 0,
      dev         => false,
      prefer_dist => true,
      user        => $appuser,
      interaction => false,
      unless      => "test -f ${doc_base}/vendor/autoload.php",
  }

  $writable_absolute_dirs = prefix($writable_dirs, "${doc_base}/")
  if $writable_dirs {
    file { $writable_absolute_dirs:
      ensure  => directory,
      owner   => $nginx_user,
      recurse => true,
      require => Composer::Exec["${appname}-install"]
    } ->
    fooacl::conf { $writable_absolute_dirs:
      permissions => [
        "user:${appuser}:rwX",
      ],
    }
  }


  $server_name = $server_domain ? {
      undef   => $::fqdn,
      default => $server_domain,
  }

  # setup nginx
  class { 'nginx': }

  nginx::resource::upstream { 'app':
    ensure  => present,
    members => [
      '127.0.0.1:9000',
    ],
  }

  if $ssl {
    $real_port = 443
    $vhost_name = "${server_name} ssl"
    nginx::resource::vhost {$server_name:
      ensure              => present,
      www_root            => "${doc_base}/${web_root}",
      location_cfg_append => {
        'rewrite' => '^ https://$server_name$request_uri? permanent'
      },
    }
  } else {
    $real_port = 80
    $vhost_name = $server_name
  }

  if $environment == 'production' {
    $nginx_location = '~ ^/app\.php(/|$)'
    $nginx_location_cfg_prepend = {
      fastcgi_read_timeout => 600,
      'internal'           => ''
    }
  } else {
    $nginx_location = '~ ^/(app_dev|app|config)\.php(/|$)'
    $nginx_location_cfg_prepend = {
      fastcgi_read_timeout => 600,
    }
  }

  nginx::resource::vhost {$vhost_name:
    ensure            => present,
    www_root          => "${doc_base}/${web_root}",
    listen_port       => $real_port,
    server_name       => [$server_name],
    vhost_cfg_prepend => {
      'add_header' => "X-APP-Server ${::hostname}"
    },
    ssl               => $ssl,
    ssl_cert          => $ssl_cert,
    ssl_key           => $ssl_key,
    proxy_set_header  => ['Host $host', 'X-Real-IP $remote_addr', 'X-Forwarded-For $proxy_add_x_forwarded_for'],
    try_files         => ['$uri /app.php$is_args$args'],
  }

  nginx::resource::location { "php_${server_name}":
    ensure               => present,
    vhost                => $vhost_name,
    location             => $nginx_location,
    ssl                  => $ssl,
    ssl_only             => $ssl,
    fastcgi              => 'app',
    fastcgi_split_path   => '^(.+\.php)(/.*)$',
    fastcgi_script       => "${doc_base}/${web_root}/\$fastcgi_script_name",
    fastcgi_param        => {
      'HTTPS' => '$https',
    },
    location_cfg_prepend => $nginx_location_cfg_prepend,
  }

  $real_ports = $ssl ? {
    true    => [$port, '443'],
    default => [$port]
  }

  firewall { '100 allow http and https access':
    port   => $real_ports,
    proto  => tcp,
    action => accept,
  }
}