Puppet Class: dcos::adminrouter

Defined in:
manifests/adminrouter.pp

Overview

Adminrouter (nginx) config

Config is a hash containing configuration:

dcos::master::adminrouter:
  server_name: 'master.example.com'
  ssl_certificate: '/etc/letsencrypt/live/master.example.com/fullchain.pem'
  ssl_certificate_key: '/etc/letsencrypt/live/master.example.com/privkey.pem'

Parameters:

  • config (Hash) 


11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
 
# File 'manifests/adminrouter.pp', line 11

class dcos::adminrouter (
  Hash $config,
) {
  $server_name = pick($config['server_name'], 'master.mesos')
  $ssl_certificate = pick($config['ssl_certificate'], 'includes/snakeoil.crt')
  $ssl_certificate_key = pick($config['ssl_certificate_key'], 'includes/snakeoil.key')

  if 'default_scheme' in $config {
    $default_scheme = $config['default_scheme']
  }

  $config_dir = $facts['dcos_config_path']
  $adminrouter_path = $facts['dcos_adminrouter_path']
  $include_master_conf = $facts['dcos_include_master_conf']

  if $config_dir and $adminrouter_path {
    file { "${config_dir}/adminrouter-listen-open.conf":
      ensure  => 'file',
      content => template('dcos/adminrouter-listen-open.conf.erb'),
      notify  => Service['dcos-adminrouter'],
    }

    file { "${adminrouter_path}/nginx/conf/nginx.master.conf":
      ensure => 'file',
      notify => Service['dcos-adminrouter'],
    }

    if versioncmp($facts['dcos_version'], '1.13.0') >= 0 {
      File<| title == "${adminrouter_path}/nginx/conf/nginx.master.conf" |> {
        content => template('dcos/nginx.master.conf-1.13.erb'),
      }
    } else {
      File<| title == "${adminrouter_path}/nginx/conf/nginx.master.conf" |> {
        content => template('dcos/nginx.master.conf.erb'),
      }
    }

    file { "${config_dir}/../etc/adminrouter.env":
      ensure  => 'file',
      content => template('dcos/adminrouter.env.erb'),
      notify  => Service['dcos-adminrouter'],
    }

    service { 'dcos-adminrouter':
      ensure     => 'running',
      hasstatus  => true,
      hasrestart => true,
      enable     => true,
      require    => [
        File["${config_dir}/adminrouter-listen-open.conf"],
        File["${adminrouter_path}/nginx/conf/nginx.master.conf"]
      ],
    }
  }
}