Puppet Class: mysql::server

Inherits:
mysql::params
Defined in:
manifests/server.pp

Overview

Class: mysql::server: See README.md for documentation.

Parameters:

  • config_file (Any) (defaults to: $mysql::params::config_file)
  • includedir (Any) (defaults to: $mysql::params::includedir)
  • install_options (Any) (defaults to: undef)
  • manage_config_file (Any) (defaults to: $mysql::params::manage_config_file)
  • old_root_password (Any) (defaults to: $mysql::params::old_root_password)
  • override_options (Any) (defaults to: {})
  • package_ensure (Any) (defaults to: $mysql::params::server_package_ensure)
  • package_name (Any) (defaults to: $mysql::params::server_package_name)
  • purge_conf_dir (Any) (defaults to: $mysql::params::purge_conf_dir)
  • remove_default_accounts (Any) (defaults to: false)
  • restart (Any) (defaults to: $mysql::params::restart)
  • root_group (Any) (defaults to: $mysql::params::root_group)
  • root_password (Any) (defaults to: $mysql::params::root_password)
  • service_enabled (Any) (defaults to: $mysql::params::server_service_enabled)
  • service_manage (Any) (defaults to: $mysql::params::server_service_manage)
  • service_name (Any) (defaults to: $mysql::params::server_service_name)
  • service_provider (Any) (defaults to: $mysql::params::server_service_provider)
  • create_root_user (Any) (defaults to: $mysql::params::create_root_user)
  • create_root_my_cnf (Any) (defaults to: $mysql::params::create_root_my_cnf)
  • users (Any) (defaults to: {})
  • grants (Any) (defaults to: {})
  • databases (Any) (defaults to: {})
  • enabled (Any) (defaults to: undef)
  • manage_service (Any) (defaults to: undef) 


2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
 
# File 'manifests/server.pp', line 2

class mysql::server (
  $config_file             = $mysql::params::config_file,
  $includedir              = $mysql::params::includedir,
  $install_options         = undef,
  $manage_config_file      = $mysql::params::manage_config_file,
  $old_root_password       = $mysql::params::old_root_password,
  $override_options        = {},
  $package_ensure          = $mysql::params::server_package_ensure,
  $package_name            = $mysql::params::server_package_name,
  $purge_conf_dir          = $mysql::params::purge_conf_dir,
  $remove_default_accounts = false,
  $restart                 = $mysql::params::restart,
  $root_group              = $mysql::params::root_group,
  $root_password           = $mysql::params::root_password,
  $service_enabled         = $mysql::params::server_service_enabled,
  $service_manage          = $mysql::params::server_service_manage,
  $service_name            = $mysql::params::server_service_name,
  $service_provider        = $mysql::params::server_service_provider,
  $create_root_user        = $mysql::params::create_root_user,
  $create_root_my_cnf      = $mysql::params::create_root_my_cnf,
  $users                   = {},
  $grants                  = {},
  $databases               = {},

  # Deprecated parameters
  $enabled                 = undef,
  $manage_service          = undef
) inherits mysql::params {

  # Deprecated parameters.
  if $enabled {
    crit('This parameter has been renamed to service_enabled.')
    $real_service_enabled = $enabled
  } else {
    $real_service_enabled = $service_enabled
  }
  if $manage_service {
    crit('This parameter has been renamed to service_manage.')
    $real_service_manage = $manage_service
  } else {
    $real_service_manage = $service_manage
  }

  # Create a merged together set of options.  Rightmost hashes win over left.
  $options = mysql_deepmerge($mysql::params::default_options, $override_options)

  Class['mysql::server::root_password'] -> Mysql::Db <| |>

  include '::mysql::server::install'
  include '::mysql::server::config'
  include '::mysql::server::service'
  include '::mysql::server::root_password'
  include '::mysql::server::providers'

  if $remove_default_accounts {
    class { '::mysql::server::account_security':
      require => Anchor['mysql::server::end'],
    }
  }

  anchor { 'mysql::server::start': }
  anchor { 'mysql::server::end': }

  if $restart {
    Anchor['mysql::server::start'] ->
    Class['mysql::server::install'] ->
    # Only difference between the blocks is that we use ~> to restart if
    # restart is set to true.
    Class['mysql::server::config'] ~>
    Class['mysql::server::service'] ->
    Class['mysql::server::root_password'] ->
    Class['mysql::server::providers'] ->
    Anchor['mysql::server::end']
  } else {
    Anchor['mysql::server::start'] ->
    Class['mysql::server::install'] ->
    Class['mysql::server::config'] ->
    Class['mysql::server::service'] ->
    Class['mysql::server::root_password'] ->
    Class['mysql::server::providers'] ->
    Anchor['mysql::server::end']
  }


}