Puppet Class: jmeter

Inherits:
jmeter::params
Defined in:
manifests/init.pp

Summary

Main class for jmeter module

Overview

jmeter

Examples:

Declaring the class

class { 'jmeter': }

Configuring to install plugins

class { 'jmeter':
  jmeter_version         => '3.2',
  plugin_manager_install => true,
  plugins                => {
    'foo' => { ensure => present },
    'bar' => { ensure => present },
  }
 }

Enabling server (and jmeter service)

class { 'jmeter':
  enable_server => true,
  bind_ip       => 10.3.3.6,
}

Parameters:

  • bind_ip (Stdlib::Compat::Ip_address) (defaults to: '0.0.0.0') —

    IP address to bind to. Defaults to ‘0.0.0.0’ (all interfaces). Replaces ‘jmeter::server::server_ip`

  • bind_port (Integer[0,65535]) (defaults to: 1099) —

    Port for server to use.

  • checksum_type (String) (defaults to: 'sha1') —

    Checksum type to use for all download commands that use one. You can set to ‘none’ to disable this check.

  • cmdrunner_checksum (String) (defaults to: '06ecaa09961e3d7bab009fed4fd6d34db81fa830') —

    Checksum for the cmdrunner .jar.

  • cmdrunner_version (String) (defaults to: '2.0') —

    Version of cmdrunner to use. This should generally be left as default.

  • download_url (Stdlib::HTTPUrl) (defaults to: 'http://archive.apache.org/dist/jmeter/binaries/') —

    Download URL for Jmeter.

  • enable_server (Boolean) (defaults to: false) —

    Whether to enable the server. Replaces the previous method of declaring ‘class { ’jmeter::server’: }‘

  • java_version (String) (defaults to: $jmeter::params::java_version) —

    Java version to install.

  • jdk_pkg (String) (defaults to: $jmeter::params::jdk_pkg) —

    Name for the jdk package.

  • jmeter_version (String) (defaults to: $jmeter::params::jmeter_version) —

    Sets version of jmeter to install. Note that 3.x requires Java v8.

  • jmeter_checksum (String) (defaults to: $jmeter::params::jmeter_checksum) —

    Checksum for the Jmeter binary.

  • manage_java (Boolean) (defaults to: true) —

    Whether to ensure that java is installed.

  • jmeter_user (String) (defaults to: 'jmeter') —

    User to run jmeter under

  • jmeter_group (String) (defaults to: 'jmeter') —

    Group to run jmeter under

  • plugin_manager_checksum (String) (defaults to: 'a6ea7eccea25ae80e76c72ac06695f14c3bef010') —

    Checksum for the plugin manager download.

  • plugin_manager_install (Boolean) (defaults to: false) —

    Whether or not to install the plugin manager.

  • plugin_manager_url (Stdlib::HTTPUrl) (defaults to: 'http://search.maven.org/remotecontent?filepath=kg/apc/') —

    Download URL for both the plugin manager and command runner. Note, this redirects, and part of the path has the package name appended and is built dynamically in jmeter::install.

  • plugin_manager_version (String) (defaults to: '0.16') —

    Sets the version of the plugin manager to install.

  • plugins (Optional[Hash]) (defaults to: undef) —

    An optional hash of plugins to install via the plugin manager.



44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
 
# File 'manifests/init.pp', line 44

class jmeter (
  Boolean $enable_server              = false,
  Stdlib::Compat::Ip_address $bind_ip = '0.0.0.0',
  Integer[0,65535] $bind_port         = 1099,
  String $jmeter_version              = $jmeter::params::jmeter_version,
  String $jmeter_checksum             = $jmeter::params::jmeter_checksum,
  String $jmeter_user                 = 'jmeter',
  String $jmeter_group                = 'jmeter',
  String $checksum_type               = 'sha1',
  Boolean $plugin_manager_install     = false,
  String $plugin_manager_version      = '0.16',
  String $plugin_manager_checksum     = 'a6ea7eccea25ae80e76c72ac06695f14c3bef010',
  String $cmdrunner_version           = '2.0',
  String $cmdrunner_checksum          = '06ecaa09961e3d7bab009fed4fd6d34db81fa830',
  Optional[Hash] $plugins             = undef,
  Stdlib::HTTPUrl $download_url       = 'http://archive.apache.org/dist/jmeter/binaries/',
  Stdlib::HTTPUrl $plugin_manager_url = 'http://search.maven.org/remotecontent?filepath=kg/apc/',
  String $java_version                = $jmeter::params::java_version,
  Boolean $manage_java                = true,
  String $jdk_pkg                     = $jmeter::params::jdk_pkg
) inherits jmeter::params {

  Exec { path => '/bin:/usr/bin:/usr/sbin' }

  contain jmeter::install

  if $enable_server {
    contain jmeter::server
    contain jmeter::service

    Class['jmeter::install']
    -> Class['jmeter::server']
    ~> Class['jmeter::service']
  }

}