Puppet Class: datadog_agent::security_agent

Inherits:
datadog_agent::params
Defined in:
manifests/security_agent.pp

Overview

Class: datadog_agent::security_agent

This class defines the Datadog Security Agent configuration.

Parameters:

  • enabled (Boolean) (defaults to: false)
  • socket (Optional[String]) (defaults to: undef)
  • service_enable (Boolean) (defaults to: true)
  • service_ensure (String) (defaults to: 'running')
  • service_provider (Optional[String]) (defaults to: undef) 


5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
 
# File 'manifests/security_agent.pp', line 5

class datadog_agent::security_agent (
  Boolean $enabled = false,
  Optional[String] $socket = undef,

  Boolean $service_enable = true,
  String $service_ensure = 'running',
  Optional[String] $service_provider = undef,

) inherits datadog_agent::params {
  $securityagent_config = {
    'runtime_security_config' => {
      'enabled' => $enabled,
      'socket' => $socket,
    },
  }

  if $facts['os']['name'] == 'Windows' {
    file { 'C:/ProgramData/Datadog/security-agent.yaml':
      owner   => $datadog_agent::params::dd_user,
      group   => $datadog_agent::params::dd_group,
      mode    => '0640',
      content => template('datadog_agent/security-agent.yaml.erb'),
      require => File['C:/ProgramData/Datadog'],
    }
  } else {
    if $service_provider {
      service { $datadog_agent::params::securityagent_service_name:
        ensure    => $service_ensure,
        enable    => $service_enable,
        provider  => $service_provider,
        hasstatus => false,
        pattern   => 'dd-agent',
        require   => Package[$datadog_agent::params::package_name],
      }
    } else {
      service { $datadog_agent::params::securityagent_service_name:
        ensure    => $service_ensure,
        enable    => $service_enable,
        hasstatus => false,
        pattern   => 'dd-agent',
        require   => Package[$datadog_agent::params::package_name],
      }
    }

    file { '/etc/datadog-agent/security-agent.yaml':
      owner   => $datadog_agent::params::dd_user,
      group   => $datadog_agent::params::dd_group,
      mode    => '0640',
      content => template('datadog_agent/security-agent.yaml.erb'),
      notify  => Service[$datadog_agent::params::securityagent_service_name],
      require => File['/etc/datadog-agent'],
    }
  }
}