Puppet Class: mysql

Inherits:
mysql::params
Inherited by:
mysql::spec
Defined in:
manifests/init.pp

Overview

Class: mysql

This is the main mysql class

Parameters

Class specifi variables

root_password

The mysql password of the root user. If blank, no password is set If ‘auto’ a random password is generated

password_salt

Uses a salt with FQDN_RAND when generating the root password. If you do not use this, the password can be reverse engineered very easily. Example: $password_salt = ‘smeg’

Standard class parameters Define the general class behaviour and customizations

my_class

Name of a custom class to autoload to manage module’s customizations If defined, mysql class will automatically “include $my_class” Can be defined also by the (top scope) variable $mysql_myclass

source

Sets the content of source parameter for main configuration file If defined, mysql main config file will have the param: source => $source Can be defined also by the (top scope) variable $mysql_source

source_dir

If defined, the whole mysql configuration directory content is retrieved recursively from the specified source (source => $source_dir , recurse => true) Can be defined also by the (top scope) variable $mysql_source_dir

source_dir_purge

If set to true (default false) the existing configuration directory is mirrored with the content retrieved from source_dir (source => $source_dir , recurse => true , purge => true) Can be defined also by the (top scope) variable $mysql_source_dir_purge

template

Sets the path to the template to use as content for main configuration file If defined, mysql main config file has: content => content(“$template”) Note source and template parameters are mutually exclusive: don’t use both Can be defined also by the (top scope) variable $mysql_template

options

An hash of custom options to be used in templates for arbitrary settings. Can be defined also by the (top scope) variable $mysql_options

service_autorestart

Automatically restarts the mysql service when there is a change in configuration files. Default: true, Set to false if you don’t want to automatically restart the service.

service_manage

When you make HA with corosync/pacemaker for exemple, the mysql service status should be managed by corosync/pacemaker. Set this parameter to true allow you to tell puppet to not change mysql service status

version

The package version, used in the ensure parameter of package type. Default: present. Can be ‘latest’ or a specific version number. Note that if the argument absent (see below) is set to true, the package is removed, whatever the value of version parameter.

absent

Set to ‘true’ to remove package(s) installed by module Can be defined also by the (top scope) variable $mysql_absent

disable

Set to ‘true’ to disable service(s) managed by module Can be defined also by the (top scope) variable $mysql_disable

disableboot

Set to ‘true’ to disable service(s) at boot, without checks if it’s running Use this when the service is managed by a tool like a cluster software Can be defined also by the (top scope) variable $mysql_disableboot

monitor

Set to ‘true’ to enable monitoring of the services provided by the module Can be defined also by the (top scope) variables $mysql_monitor and $monitor

monitor_tool

Define which monitor tools (ad defined in Example42 monitor module) you want to use for mysql checks Can be defined also by the (top scope) variables $mysql_monitor_tool and $monitor_tool

monitor_target

The Ip address or hostname to use as a target for monitoring tools. Default is the fact $ipaddress Can be defined also by the (top scope) variables $mysql_monitor_target and $monitor_target

puppi

Set to ‘true’ to enable creation of module data files that are used by puppi Can be defined also by the (top scope) variables $mysql_puppi and $puppi

puppi_helper

Specify the helper to use for puppi commands. The default for this module is specified in params.pp and is generally a good choice. You can customize the output of puppi commands for this module using another puppi helper. Use the define puppi::helper to create a new custom helper Can be defined also by the (top scope) variables $mysql_puppi_helper and $puppi_helper

firewall

Set to ‘true’ to enable firewalling of the services provided by the module Can be defined also by the (top scope) variables $mysql_firewall and $firewall

firewall_tool

Define which firewall tool(s) (ad defined in Example42 firewall module) you want to use to open firewall for mysql port(s) Can be defined also by the (top scope) variables $mysql_firewall_tool and $firewall_tool

firewall_src

Define which source ip/net allow for firewalling mysql. Default: 0.0.0.0/0 Can be defined also by the (top scope) variables $mysql_firewall_src and $firewall_src

