Puppet Class: apache

Inherits:
apache::params
Inherited by:
apache::spec
Defined in:
manifests/init.pp

Overview

Class: apache

This is the main apache class

Parameters

Standard class parameters Define the general class behaviour and customizations

my_class

Name of a custom class to autoload to manage module’s customizations If defined, apache class will automatically “include $my_class” Can be defined also by the (top scope) variable $apache_myclass

source

Sets the content of source parameter for main configuration file If defined, apache main config file will have the param: source => $source Can be defined also by the (top scope) variable $apache_source

source_dir

If defined, the whole apache configuration directory content is retrieved recursively from the specified source (source => $source_dir , recurse => true) Can be defined also by the (top scope) variable $apache_source_dir

source_dir_purge

If set to true (default false) the existing configuration directory is mirrored with the content retrieved from source_dir (source => $source_dir , recurse => true , purge => true) Can be defined also by the (top scope) variable $apache_source_dir_purge

template

Sets the path to the template to use as content for main configuration file If defined, apache main config file has: content => content(“$template”) Note source and template parameters are mutually exclusive: don’t use both Can be defined also by the (top scope) variable $apache_template

options

An hash of custom options to be used in templates for arbitrary settings. Can be defined also by the (top scope) variable $apache_options

service_autorestart

Automatically restarts the apache service when there is a change in configuration files. Default: true, Set to false if you don’t want to automatically restart the service.

service_requires

Overwrites the service dependencies, which are by default: Package. Set this parameter to a custom set of requirements, if you want to let the Apache service depend on more than just the package dependency.

absent

Set to ‘true’ to remove package(s) installed by module Can be defined also by the (top scope) variable $apache_absent

disable

Set to ‘true’ to disable service(s) managed by module Can be defined also by the (top scope) variable $apache_disable

disableboot

Set to ‘true’ to disable service(s) at boot, without checks if it’s running Use this when the service is managed by a tool like a cluster software Can be defined also by the (top scope) variable $apache_disableboot

monitor

Set to ‘true’ to enable monitoring of the services provided by the module Can be defined also by the (top scope) variables $apache_monitor and $monitor

monitor_tool

Define which monitor tools (ad defined in Example42 monitor module) you want to use for apache checks Can be defined also by the (top scope) variables $apache_monitor_tool and $monitor_tool

monitor_target

The Ip address or hostname to use as a target for monitoring tools. Default is the fact $ipaddress Can be defined also by the (top scope) variables $apache_monitor_target and $monitor_target

puppi

Set to ‘true’ to enable creation of module data files that are used by puppi Can be defined also by the (top scope) variables $apache_puppi and $puppi

puppi_helper

Specify the helper to use for puppi commands. The default for this module is specified in params.pp and is generally a good choice. You can customize the output of puppi commands for this module using another puppi helper. Use the define puppi::helper to create a new custom helper Can be defined also by the (top scope) variables $apache_puppi_helper and $puppi_helper

firewall

Set to ‘true’ to enable firewalling of the services provided by the module Can be defined also by the (top scope) variables $apache_firewall and $firewall

firewall_tool

Define which firewall tool(s) (ad defined in Example42 firewall module) you want to use to open firewall for apache port(s) Can be defined also by the (top scope) variables $apache_firewall_tool and $firewall_tool

firewall_src

Define which source ip/net allow for firewalling apache. Default: 0.0.0.0/0 Can be defined also by the (top scope) variables $apache_firewall_src and $firewall_src

firewall_dst

Define which destination ip to use for firewalling. Default: $ipaddress Can be defined also by the (top scope) variables $apache_firewall_dst and $firewall_dst

debug

Set to ‘true’ to enable modules debugging Can be defined also by the (top scope) variables $apache_debug and $debug

audit_only

Set to ‘true’ if you don’t intend to override existing configuration files and want to audit the difference between existing files and the ones managed by Puppet. Can be defined also by the (top scope) variables $apache_audit_only and $audit_only

Default class params - As defined in apache::params. Note that these variables are mostly defined and used in the module itself, overriding the default values might not affected all the involved components. Set and override them only if you know what you’re doing. Note also that you can’t override/set them via top scope variables.

