Puppet Class: clickhouse::client

Inherits:
clickhouse
Defined in:
manifests/client.pp

Summary

ClickHouse client class

Overview

The class installs clickhouse-client.

Examples:

Simple use

include clickhouse::client

Use with params

class { 'clickhouse::client':
  package_name   => 'clickhouse-client-custom',
  package_ensure => 'hold',
  user           => 'custom-user',
  config_d_dir   => '/some/path',
}

Parameters:

  • package_name (String[1]) (defaults to: 'clickhouse-client') —

    Package to be installed.

  • package_ensure (String[1]) (defaults to: 'installed') —

    Client package ‘ensure`. See `ensure` attribute for `package` resource.

  • conf_d_dir (Optional[Stdlib::Unixpath]) (defaults to: undef) —

    Deprecated, use config_d_dir.

  • config_d_dir (Stdlib::Unixpath) (defaults to: $conf_d_dir ? { undef => '/etc/clickhouse-client/config.d', default => $conf_d_dir) —

    Directory for custom configs. Unmanaged configs will be removed from the dirrectory during puppet running.

Author:

  • InnoGames GmbH



27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
 
# File 'manifests/client.pp', line 27

class clickhouse::client(
    String[1]                  $package_name   = 'clickhouse-client',
    String[1]                  $package_ensure = 'installed',
    Optional[Stdlib::Unixpath] $conf_d_dir     = undef,
    Stdlib::Unixpath           $config_d_dir   = $conf_d_dir ? {
        undef   => '/etc/clickhouse-client/config.d',
        default => $conf_d_dir,
    },
) inherits clickhouse {

    package { $package_name:
        ensure => $package_ensure,
    }

    # TODO: remove it in 3 releases
    if ($conf_d_dir) {
        notify { 'conf_d deprecation':
            message  => @("END")
                Parameter conf_d_dir is deprecated, use config_d_dir
                Be aware that after remove it the ${conf_d_dir} will be removed as well, you shouldn't use it.
                See https://clickhouse.yandex/docs/en/operations/configuration_files
                | END
            ,
            loglevel => 'warning',
        }

        file { $conf_d_dir:
            ensure  => 'directory',
            require => Package[$package_name],
        }

    } else {
        file { '/etc/clickhouse-client/conf.d':
            ensure => 'absent',
        }

        file { $config_d_dir:
            ensure  => 'directory',
            recurse => true,
            purge   => true,
            force   => true,
            require => Package[$package_name],
        }
    }
}