firewall_dst

Define which destination ip to use for firewalling. Default: $ipaddress Can be defined also by the (top scope) variables $mysql_firewall_dst and $firewall_dst

debug

Set to ‘true’ to enable modules debugging Can be defined also by the (top scope) variables $mysql_debug and $debug

audit_only

Set to ‘true’ if you don’t intend to override existing configuration files and want to audit the difference between existing files and the ones managed by Puppet. Can be defined also by the (top scope) variables $mysql_audit_only and $audit_only

Default class params - As defined in mysql::params. Note that these variables are mostly defined and used in the module itself, overriding the default values might not affected all the involved components. Set and override them only if you know what you’re doing. Note also that you can’t override/set them via top scope variables.

package

The name of mysql package

service

The name of mysql service

service_status

If the mysql service init script supports status argument

process

The name of mysql process

process_args

The name of mysql arguments. Used by puppi and monitor. Used only in case the mysql process name is generic (java, ruby…)

process_user

The name of the user mysql runs with. Used by puppi and monitor.

config_dir

Main configuration directory. Used by puppi

config_file

Main configuration file path

config_file_mode

Main configuration file path mode

config_file_owner

Main configuration file path owner

config_file_group

Main configuration file path group

config_file_init

Path of configuration file sourced by init script

pid_file

Path of pid file. Used by monitor

data_dir

Path of application data directory. Used by puppi

log_dir

Base logs directory. Used by puppi

log_file

Log file(s). Used by puppi

port

The listening port, if any, of the service. This is used by monitor, firewall and puppi (optional) components Note: This doesn’t necessarily affect the service configuration file Can be defined also by the (top scope) variable $mysql_port

protocol

The protocol used by the the service. This is used by monitor, firewall and puppi (optional) components Can be defined also by the (top scope) variable $mysql_protocol

Examples

You can use this class in 2 ways:

  • Set variables (at top scope level on in a ENC) and “include mysql”

  • Call mysql as a parametrized class

See README for details.

Author

Alessandro Franceschi <al@lab42.it/>

