Puppet Class: inittab

Defined in:
manifests/init.pp

Overview

Class: inittab

Manage inittab

Parameters:

  • default_runlevel (Any) (defaults to: 'USE_DEFAULTS')
  • ensure_ttys1 (Any) (defaults to: undef)
  • file_mode (Any) (defaults to: '0644')
  • require_single_user_mode_password (Any) (defaults to: false)
  • enable_ctrlaltdel (Any) (defaults to: true)
  • ctrlaltdel_override_path (Any) (defaults to: 'USE_DEFAULTS')
  • ctrlaltdel_override_owner (Any) (defaults to: 'root')
  • ctrlaltdel_override_group (Any) (defaults to: 'root')
  • ctrlaltdel_override_mode (Any) (defaults to: '0644') 


5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
 
# File 'manifests/init.pp', line 5

class inittab (
  $default_runlevel                   = 'USE_DEFAULTS',
  $ensure_ttys1                       = undef,
  $file_mode                          = '0644',
  $require_single_user_mode_password  = false,
  $enable_ctrlaltdel                  = true,
  $ctrlaltdel_override_path           = 'USE_DEFAULTS',
  $ctrlaltdel_override_owner          = 'root',
  $ctrlaltdel_override_group          = 'root',
  $ctrlaltdel_override_mode           = '0644',
) {

  if $ensure_ttys1 {
    validate_re($ensure_ttys1,'^(present)|(absent)$',"inittab::ensure_ttys1 is ${ensure_ttys1} and if defined must be \'present\' or \'absent\'.")
  }

  validate_re($file_mode, '^[0-7]{4}$',
    "inittab::file_mode is <${file_mode}> and must be a valid four digit mode in octal notation.")

  if is_string($require_single_user_mode_password) {
    $require_single_user_mode_password_bool = str2bool($require_single_user_mode_password)
  } else {
    $require_single_user_mode_password_bool = $require_single_user_mode_password
  }
  validate_bool($require_single_user_mode_password_bool)

  if is_string($enable_ctrlaltdel) {
    $enable_ctrlaltdel_bool = str2bool($enable_ctrlaltdel)
  } else {
    $enable_ctrlaltdel_bool = $enable_ctrlaltdel
  }
  validate_bool($enable_ctrlaltdel_bool)

  validate_string($ctrlaltdel_override_owner)

  validate_string($ctrlaltdel_override_group)

  validate_re($ctrlaltdel_override_mode, '^[0-7]{4}$',
    "inittab::ctrlaltdel_override_mode is <${ctrlaltdel_override_mode}> and must be a valid four digit mode in octal notation.")

  case $::osfamily {
    'RedHat': {
      case $::operatingsystemrelease {
        /^5/: {
          $default_default_runlevel    = 3
          $template                    = 'inittab/el5.erb'
          $support_ctrlaltdel_override = false
          $systemd                     = false
        }
        /^6/: {
          $default_default_runlevel         = 3
          $template                         = 'inittab/el6.erb'
          $support_ctrlaltdel_override      = true
          $default_ctrlaltdel_override_path = '/etc/init/control-alt-delete.override'
          $systemd                          = false

          if $ensure_ttys1 {
            file { 'ttys1_conf':
              ensure => $ensure_ttys1,
              path   => '/etc/init/ttyS1.conf',
              source => 'puppet:///modules/inittab/ttyS1.conf',
              owner  => 'root',
              group  => 'root',
              mode   => '0644',
            }
          }

          if $ensure_ttys1 == 'present' {
            service { 'ttyS1':
              ensure     => running,
              hasstatus  => false,
              hasrestart => false,
              start      => '/sbin/initctl start ttyS1',
              stop       => '/sbin/initctl stop ttyS1',
              status     => '/sbin/initctl status ttyS1 | grep ^"ttyS1 start/running" 1>/dev/null 2>&1',
              require    => File['ttys1_conf'],
            }
          }
        }
        /^7/: {
          $default_default_runlevel    = 3
          $template                    = 'inittab/el7.erb'
          $support_ctrlaltdel_override = false
          $systemd                     = true
        }
        default: {
          fail("operatingsystemrelease is <${::operatingsystemrelease}> and inittab supports RedHat versions 5, 6 and 7.")
        }
      }
    }
    'Debian': {
      $support_ctrlaltdel_override = false
      $systemd                     = false

      if $::operatingsystem == 'Ubuntu' {

        $default_default_runlevel         = 3
        $template                         = 'inittab/ubuntu.erb'

      } else {

        case $::operatingsystemmajrelease {
          '6': {
            $default_default_runlevel = 2
            $template                 = 'inittab/debian6.erb'
          }
          default: {
            fail("operatingsystemmajrelease is <${::operatingsystemmajrelease}> and inittab supports Debian version 6.")
          }
        }
      }
    }
    'Solaris': {
      $support_ctrlaltdel_override = false
      $systemd                     = false

      case $::kernelrelease {
        '5.10': {
          $default_default_runlevel = 3
          $template                 = 'inittab/sol10.erb'
        }
        '5.11': {
          $default_default_runlevel = 3
          $template                 = 'inittab/sol11.erb'
        }
        default: {
          fail("kernelrelease is <${::kernelrelease}> and inittab supports Solaris versions 5.10 and 5.11.")
        }
      }
    }
    'Suse':{
      $support_ctrlaltdel_override = false
      $systemd                     = false

      case $::operatingsystemrelease {
        /^10/: {
          $default_default_runlevel = 3
          $template                 = 'inittab/suse10.erb'
        }
        /^11/: {
          $default_default_runlevel = 3
          $template                 = 'inittab/suse11.erb'
        }
        /^12/: {
          $default_default_runlevel = 3
          $template                 = 'inittab/suse12.erb'
        }
        default: {
          fail("operatingsystemrelease is <${::operatingsystemrelease}> and inittab supports Suse versions 10 and 11.")
        }
      }
    }
    default: {
      fail("osfamily is <${::osfamily}> and inittab module supports Debian, RedHat, Ubuntu, Suse and Solaris.")
    }
  }

  if $default_runlevel == 'USE_DEFAULTS' {
    $default_runlevel_real = $default_default_runlevel
  } else {
    $default_runlevel_real = $default_runlevel
  }

  # convert integer to string
  if type3x($default_runlevel_real) == 'integer' {
    $default_runlevel_real_string = "${default_runlevel_real}" # lint:ignore:only_variable_string
  }

  # validate default_runlevel_real
  validate_re($default_runlevel_real_string, '^[0-6sS]$',
    "default_runlevel <${default_runlevel_real}> does not match regex")

  if $enable_ctrlaltdel_bool == true {
    $ctrlaltdel_override_ensure = 'absent'
    $ctrlaltdel_target = '/lib/systemd/system/ctrl-alt-del.target'
  } else {
    $ctrlaltdel_override_ensure = 'file'
    $ctrlaltdel_target = '/dev/null'
  }

  if $::operatingsystem == 'Ubuntu' {
    file { 'rc-sysinit.override':
      ensure  => file,
      path    => '/etc/init/rc-sysinit.override',
      content => template($template),
      owner   => 'root',
      group   => 'root',
      mode    => '0644',
    }
  } else {
    file { 'inittab':
      ensure  => file,
      path    => '/etc/inittab',
      content => template($template),
      owner   => 'root',
      group   => 'root',
      mode    => $file_mode,
    }
  }

  if $systemd == true {
    case $default_runlevel_real {
      3: {
        $target = '/lib/systemd/system/multi-user.target'
      }
      5: {
        $target = '/lib/systemd/system/graphical.target'
      }
      default: {
        fail("default_runlevel for EL7 is <${default_runlevel_real}> and must be 3 or 5.")
      }
    }

    file { '/etc/systemd/system/default.target':
      ensure => 'link',
      target => $target,
    }

    file { '/etc/systemd/system/ctrl-alt-del.target':
      ensure => 'link',
      target => $ctrlaltdel_target,
    }
  }

  validate_bool($support_ctrlaltdel_override)

  if $support_ctrlaltdel_override == true {

    if $ctrlaltdel_override_path == 'USE_DEFAULTS' {
      $ctrlaltdel_override_path_real = $default_ctrlaltdel_override_path
    } else {
      $ctrlaltdel_override_path_real = $ctrlaltdel_override_path
    }
    validate_absolute_path($ctrlaltdel_override_path_real)

    if $systemd == false {
      file { 'ctrlaltdel_override':
        ensure  => $ctrlaltdel_override_ensure,
        path    => $ctrlaltdel_override_path_real,
        content => template('inittab/control-alt-delete.override.erb'),
        owner   => $ctrlaltdel_override_owner,
        group   => $ctrlaltdel_override_group,
        mode    => $ctrlaltdel_override_mode,
      }
    }
  }
}