Puppet Class: dcos::install

Defined in:
manifests/install.pp

Overview

Class dcos::install

This class is called from dcos for install.



5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
 
# File 'manifests/install.pp', line 5

class dcos::install {
  file { '/usr/local/bin/dcos-version':
    ensure => 'file',
    owner  => 'root',
    group  => 'root',
    mode   => '0755',
    source => 'puppet:///modules/dcos/dcos-version',
  }

  # prerequisities
  case $facts['os']['family'] {
    'Debian': {
      contain dcos::os::debian
    }
    'RedHat', 'Amazon': {
      contain dcos::os::redhat
    }
    default: {
      fail("${facts['os']['family']} not supported")
    }
  }

  if $dcos::bootstrap_url {
    $download_url = "${dcos::bootstrap_url}/${dcos::bootstrap_script}"

    file { $dcos::download_dir:
      ensure  => directory,
      recurse => true,
      owner   => 'root',
      group   => 'root',
    }

    archive { "${dcos::download_dir}/dcos_install.sh":
      ensure        => present,
      user          => 'root',
      group         => 'root',
      source        => $download_url,
      creates       => "${dcos::download_dir}/dcos_install.sh",
      extract       => false,
      cleanup       => false,
      checksum      => $dcos::install_checksum['hash'],
      checksum_type => $dcos::install_checksum['type'],
      require       => File[$dcos::download_dir],
    }
  }
}