Puppet Class: icingaweb2::module::icingadb
- Defined in:
- manifests/module/icingadb.pp
Summary
Manages the icingadb module. This module is still optional at the moment.Overview
Note:
At first have a look at the [IcingaDB module documentation](icinga.com/docs/icinga-db/latest/doc/01-About/).
122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 |
# File 'manifests/module/icingadb.pp', line 122
class icingaweb2::module::icingadb (
String $package_name,
Icingaweb2::Secret $db_password,
Enum['absent', 'present'] $ensure = 'present',
Enum['mysql', 'pgsql'] $db_type = 'mysql',
Stdlib::Host $db_host = 'localhost',
Optional[Stdlib::Port] $db_port = undef,
String $db_name = 'icingadb',
String $db_username = 'icingadb',
Optional[String] $db_charset = undef,
Optional[Boolean] $db_use_tls = undef,
Optional[String] $db_tls_cert = undef,
Optional[Icingaweb2::Secret] $db_tls_key = undef,
Optional[String] $db_tls_cacert = undef,
Optional[Stdlib::Absolutepath] $db_tls_cert_file = undef,
Optional[Stdlib::Absolutepath] $db_tls_key_file = undef,
Optional[Stdlib::Absolutepath] $db_tls_cacert_file = undef,
Optional[Stdlib::Absolutepath] $db_tls_capath = undef,
Optional[Boolean] $db_tls_noverify = undef,
Optional[String] $db_tls_cipher = undef,
Stdlib::Host $redis_host = 'localhost',
Optional[Stdlib::Port] $redis_port = undef,
Optional[Icingaweb2::Secret] $redis_password = undef,
Stdlib::Host $redis_primary_host = $redis_host,
Optional[Stdlib::Port] $redis_primary_port = $redis_port,
Optional[Icingaweb2::Secret] $redis_primary_password = $redis_password,
Optional[Stdlib::Host] $redis_secondary_host = undef,
Optional[Stdlib::Port] $redis_secondary_port = undef,
Optional[Icingaweb2::Secret] $redis_secondary_password = undef,
Optional[Boolean] $redis_use_tls = undef,
Optional[String] $redis_tls_cert = undef,
Optional[Icingaweb2::Secret] $redis_tls_key = undef,
Optional[String] $redis_tls_cacert = undef,
Optional[Stdlib::Absolutepath] $redis_tls_cert_file = undef,
Optional[Stdlib::Absolutepath] $redis_tls_key_file = undef,
Optional[Stdlib::Absolutepath] $redis_tls_cacert_file = undef,
Hash[String, Any] $settings = {},
Hash[String, Hash] $commandtransports = {},
) {
icingaweb2::assert_module()
$conf_dir = $icingaweb2::globals::conf_dir
$module_conf_dir = "${conf_dir}/modules/icingadb"
if $redis_use_tls {
$redis_tls_files = icingaweb2::cert::files(
'redis',
$module_conf_dir,
$redis_tls_key_file,
$redis_tls_cert_file,
$redis_tls_cacert_file,
$redis_tls_key,
$redis_tls_cert,
$redis_tls_cacert,
)
$redis_settings = delete_undef_values({
tls => true,
cert => $redis_tls_files['cert_file'],
key => $redis_tls_files['key_file'],
ca => $redis_tls_files['cacert_file'],
})
icingaweb2::tls::client { 'icingaweb2::module::icingadb redis client tls config':
args => $redis_tls_files,
}
} else {
$redis_settings = {}
}
$_settings = {
'icingaweb2-module-icingadb-config' => {
'section_name' => 'icingadb',
'target' => "${module_conf_dir}/config.ini",
'settings' => {
resource => 'icingaweb2-module-icingadb',
},
},
'icingaweb2-module-icingadb-redis' => {
'section_name' => 'redis',
'target' => "${module_conf_dir}/config.ini",
'settings' => $redis_settings,
},
'icingaweb2-module-icingadb-redis1' => {
'section_name' => 'redis1',
'target' => "${module_conf_dir}/redis.ini",
'settings' => delete_undef_values({
host => $redis_primary_host,
port => $redis_primary_port,
password => $redis_primary_password,
}),
},
'icingaweb2-module-icingadb-redis2' => {
'section_name' => 'redis2',
'target' => "${module_conf_dir}/redis.ini",
'settings' => delete_undef_values({
host => $redis_secondary_host,
port => $redis_secondary_port,
password => $redis_secondary_password,
}),
},
'icingaweb2-module-icingadb-settings' => {
'section_name' => 'settings',
'target' => "${module_conf_dir}/config.ini",
'settings' => delete_undef_values($settings),
},
}
$db_tls = merge(delete($icingaweb2::config::tls, ['key', 'cert', 'cacert']), delete_undef_values(merge(icingaweb2::cert::files(
'client',
$module_conf_dir,
$db_tls_key_file,
$db_tls_cert_file,
$db_tls_cacert_file,
$db_tls_key,
$db_tls_cert,
$db_tls_cacert,
), {
capath => $db_tls_capath,
noverify => $db_tls_noverify,
cipher => $db_tls_cipher,
})))
icingaweb2::tls::client { 'icingaweb2::module::icingadb tls client config':
args => $db_tls,
}
icingaweb2::resource::database { 'icingaweb2-module-icingadb':
type => $db_type,
host => $db_host,
port => pick($db_port, $icingaweb2::globals::port[$db_type]),
database => $db_name,
username => $db_username,
password => $db_password,
charset => $db_charset,
use_tls => $db_use_tls,
tls_noverify => $db_tls['noverify'],
tls_key => $db_tls['key_file'],
tls_cert => $db_tls['cert_file'],
tls_cacert => $db_tls['cacert_file'],
tls_capath => $db_tls['capath'],
tls_cipher => $db_tls['cipher'],
}
create_resources('icingaweb2::module::icingadb::commandtransport', $commandtransports)
icingaweb2::module { 'icingadb':
ensure => $ensure,
install_method => 'package',
package_name => $package_name,
settings => $_settings,
}
}
|