Parameters:

  • root_password (Any) (defaults to: params_lookup( 'root_password' ))
  • root_cnf_template (Any) (defaults to: params_lookup( 'root_cnf_template' ))
  • password_salt (Any) (defaults to: params_lookup( 'password_salt' ))
  • my_class (Any) (defaults to: params_lookup( 'my_class' ))
  • source (Any) (defaults to: params_lookup( 'source' ))
  • source_dir (Any) (defaults to: params_lookup( 'source_dir' ))
  • source_dir_purge (Any) (defaults to: params_lookup( 'source_dir_purge' ))
  • template (Any) (defaults to: params_lookup( 'template' ))
  • service_autorestart (Any) (defaults to: params_lookup( 'service_autorestart' , 'global' ))
  • service_manage (Any) (defaults to: params_lookup( 'service_manage' ))
  • options (Any) (defaults to: params_lookup( 'options' ))
  • version (Any) (defaults to: params_lookup( 'version' ))
  • absent (Any) (defaults to: params_lookup( 'absent' ))
  • disable (Any) (defaults to: params_lookup( 'disable' ))
  • disableboot (Any) (defaults to: params_lookup( 'disableboot' ))
  • monitor (Any) (defaults to: params_lookup( 'monitor' , 'global' ))
  • monitor_tool (Any) (defaults to: params_lookup( 'monitor_tool' , 'global' ))
  • monitor_target (Any) (defaults to: params_lookup( 'monitor_target' , 'global' ))
  • puppi (Any) (defaults to: params_lookup( 'puppi' , 'global' ))
  • puppi_helper (Any) (defaults to: params_lookup( 'puppi_helper' , 'global' ))
  • firewall (Any) (defaults to: params_lookup( 'firewall' , 'global' ))
  • firewall_tool (Any) (defaults to: params_lookup( 'firewall_tool' , 'global' ))
  • firewall_src (Any) (defaults to: params_lookup( 'firewall_src' , 'global' ))
  • firewall_dst (Any) (defaults to: params_lookup( 'firewall_dst' , 'global' ))
  • debug (Any) (defaults to: params_lookup( 'debug' , 'global' ))
  • audit_only (Any) (defaults to: params_lookup( 'audit_only' , 'global' ))
  • package (Any) (defaults to: params_lookup( 'package' ))
  • service (Any) (defaults to: params_lookup( 'service' ))
  • service_status (Any) (defaults to: params_lookup( 'service_status' ))
  • process (Any) (defaults to: params_lookup( 'process' ))
  • process_args (Any) (defaults to: params_lookup( 'process_args' ))
  • process_user (Any) (defaults to: params_lookup( 'process_user' ))
  • config_dir (Any) (defaults to: params_lookup( 'config_dir' ))
  • config_file (Any) (defaults to: params_lookup( 'config_file' ))
  • config_file_mode (Any) (defaults to: params_lookup( 'config_file_mode' ))
  • config_file_owner (Any) (defaults to: params_lookup( 'config_file_owner' ))
  • config_file_group (Any) (defaults to: params_lookup( 'config_file_group' ))
  • config_file_init (Any) (defaults to: params_lookup( 'config_file_init' ))
  • pid_file (Any) (defaults to: params_lookup( 'pid_file' ))
  • data_dir (Any) (defaults to: params_lookup( 'data_dir' ))
  • log_dir (Any) (defaults to: params_lookup( 'log_dir' ))
  • log_file (Any) (defaults to: params_lookup( 'log_file' ))
  • port (Any) (defaults to: params_lookup( 'port' ))
  • protocol (Any) (defaults to: params_lookup( 'protocol' ))
  • augeas_hash (Any) (defaults to: params_lookup( 'augeas_hash'))
  • grant_hash (Any) (defaults to: params_lookup( 'grant_hash'))
  • query_hash (Any) (defaults to: params_lookup( 'query_hash'))
  • queryfile_hash (Any) (defaults to: params_lookup( 'queryfile_hash'))
  • user_hash (Any) (defaults to: params_lookup( 'user_hash')) 


224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
 
# File 'manifests/init.pp', line 224

