Puppet Class: datadog_agent::integrations::varnish

Inherits:
datadog_agent::params
Defined in:
manifests/integrations/varnish.pp

Overview

Class: datadog_agent::integrations::varnish

This class will install the necessary configuration for the varnish integration

Parameters:

varnishstat
    Path to the varnishstat binary

instance_name
    Used in the varnishstat command for the -n argument

tags
    DataDog tags

Sample usage:

include ‘datadog_agent::integrations::varnish’

class { ‘datadog_agent::integrations::varnish’:

url      => '/usr/bin/varnishstat',
tags     => ['env:production'],

}

Parameters:

  • varnishstat (Any) (defaults to: '/usr/bin/varnishstat')
  • instance_name (Any) (defaults to: undef)
  • tags (Any) (defaults to: []) 


24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
 
# File 'manifests/integrations/varnish.pp', line 24

class datadog_agent::integrations::varnish (
  $varnishstat   = '/usr/bin/varnishstat',
  $instance_name = undef,
  $tags          = [],
) inherits datadog_agent::params {
  require ::datadog_agent

  $legacy_dst = "${datadog_agent::params::legacy_conf_dir}/varnish.yaml"
  if $::datadog_agent::_agent_major_version > 5 {
    $dst_dir = "${datadog_agent::params::conf_dir}/varnish.d"
    file { $legacy_dst:
      ensure => 'absent'
    }

    file { $dst_dir:
      ensure  => directory,
      owner   => $datadog_agent::params::dd_user,
      group   => $datadog_agent::params::dd_group,
      mode    => $datadog_agent::params::permissions_directory,
      require => Package[$datadog_agent::params::package_name],
      notify  => Service[$datadog_agent::params::service_name]
    }
    $dst = "${dst_dir}/conf.yaml"
  } else {
    $dst = $legacy_dst
  }

  file { $dst:
    ensure  => file,
    owner   => $datadog_agent::params::dd_user,
    group   => $datadog_agent::params::dd_group,
    mode    => $datadog_agent::params::permissions_protected_file,
    content => template('datadog_agent/agent-conf.d/varnish.yaml.erb'),
    require => Package[$datadog_agent::params::package_name],
    notify  => Service[$datadog_agent::params::service_name]
  }
}