Puppet Class: datadog_agent::system_probe

Inherits:
datadog_agent::params
Defined in:
manifests/system_probe.pp

Overview

Parameters:

  • enabled (Boolean) (defaults to: false)
  • log_file (Optional[String]) (defaults to: undef)
  • sysprobe_socket (Optional[String]) (defaults to: undef)
  • service_enable (Boolean) (defaults to: true)
  • service_ensure (String) (defaults to: 'running')
  • service_provider (Optional[String]) (defaults to: undef) 


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
 
# File 'manifests/system_probe.pp', line 1

class datadog_agent::system_probe(
  Boolean $enabled = false,
  Optional[String] $log_file = undef,
  Optional[String] $sysprobe_socket = undef,

  Boolean $service_enable = true,
  String $service_ensure = 'running',
  Optional[String] $service_provider = undef,
) inherits datadog_agent::params {

  if $::operatingsystem == 'Windows' {
    # Datadog does not currently support Windows and macOS platforms for Network Performance Monitoring
    fail('Network performance monitoring is only supported on Linux.')
  }

  if $service_provider {
    service { $datadog_agent::params::sysprobe_service_name:
      ensure    => $service_ensure,
      enable    => $service_enable,
      provider  => $service_provider,
      hasstatus => false,
      pattern   => 'dd-agent',
      require   => Package[$datadog_agent::params::package_name],
    }
  } else {
    service { $datadog_agent::params::sysprobe_service_name:
      ensure    => $service_ensure,
      enable    => $service_enable,
      hasstatus => false,
      pattern   => 'dd-agent',
      require   => Package[$datadog_agent::params::package_name],
    }
  }

  $sysprobe_config = {
    'system_probe_config' => {
      'enabled' => $enabled,
      'sysprobe_socket' => $sysprobe_socket,
      'log_file' => $log_file,
    }
  }

  file { '/etc/datadog-agent/system-probe.yaml':
    owner   => $datadog_agent::params::dd_user,
    group   => 'dd-agent',
    mode    => '0640',
    content => template('datadog_agent/system_probe.yaml.erb'),
    notify  => Service[$datadog_agent::params::sysprobe_service_name],
    require => File['/etc/datadog-agent'],
  }

}