Puppet Class: jboss::install

Defined in:
manifests/install.pp

Overview

Sets up the system for installing JBoss/WildFly AS.

It is intended to be called by jboss::jboss in order to:

  • create JBoss user and group;
  • make /opt folder group owned by jboss and group writable;
  • create /home/jboss/bin folder to host some management scripts;
  • according to the parameter jboss_instance_list create in /usr/local/bin a text file with all the instance names on the node, one per line.

Parameters:

  • jboss_instance_list (Boolean) (defaults to: false) —

    should a text file with all instance names on the node, one per line, be created in /usr/local/bin?

Author:

  • Dario Sestero



15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
 
# File 'manifests/install.pp', line 15

class jboss::install (Boolean $jboss_instance_list = false) {

  user { 'jboss':
    ensure     => present,
    comment    => 'JBoss user',
    gid        => 'jboss',
    shell      => '/bin/bash',
    managehome => true,
  }

  group { 'jboss':
    ensure => present,
  }

  file {
    default:
      owner => 'jboss',
      group => 'jboss',
      ;
    '/opt':
      ensure => present,
      mode   => 'g+w',
      ;
    '/home/jboss/bin':
      ensure  => directory,
      ;
  }

  if $jboss_instance_list {
    Concat::Fragment <<| target == '/usr/local/bin/jboss-instance-list.conf'
    and tag == $facts['networking']['fqdn'] |>> {
    }

    concat { '/usr/local/bin/jboss-instance-list.conf':
      ensure => present,
    }
  }
}