Puppet Class: dcos::master

Inherits:
dcos
Defined in:
manifests/master.pp

Overview

DC/OS master node

Parameters:

  • mesos (Hash) (defaults to: {})
  • manage_adminrouter (Boolean) (defaults to: false)
  • service_name (String) (defaults to: 'dcos-mesos-master')
  • adminrouter (Hash) (defaults to: {})
  • metrics (Hash) (defaults to: {})
  • region (Optional[String]) (defaults to: $dcos::region)
  • zone (Optional[String]) (defaults to: $dcos::zone) 


10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
 
# File 'manifests/master.pp', line 10

class dcos::master (
  Hash             $mesos = {},
  Boolean          $manage_adminrouter = false,
  String           $service_name = 'dcos-mesos-master',
  Hash             $adminrouter = {},
  Hash             $metrics = {},
  Optional[String] $region = $dcos::region,
  Optional[String] $zone = $dcos::zone,
) inherits dcos {
  anchor { 'dcos::master::installed': }

  if $dcos::bootstrap_url {
    exec { 'dcos master install':
      command     => "bash ${dcos::download_dir}/dcos_install.sh master",
      path        => '/bin:/usr/bin:/usr/sbin',
      onlyif      => 'test -z "`ls -A /opt/mesosphere`"',
      refreshonly => false,
      before      => Anchor['dcos::master::installed'],
    }
  }

  case $facts['os']['family'] {
    'Debian': {
      # needed for DC/OS < 1.11
      # make sure to try system library first
      file_line { 'update LD_PATH /opt/mesosphere/environment':
        path    => '/opt/mesosphere/environment',
        line    => 'LD_LIBRARY_PATH=/usr/lib/x86_64-linux-gnu:/opt/mesosphere/lib',
        match   => '^LD_LIBRARY_PATH=*',
        replace => true,
        require => Anchor['dcos::master::installed'],
      }
    }
    default: {}
  }

  if $manage_adminrouter {
    class { 'dcos::adminrouter':
      config  => $adminrouter,
      require => Anchor['dcos::master::installed'],
    }
  }

  file { '/opt/mesosphere/etc/mesos-master-extras':
    ensure  => 'file',
    content => template('dcos/master-extras.erb'),
    notify  => Service[$service_name],
  }

  if $region or $zone {
    file { '/var/lib/dcos/mesos-master-domain.json':
      ensure  => 'file',
      content => dcos::domain($region, $zone),
      notify  => Service[$service_name],
      require => Anchor['dcos::master::installed'],
    }
  }

  $config_dir = $facts['dcos_config_path']

  # make sure fact is defined
  if $facts['dcos_version'] and versioncmp($facts['dcos_version'], '1.13.0') < 0 {
    if !empty($metrics) {
      file { "${config_dir}/../etc/dcos-metrics-config.yaml":
        ensure  => 'file',
        content => template('dcos/dcos-metrics-config.erb'),
        notify  => Service['dcos-metrics-master'],
      }
    }

    service { 'dcos-metrics-master':
      ensure     => 'running',
      hasstatus  => true,
      hasrestart => true,
      enable     => true,
    }
  }

  service { $service_name:
    ensure     => 'running',
    hasstatus  => true,
    hasrestart => true,
    enable     => true,
    require    => [File['/opt/mesosphere/etc/mesos-master-extras'],Anchor['dcos::master::installed']],
  }
}