package

The name of apache package

service

The name of apache service

service_status

If the apache service init script supports status argument

process

The name of apache process

process_args

The name of apache arguments. Used by puppi and monitor. Used only in case the apache process name is generic (java, ruby…)

process_user

The name of the user apache runs with. Used by puppi and monitor.

config_dir

Main configuration directory. Used by puppi

config_file

Main configuration file path

config_file_mode

Main configuration file path mode

config_file_owner

Main configuration file path owner

config_file_group

Main configuration file path group

config_file_init

Path of configuration file sourced by init script

config_file_default_purge

Set to ‘true’ to purge the default configuration file

pid_file

Path of pid file. Used by monitor

data_dir

Path of application data directory. Used by puppi

log_dir

Base logs directory. Used by puppi

log_file

Log file(s). Used by puppi

port

The listening port, if any, of the service. This is used by monitor, firewall and puppi (optional) components Note: This doesn’t necessarily affect the service configuration file Can be defined also by the (top scope) variable $apache_port

ssl_port

The ssl port, used if apache::ssl is included and monitor/firewall are enabled

protocol

The protocol used by the the service. This is used by monitor, firewall and puppi (optional) components Can be defined also by the (top scope) variable $apache_protocol

version

The version of apache package to be installed

Examples

You can use this class in 2 ways:

  • Set variables (at top scope level on in a ENC) and “include apache”

  • Call apache as a parametrized class

See README for details.

Author

Alessandro Franceschi <al@lab42.it/>

Parameters:

  • my_class (Any) (defaults to: params_lookup( 'my_class' ))
  • source (Any) (defaults to: params_lookup( 'source' ))
  • source_dir (Any) (defaults to: params_lookup( 'source_dir' ))
  • source_dir_purge (Any) (defaults to: params_lookup( 'source_dir_purge' ))
  • template (Any) (defaults to: params_lookup( 'template' ))
  • service_autorestart (Any) (defaults to: params_lookup( 'service_autorestart' , 'global' ))
  • options (Any) (defaults to: params_lookup( 'options' ))
  • absent (Any) (defaults to: params_lookup( 'absent' ))
  • disable (Any) (defaults to: params_lookup( 'disable' ))
  • disableboot (Any) (defaults to: params_lookup( 'disableboot' ))
  • monitor (Any) (defaults to: params_lookup( 'monitor' , 'global' ))
  • monitor_tool (Any) (defaults to: params_lookup( 'monitor_tool' , 'global' ))
  • monitor_target (Any) (defaults to: params_lookup( 'monitor_target' , 'global' ))
  • puppi (Any) (defaults to: params_lookup( 'puppi' , 'global' ))
  • puppi_helper (Any) (defaults to: params_lookup( 'puppi_helper' , 'global' ))
  • firewall (Any) (defaults to: params_lookup( 'firewall' , 'global' ))
  • firewall_tool (Any) (defaults to: params_lookup( 'firewall_tool' , 'global' ))
  • firewall_src (Any) (defaults to: params_lookup( 'firewall_src' , 'global' ))
  • firewall_dst (Any) (defaults to: params_lookup( 'firewall_dst' , 'global' ))
  • debug (Any) (defaults to: params_lookup( 'debug' , 'global' ))
  • audit_only (Any) (defaults to: params_lookup( 'audit_only' , 'global' ))
  • package (Any) (defaults to: params_lookup( 'package' ))
  • service (Any) (defaults to: params_lookup( 'service' ))
  • service_status (Any) (defaults to: params_lookup( 'service_status' ))
  • service_requires (Any) (defaults to: params_lookup( 'service_requires' ))
  • process (Any) (defaults to: params_lookup( 'process' ))
  • process_args (Any) (defaults to: params_lookup( 'process_args' ))
  • process_user (Any) (defaults to: params_lookup( 'process_user' ))
  • config_dir (Any) (defaults to: params_lookup( 'config_dir' ))
  • config_file (Any) (defaults to: params_lookup( 'config_file' ))
  • config_file_mode (Any) (defaults to: params_lookup( 'config_file_mode' ))
  • config_file_owner (Any) (defaults to: params_lookup( 'config_file_owner' ))
  • config_file_group (Any) (defaults to: params_lookup( 'config_file_group' ))
  • config_file_init (Any) (defaults to: params_lookup( 'config_file_init' ))
  • config_file_default_purge (Any) (defaults to: params_lookup( 'config_file_default_purge'))
  • pid_file (Any) (defaults to: params_lookup( 'pid_file' ))
  • data_dir (Any) (defaults to: params_lookup( 'data_dir' ))
  • log_dir (Any) (defaults to: params_lookup( 'log_dir' ))
  • log_file (Any) (defaults to: params_lookup( 'log_file' ))
  • port (Any) (defaults to: params_lookup( 'port' ))
  • ssl_port (Any) (defaults to: params_lookup( 'ssl_port' ))
  • protocol (Any) (defaults to: params_lookup( 'protocol' ))
  • version (Any) (defaults to: params_lookup( 'version' ))
  • dotconf_hash (Any) (defaults to: params_lookup( 'dotconf_hash'))
  • htpasswd_hash (Any) (defaults to: params_lookup( 'htpasswd_hash'))
  • listen_hash (Any) (defaults to: params_lookup( 'listen_hash'))
  • module_hash (Any) (defaults to: params_lookup( 'module_hash'))
  • vhost_hash (Any) (defaults to: params_lookup( 'vhost_hash'))
  • virtualhost_hash (Any) (defaults to: params_lookup( 'virtualhost_hash')) 


