Puppet Class: datadog_agent::integrations::disk

Inherits:
datadog_agent::params
Defined in:
manifests/integrations/disk.pp

Overview

Sample Usage:

class { 'datadog_agent::integrations::disk' :
    use_mount            => 'yes',
    excluded_filesystems => '/dev/tmpfs',
    excluded_disk_re     => '/dev/sd[e-z]*'
}

Parameters:

  • use_mount (String) (defaults to: 'no')
  • all_partitions (Any) (defaults to: undef)
  • tag_by_filesystem (Any) (defaults to: undef)
  • filesystem_exclude (Optional[Array[String]]) (defaults to: undef)
  • device_exclude (Optional[Array[String]]) (defaults to: undef)
  • mountpoint_exclude (Optional[Array[String]]) (defaults to: undef)
  • filesystem_include (Optional[Array[String]]) (defaults to: undef)
  • device_include (Optional[Array[String]]) (defaults to: undef)
  • mountpoint_include (Optional[Array[String]]) (defaults to: undef)
  • filesystem_blacklist (Optional[Array[String]]) (defaults to: undef)
  • device_blacklist (Optional[Array[String]]) (defaults to: undef)
  • mountpoint_blacklist (Optional[Array[String]]) (defaults to: undef)
  • filesystem_whitelist (Optional[Array[String]]) (defaults to: undef)
  • device_whitelist (Optional[Array[String]]) (defaults to: undef)
  • mountpoint_whitelist (Optional[Array[String]]) (defaults to: undef)
  • excluded_filesystems (Optional[Variant[String, Array[String]]]) (defaults to: undef)
  • excluded_disks (Optional[Variant[String, Array[String]]]) (defaults to: undef)
  • excluded_disk_re (Optional[String]) (defaults to: undef)
  • excluded_mountpoint_re (Optional[String]) (defaults to: undef) 


63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
 
# File 'manifests/integrations/disk.pp', line 63

class datadog_agent::integrations::disk (
  String $use_mount                              = 'no',
  $all_partitions                                = undef,
  $tag_by_filesystem                             = undef,
  Optional[Array[String]] $filesystem_exclude    = undef,
  Optional[Array[String]] $device_exclude        = undef,
  Optional[Array[String]] $mountpoint_exclude    = undef,
  Optional[Array[String]] $filesystem_include    = undef,
  Optional[Array[String]] $device_include        = undef,
  Optional[Array[String]] $mountpoint_include    = undef,
  Optional[Array[String]] $filesystem_blacklist  = undef, # deprecated in agent version >7.24
  Optional[Array[String]] $device_blacklist      = undef, # deprecated in agent version >7.24
  Optional[Array[String]] $mountpoint_blacklist  = undef, # deprecated in agent version >7.24
  Optional[Array[String]] $filesystem_whitelist  = undef, # deprecated in agent version >7.24
  Optional[Array[String]] $device_whitelist      = undef, # deprecated in agent version >7.24
  Optional[Array[String]] $mountpoint_whitelist  = undef, # deprecated in agent version >7.24
  Optional[Variant[String, Array[String]]] $excluded_filesystems   = undef,  # deprecated in agent versions >6.9
  Optional[Variant[String, Array[String]]] $excluded_disks         = undef,  # deprecated in agent versions >6.9
  Optional[String] $excluded_disk_re       = undef,  # deprecated in agent versions >6.9
  Optional[String] $excluded_mountpoint_re = undef,  # deprecated in agent versions >6.9
) inherits datadog_agent::params {
  require ::datadog_agent

  validate_legacy('Optional[String]', 'validate_re', $all_partitions, '^(no|yes)$')

  if $use_mount !~ '^(no|yes)$' {
    fail('error during compilation')
  }

  $legacy_dst = "${datadog_agent::params::legacy_conf_dir}/disk.yaml"
  if $::datadog_agent::_agent_major_version > 5 {
    $dst_dir = "${datadog_agent::params::conf_dir}/disk.d"
    file { $legacy_dst:
      ensure => 'absent'
    }

    file { $dst_dir:
      ensure  => directory,
      owner   => $datadog_agent::params::dd_user,
      group   => $datadog_agent::params::dd_group,
      mode    => $datadog_agent::params::permissions_directory,
      require => Package[$datadog_agent::params::package_name],
      notify  => Service[$datadog_agent::params::service_name]
    }
    $dst = "${dst_dir}/conf.yaml"
  } else {
    $dst = $legacy_dst
  }

  file { $dst:
    ensure  => file,
    owner   => $datadog_agent::params::dd_user,
    group   => $datadog_agent::params::dd_group,
    mode    => $datadog_agent::params::permissions_protected_file,
    content => template('datadog_agent/agent-conf.d/disk.yaml.erb'),
    require => Package[$datadog_agent::params::package_name],
    notify  => Service[$datadog_agent::params::service_name]
  }
}