Puppet Class: etcd::config

Defined in:
manifests/config.pp

Summary

This class handles the etcd configuration file

Overview



7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
 
# File 'manifests/config.pp', line 7

class etcd::config {
  assert_private()

  File {
    owner => 'etcd',
  }

  if $etcd::manage_config_dir {
    file { $etcd::config_dir:
      ensure  => directory,
      purge   => $etcd::purge_config_dir,
      recurse => true,
    }
  }

  if !empty($etcd::config) {
    file { "${etcd::config_dir}/${etcd::config_file}":
      ensure  => file,
      content => $etcd::config ? { # lint:ignore:selector_inside_resource
        Hash   => stdlib::to_yaml($etcd::config),
        String => $etcd::config,
      },
      notify  => Class['etcd::service'],
    }
  }

  file { '/etc/puppetlabs/puppet/etcdctl.yaml':
    ensure  => file,
    mode    => '0640',
    owner   => 'root',
    content => stdlib::to_yaml({ env => $etcd::etcdctl_env }),
  }

  if $etcd::manage_etcdctl_profile {
    file { '/etc/profile.d/etcdctl.sh':
      ensure  => file,
      mode    => '0640',
      owner   => 'root',
      content => epp("${module_name}/etcdctl.env.epp", {
          env => $etcd::etcdctl_env,
      }),
    }
  }
}