216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
 
# File 'manifests/init.pp', line 216

class apache (
  $my_class                  = params_lookup( 'my_class' ),
  $source                    = params_lookup( 'source' ),
  $source_dir                = params_lookup( 'source_dir' ),
  $source_dir_purge          = params_lookup( 'source_dir_purge' ),
  $template                  = params_lookup( 'template' ),
  $service_autorestart       = params_lookup( 'service_autorestart' , 'global' ),
  $options                   = params_lookup( 'options' ),
  $absent                    = params_lookup( 'absent' ),
  $disable                   = params_lookup( 'disable' ),
  $disableboot               = params_lookup( 'disableboot' ),
  $monitor                   = params_lookup( 'monitor' , 'global' ),
  $monitor_tool              = params_lookup( 'monitor_tool' , 'global' ),
  $monitor_target            = params_lookup( 'monitor_target' , 'global' ),
  $puppi                     = params_lookup( 'puppi' , 'global' ),
  $puppi_helper              = params_lookup( 'puppi_helper' , 'global' ),
  $firewall                  = params_lookup( 'firewall' , 'global' ),
  $firewall_tool             = params_lookup( 'firewall_tool' , 'global' ),
  $firewall_src              = params_lookup( 'firewall_src' , 'global' ),
  $firewall_dst              = params_lookup( 'firewall_dst' , 'global' ),
  $debug                     = params_lookup( 'debug' , 'global' ),
  $audit_only                = params_lookup( 'audit_only' , 'global' ),
  $package                   = params_lookup( 'package' ),
  $service                   = params_lookup( 'service' ),
  $service_status            = params_lookup( 'service_status' ),
  $service_requires          = params_lookup( 'service_requires' ),
  $process                   = params_lookup( 'process' ),
  $process_args              = params_lookup( 'process_args' ),
  $process_user              = params_lookup( 'process_user' ),
  $config_dir                = params_lookup( 'config_dir' ),
  $config_file               = params_lookup( 'config_file' ),
  $config_file_mode          = params_lookup( 'config_file_mode' ),
  $config_file_owner         = params_lookup( 'config_file_owner' ),
  $config_file_group         = params_lookup( 'config_file_group' ),
  $config_file_init          = params_lookup( 'config_file_init' ),
  $config_file_default_purge = params_lookup( 'config_file_default_purge'),
  $pid_file                  = params_lookup( 'pid_file' ),
  $data_dir                  = params_lookup( 'data_dir' ),
  $log_dir                   = params_lookup( 'log_dir' ),
  $log_file                  = params_lookup( 'log_file' ),
  $port                      = params_lookup( 'port' ),
  $ssl_port                  = params_lookup( 'ssl_port' ),
  $protocol                  = params_lookup( 'protocol' ),
  $version                   = params_lookup( 'version' ),
  $dotconf_hash              = params_lookup( 'dotconf_hash'),
  $htpasswd_hash             = params_lookup( 'htpasswd_hash'),
  $listen_hash               = params_lookup( 'listen_hash'),
  $module_hash               = params_lookup( 'module_hash'),
  $vhost_hash                = params_lookup( 'vhost_hash'),
  $virtualhost_hash          = params_lookup( 'virtualhost_hash'),
  ) inherits apache::params {

  $bool_source_dir_purge=any2bool($source_dir_purge)
  $bool_service_autorestart=any2bool($service_autorestart)
  $bool_absent=any2bool($absent)
  $bool_disable=any2bool($disable)
  $bool_disableboot=any2bool($disableboot)
  $bool_monitor=any2bool($monitor)
  $bool_puppi=any2bool($puppi)
  $bool_firewall=any2bool($firewall)
  $bool_debug=any2bool($debug)
  $bool_audit_only=any2bool($audit_only)

  ## Integration with Hiera
  if $dotconf_hash != {} {
    validate_hash($dotconf_hash)
    create_resources('apache::dotconf', $dotconf_hash)
  }
  if $htpasswd_hash != {} {
    validate_hash($htpasswd_hash)
    create_resources('apache::htpasswd', $htpasswd_hash)
  }
  if $listen_hash != {} {
    validate_hash($listen_hash)
    create_resources('apache::listen', $listen_hash)
  }
  if $module_hash != {} {
    validate_hash($module_hash)
    create_resources('apache::module', $module_hash)
  }
  if $vhost_hash != {} {
    validate_hash($vhost_hash)
    create_resources('apache::vhost', $vhost_hash)
  }
  if $virtualhost_hash != {} {
    validate_hash($virtualhost_hash)
    create_resources('apache::virtualhost', $virtualhost_hash)
  }

  ### Calculation of variables that dependes on arguments
  $vdir = $::operatingsystem ? {
    /(?i:Ubuntu|Debian|Mint)/ => "${apache::config_dir}/sites-available",
    'SLES'                    => "${apache::config_dir}/vhosts.d",
    default                   => "${apache::config_dir}/conf.d",
  }

  case $::operatingsystem {
    /(?i:Ubuntu)/ : {
      case $::lsbmajdistrelease {
        /14/ : {
          $dotconf_dir = "${apache::config_dir}/conf-available"
        }
        default: {
          $dotconf_dir = "${apache::config_dir}/conf.d"
        }
      }
    }
    /(?i:Debian)/ : {
      case $::lsbmajdistrelease {
        /8/ : {
          $dotconf_dir = "${apache::config_dir}/conf-available"
        }
        default: {
          $dotconf_dir = "${apache::config_dir}/conf.d"
        }
      }
    }
    default: {
      $dotconf_dir = "${apache::config_dir}/conf.d"
    }
  }

  ### Definition of some variables used in the module
  $manage_package = $apache::bool_absent ? {
    true  => 'absent',
    false => $apache::version ? {
        ''      => 'present',
        default => $apache::version,
    },
  }

  $manage_service_enable = $apache::bool_disableboot ? {
    true    => false,
    default => $apache::bool_disable ? {
      true    => false,
      default => $apache::bool_absent ? {
        true  => false,
        false => true,
      },
    },
  }

  $manage_service_ensure = $apache::bool_disable ? {
    true    => 'stopped',
    default =>  $apache::bool_absent ? {
      true    => 'stopped',
      default => 'running',
    },
  }

  $manage_service_autorestart = $apache::bool_service_autorestart ? {
    true    => 'Service[apache]',
    false   => undef,
  }

  $manage_file = $apache::bool_absent ? {
    true    => 'absent',
    default => 'present',
  }

  if $apache::bool_absent == true
  or $apache::bool_disable == true
  or $apache::bool_monitor == false
  or $apache::bool_disableboot == true {
    $manage_monitor = false
  } else {
    $manage_monitor = true
  }

  if $apache::bool_absent == true or $apache::bool_disable == true {
    $manage_firewall = false
  } else {
    $manage_firewall = true
  }

  $manage_audit = $apache::bool_audit_only ? {
    true  => 'all',
    false => undef,
  }

  $manage_file_replace = $apache::bool_audit_only ? {
    true  => false,
    false => true,
  }

  $manage_file_source = $apache::source ? {
    ''        => undef,
    default   => $apache::source,
  }

  $manage_file_content = $apache::template ? {
    ''        => undef,
    default   => template($apache::template),
  }

  ### Managed resources
  package { 'apache':
    ensure => $apache::manage_package,
    name   => $apache::package,
  }

  service { 'apache':
    ensure    => $apache::manage_service_ensure,
    name      => $apache::service,
    enable    => $apache::manage_service_enable,
    hasstatus => $apache::service_status,
    pattern   => $apache::process,
    require   => $service_requires,
  }

  file { 'apache.conf':
    ensure  => $apache::manage_file,
    path    => $apache::config_file,
    mode    => $apache::config_file_mode,
    owner   => $apache::config_file_owner,
    group   => $apache::config_file_group,
    require => Package['apache'],
    notify  => $apache::manage_service_autorestart,
    source  => $apache::manage_file_source,
    content => $apache::manage_file_content,
    replace => $apache::manage_file_replace,
    audit   => $apache::manage_audit,
  }

  # The whole apache configuration directory can be recursively overriden
  if $apache::source_dir and $apache::source_dir != '' {
    file { 'apache.dir':
      ensure  => directory,
      path    => $apache::config_dir,
      require => Package['apache'],
      notify  => $apache::manage_service_autorestart,
      source  => $apache::source_dir,
      recurse => true,
      purge   => $apache::bool_source_dir_purge,
      force   => $apache::bool_source_dir_purge,
      replace => $apache::manage_file_replace,
      audit   => $apache::manage_audit,
    }
  }

  if $apache::config_file_default_purge {
    apache::vhost { 'default':
      enable   => false,
      priority => '',
    }
  }

  ### Include custom class if $my_class is set
  if $apache::my_class and $apache::my_class != '' {
    include $apache::my_class
  }


  ### Provide puppi data, if enabled ( puppi => true )
  if $apache::bool_puppi == true {
    $classvars=get_class_args()
    puppi::ze { 'apache':
      ensure    => $apache::manage_file,
      variables => $classvars,
      helper    => $apache::puppi_helper,
    }
  }


  ### Service monitoring, if enabled ( monitor => true )
  if $apache::monitor_tool {
    monitor::port { "apache_${apache::protocol}_${apache::port}":
      protocol => $apache::protocol,
      port     => $apache::port,
      target   => $apache::monitor_target,
      tool     => $apache::monitor_tool,
      enable   => $apache::manage_monitor,
    }
    monitor::process { 'apache_process':
      process  => $apache::process,
      service  => $apache::service,
      pidfile  => $apache::pid_file,
      user     => $apache::process_user,
      argument => $apache::process_args,
      tool     => $apache::monitor_tool,
      enable   => $apache::manage_monitor,
    }
  }


  ### Firewall management, if enabled ( firewall => true )
  if $apache::bool_firewall == true {
    firewall { "apache_${apache::protocol}_${apache::port}":
      source      => $apache::firewall_src,
      destination => $apache::firewall_dst,
      protocol    => $apache::protocol,
      port        => $apache::port,
      action      => 'allow',
      direction   => 'input',
      tool        => $apache::firewall_tool,
      enable      => $apache::manage_firewall,
    }
  }


  ### Debugging, if enabled ( debug => true )
  if $apache::bool_debug == true {
    file { 'debug_apache':
      ensure  => $apache::manage_file,
      path    => "${settings::vardir}/debug-apache",
      mode    => '0640',
      owner   => 'root',
      group   => 'root',
      content => inline_template('<%= scope.to_hash.reject { |k,v| k.to_s =~ /(uptime.*|path|timestamp|free|.*password.*|.*psk.*|.*key)/ }.to_yaml %>'),
    }
  }
}