Puppet Class: icingaweb2::module::monitoring
- Defined in:
- manifests/module/monitoring.pp
Summary
Manages the monitoring module. This module is mandatory for probably every setup.Overview
Requirements:
* IDO feature in Icinga 2 (MySQL or PostgreSQL)
* `ApiUser` object in Icinga 2 with proper permissions
class {'icingaweb2::module::monitoring':
ido_host => 'localhost',
ido_type => 'mysql',
ido_db_name => 'icinga2',
ido_db_username => 'icinga2',
ido_db_password => 'supersecret',
commandtransports => {
icinga2 => {
transport => 'api',
username => 'icingaweb2',
password => 'supersecret',
}
}
}
Note:
At first have a look at the [Monitoring module documentation](www.icinga.com/docs/icingaweb2/latest/modules/monitoring/doc/01-About/).
99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 |
# File 'manifests/module/monitoring.pp', line 99
class icingaweb2::module::monitoring (
Enum['absent', 'present'] $ensure = 'present',
Variant[String, Array[String]] $protected_customvars = ['*pw*', '*pass*', 'community'],
Enum['mysql', 'pgsql'] $ido_type = 'mysql',
Boolean $manage_package = true,
Optional[Stdlib::Host] $ido_host = undef,
Optional[Stdlib::Port] $ido_port = undef,
Optional[String] $ido_db_name = undef,
Optional[String] $ido_db_username = undef,
Optional[Icingaweb2::Secret] $ido_db_password = undef,
Optional[String] $ido_db_charset = undef,
Optional[Boolean] $use_tls = undef,
Optional[Stdlib::Absolutepath] $tls_key_file = undef,
Optional[Stdlib::Absolutepath] $tls_cert_file = undef,
Optional[Stdlib::Absolutepath] $tls_cacert_file = undef,
Optional[Stdlib::Absolutepath] $tls_capath = undef,
Optional[Icingaweb2::Secret] $tls_key = undef,
Optional[String] $tls_cert = undef,
Optional[String] $tls_cacert = undef,
Optional[Boolean] $tls_noverify = undef,
Optional[String] $tls_cipher = undef,
Hash[String, Any] $settings = {},
Hash $commandtransports = {},
) {
icingaweb2::assert_module()
$conf_dir = $icingaweb2::globals::conf_dir
$module_conf_dir = "${conf_dir}/modules/monitoring"
case $facts['os']['family'] {
'Debian': {
if $manage_package {
$install_method = 'package'
$package_name = 'icingaweb2-module-monitoring'
} else {
$install_method = 'none'
$package_name = undef
}
}
default: {
$install_method = 'none'
$package_name = undef
}
}
$tls = merge(delete($icingaweb2::config::tls, ['key', 'cert', 'cacert']), delete_undef_values(merge(icingaweb2::cert::files(
'client',
$module_conf_dir,
$tls_key_file,
$tls_cert_file,
$tls_cacert_file,
$tls_key,
$tls_cert,
$tls_cacert,
), {
capath => $tls_capath,
noverify => $tls_noverify,
cipher => $tls_cipher,
})))
icingaweb2::tls::client { 'icingaweb2::module::monitoring tls client config':
args => $tls,
}
icingaweb2::resource::database { 'icingaweb2-module-monitoring':
type => $ido_type,
host => $ido_host,
port => pick($ido_port, $icingaweb2::globals::port[$ido_type]),
database => $ido_db_name,
username => $ido_db_username,
password => $ido_db_password,
charset => $ido_db_charset,
use_tls => $use_tls,
tls_noverify => $tls['noverify'],
tls_key => $tls['key_file'],
tls_cert => $tls['cert_file'],
tls_cacert => $tls['cacert_file'],
tls_capath => $tls['capath'],
tls_cipher => $tls['cipher'],
}
$backend_settings = {
'type' => 'ido',
'resource' => 'icingaweb2-module-monitoring',
}
$security_settings = {
'protected_customvars' => $protected_customvars ? {
String => $protected_customvars,
Array[String] => join($protected_customvars, ','),
},
}
$_settings = {
'module-monitoring-backends' => {
'section_name' => 'backends',
'target' => "${module_conf_dir}/backends.ini",
'settings' => delete_undef_values($backend_settings),
},
'module-monitoring-security' => {
'section_name' => 'security',
'target' => "${module_conf_dir}/config.ini",
'settings' => delete_undef_values($security_settings),
},
'module-monitoring-general' => {
'section_name' => 'settings',
'target' => "${module_conf_dir}/config.ini",
'settings' => delete_undef_values($settings),
},
}
create_resources('icingaweb2::module::monitoring::commandtransport', $commandtransports)
icingaweb2::module { 'monitoring':
ensure => $ensure,
install_method => $install_method,
package_name => $package_name,
settings => $_settings,
}
}
|