class mysql (
  $root_password       = params_lookup( 'root_password' ),
  $root_cnf_template   = params_lookup( 'root_cnf_template' ),
  $password_salt       = params_lookup( 'password_salt' ),
  $my_class            = params_lookup( 'my_class' ),
  $source              = params_lookup( 'source' ),
  $source_dir          = params_lookup( 'source_dir' ),
  $source_dir_purge    = params_lookup( 'source_dir_purge' ),
  $template            = params_lookup( 'template' ),
  $service_autorestart = params_lookup( 'service_autorestart' , 'global' ),
  $service_manage      = params_lookup( 'service_manage' ),
  $options             = params_lookup( 'options' ),
  $version             = params_lookup( 'version' ),
  $absent              = params_lookup( 'absent' ),
  $disable             = params_lookup( 'disable' ),
  $disableboot         = params_lookup( 'disableboot' ),
  $monitor             = params_lookup( 'monitor' , 'global' ),
  $monitor_tool        = params_lookup( 'monitor_tool' , 'global' ),
  $monitor_target      = params_lookup( 'monitor_target' , 'global' ),
  $puppi               = params_lookup( 'puppi' , 'global' ),
  $puppi_helper        = params_lookup( 'puppi_helper' , 'global' ),
  $firewall            = params_lookup( 'firewall' , 'global' ),
  $firewall_tool       = params_lookup( 'firewall_tool' , 'global' ),
  $firewall_src        = params_lookup( 'firewall_src' , 'global' ),
  $firewall_dst        = params_lookup( 'firewall_dst' , 'global' ),
  $debug               = params_lookup( 'debug' , 'global' ),
  $audit_only          = params_lookup( 'audit_only' , 'global' ),
  $package             = params_lookup( 'package' ),
  $service             = params_lookup( 'service' ),
  $service_status      = params_lookup( 'service_status' ),
  $process             = params_lookup( 'process' ),
  $process_args        = params_lookup( 'process_args' ),
  $process_user        = params_lookup( 'process_user' ),
  $config_dir          = params_lookup( 'config_dir' ),
  $config_file         = params_lookup( 'config_file' ),
  $config_file_mode    = params_lookup( 'config_file_mode' ),
  $config_file_owner   = params_lookup( 'config_file_owner' ),
  $config_file_group   = params_lookup( 'config_file_group' ),
  $config_file_init    = params_lookup( 'config_file_init' ),
  $pid_file            = params_lookup( 'pid_file' ),
  $data_dir            = params_lookup( 'data_dir' ),
  $log_dir             = params_lookup( 'log_dir' ),
  $log_file            = params_lookup( 'log_file' ),
  $port                = params_lookup( 'port' ),
  $protocol            = params_lookup( 'protocol' ),
  $augeas_hash         = params_lookup( 'augeas_hash'),
  $grant_hash          = params_lookup( 'grant_hash'),
  $query_hash          = params_lookup( 'query_hash'),
  $queryfile_hash      = params_lookup( 'queryfile_hash'),
  $user_hash           = params_lookup( 'user_hash'),
  ) inherits mysql::params {

  $bool_source_dir_purge=any2bool($source_dir_purge)
  $bool_service_autorestart=any2bool($service_autorestart)
  $bool_service_manage=any2bool($service_manage)
  $bool_absent=any2bool($absent)
  $bool_disable=any2bool($disable)
  $bool_disableboot=any2bool($disableboot)
  $bool_monitor=any2bool($monitor)
  $bool_puppi=any2bool($puppi)
  $bool_firewall=any2bool($firewall)
  $bool_debug=any2bool($debug)
  $bool_audit_only=any2bool($audit_only)

  ## Integration with Hiera
  if $augeas_hash != {} {
    validate_hash($augeas_hash)
    create_resources('mysql::augeas', $augeas_hash)
  }
  if $grant_hash != {} {
    validate_hash($grant_hash)
    create_resources('mysql::grant', $grant_hash)
  }
  if $query_hash != {} {
    validate_hash($query_hash)
    create_resources('mysql::query', $query_hash)
  }
  if $queryfile_hash != {} {
    validate_hash($queryfile_hash)
    create_resources('mysql::queryfile', $queryfile_hash)
  }
  if $user_hash != {} {
    validate_hash($user_hash)
    create_resources('mysql::user', $user_hash)
  }
  
  ### Root password setup
  $random_password = $mysql::password_salt ? {
    ''       => fqdn_rand(100000000000),
    default  => fqdn_rand(100000000000,$mysql::password_salt),
  }

  $real_root_password = $mysql::root_password ? {
    ''      => '',
    auto    => $random_password,
    default => $mysql::root_password,
  }

  ### Definition of some variables used in the module
  $manage_package = $mysql::bool_absent ? {
    true  => 'absent',
    false => $mysql::version,
  }

  $manage_service_enable = $mysql::bool_disableboot ? {
    true    => false,
    default => $mysql::bool_disable ? {
      true  => false,
      false => true,
    },
  }

  $manage_service_ensure = $mysql::bool_service_manage ? {
    true => $mysql::bool_disable ? {
      true  => 'stopped',
      false => 'running',
    },
    false => undef,
  }

  $manage_service_autorestart = $mysql::bool_service_autorestart ? {
    false => undef,
    true  => $mysql::bool_absent ? {
      true  => undef,
      false => 'Service[mysql]',
    },
  }

  $manage_file = $mysql::bool_absent ? {
    true    => 'absent',
    default => 'present',
  }

  if  $mysql::bool_absent == true or
      $mysql::bool_disable == true or
      $mysql::bool_disableboot == true {
    $manage_monitor = false
  } else {
    $manage_monitor = true
  }

  if $mysql::bool_absent == true or $mysql::bool_disable == true {
    $manage_firewall = false
  } else {
    $manage_firewall = true
  }

  $manage_audit = $mysql::bool_audit_only ? {
    true  => 'all',
    false => undef,
  }

  $manage_file_replace = $mysql::bool_audit_only ? {
    true  => false,
    false => true,
  }

  $manage_file_source = $mysql::source ? {
    ''        => undef,
    default   => $mysql::source,
  }

  $manage_file_content = $mysql::template ? {
    ''        => undef,
    default   => template($mysql::template),
  }

  # Set root password
  if $mysql::real_root_password != '' { include mysql::password }

  ### Managed resources
  package { 'mysql':
    ensure => $mysql::manage_package,
    name   => $mysql::package,
  }

  if $mysql::bool_absent == false {
    service { 'mysql':
      ensure    => $mysql::manage_service_ensure,
      name      => $mysql::service,
      enable    => $mysql::manage_service_enable,
      hasstatus => $mysql::service_status,
      pattern   => $mysql::process,
      require   => [ Package['mysql'] , File['mysql.conf'] ]
    }
  }

  file { 'mysql.conf':
    ensure  => $mysql::manage_file,
    path    => $mysql::config_file,
    mode    => $mysql::config_file_mode,
    owner   => $mysql::config_file_owner,
    group   => $mysql::config_file_group,
    require => Package['mysql'],
    notify  => $mysql::manage_service_autorestart,
    source  => $mysql::manage_file_source,
    content => $mysql::manage_file_content,
    replace => $mysql::manage_file_replace,
    audit   => $mysql::manage_audit,
  }

  # The whole mysql configuration directory can be recursively overriden
  if $mysql::source_dir {
    file { 'mysql.dir':
      ensure  => directory,
      path    => $mysql::config_dir,
      require => Package['mysql'],
      notify  => $mysql::manage_service_autorestart,
      source  => $mysql::source_dir,
      recurse => true,
      purge   => $mysql::bool_source_dir_purge,
      replace => $mysql::manage_file_replace,
      audit   => $mysql::manage_audit,
    }
  }


  ### Include custom class if $my_class is set
  if $mysql::my_class {
    include $mysql::my_class
  }

  ### Provide puppi data, if enabled ( puppi => true )
  if $mysql::bool_puppi == true {
    $classvars=get_class_args()
    puppi::ze { 'mysql':
      ensure    => $mysql::manage_file,
      variables => $classvars,
      helper    => $mysql::puppi_helper,
    }
  }


  ### Service monitoring, if enabled ( monitor => true )
  if $mysql::bool_monitor == true {
    monitor::process { 'mysql_process':
      process  => $mysql::process,
      service  => $mysql::service,
      pidfile  => $mysql::pid_file,
      user     => $mysql::process_user,
      argument => $mysql::process_args,
      tool     => $mysql::monitor_tool,
      enable   => $mysql::manage_monitor,
    }
  }


  ### Firewall management, if enabled ( firewall => true )
  if $mysql::bool_firewall == true {
    firewall { "mysql_${mysql::protocol}_${mysql::port}":
      source      => $mysql::firewall_src,
      destination => $mysql::firewall_dst,
      protocol    => $mysql::protocol,
      port        => $mysql::port,
      action      => 'allow',
      direction   => 'input',
      tool        => $mysql::firewall_tool,
      enable      => $mysql::manage_firewall,
    }
  }


  ### Debugging, if enabled ( debug => true )
  if $mysql::bool_debug == true {
    file { 'debug_mysql':
      ensure  => $mysql::manage_file,
      path    => "${settings::vardir}/debug-mysql",
      mode    => '0640',
      owner   => $mysql::config_file_owner,
      group   => $mysql::config_file_group,
      content => inline_template('<%= scope.to_hash.reject { |k,v| k.to_s =~ /(uptime.*|path|timestamp|free|.*password.*|.*psk.*|.*key)/ }.to_yaml %>'),
    }
  }

}