Puppet Class: clickhouse::server

Inherits:
clickhouse
Inherited by:
clickhouse::server::config::memory
clickhouse::server::config::zookeeper
clickhouse::server::config::default_localhost
Defined in:
manifests/server.pp

Summary

ClickHouse server class

Overview

The class installs ClickHouse server and manages service

Examples:

Simple use

include clickhouse::server

Use with params

class { 'clickhouse::server':
  package_name   => 'clickhouse-server-custom',
  package_ensure => 'latest',
  service_name   => 'clickhouse-server',
  service_ensure => false,
  service_enable => false,
}

Parameters:

  • package_name (String[1]) (defaults to: 'clickhouse-server') —

    Server package to be installed.

  • package_ensure (String[1]) (defaults to: 'installed') —

    Server package ensure. See ‘ensure` attribute for `package` resource.

  • service_name (String[1]) (defaults to: $package_name) —

    Name of the managed service for clickhouse-server.

  • service_ensure (Variant[Boolean, Enum[ 'running', 'stopped' ]]) (defaults to: 'running') —

    Desired state for ‘$service_name`, see `ensure` for `service` resource.

  • service_enable (Variant[Boolean, Enum[ 'manual', 'mask' ]]) (defaults to: true) —

    If ‘$service_name` should be enabled, see `enable` for `service` resource.

  • config_service_notify (Boolean) (defaults to: true) —

    If true, every config managed by this module and requires for server restart will trigger service refresh.

  • conf_dir (Optional[Stdlib::Unixpath]) (defaults to: undef) —

    Deprecated, use config_dir

  • config_dir (Stdlib::Unixpath) (defaults to: $conf_dir ? { undef => '/etc/clickhouse-server', default => $conf_d_dir) —

    Directory with clickhouse-server configuration.

  • conf_d_dir (Optional[Stdlib::Unixpath]) (defaults to: undef) —

    Deprecated, use config_d_dir

  • config_d_dir (Stdlib::Unixpath) (defaults to: $conf_d_dir ? { undef => "${config_dir}/config.d", default => $conf_d_dir) —

    Directory with clickhouse-server included configuration. Unmanaged configs will be removed from the directory during puppet run.

  • users_d_dir (Stdlib::Unixpath) (defaults to: "${config_dir}/users.d") —

    Directory with clickhouse-server users configuration. Unmanaged configs will be removed from the directory during puppet run.

Author:

  • InnoGames GmbH



42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
 
# File 'manifests/server.pp', line 42

class clickhouse::server (
    String[1]                  $package_name          = 'clickhouse-server',
    String[1]                  $package_ensure        = 'installed',
    String[1]                  $service_name          = $package_name,
    Variant[Boolean, Enum[
        'running',
        'stopped'
    ]]                         $service_ensure        = 'running',
    Variant[Boolean, Enum[
        'manual',
        'mask'
    ]]                         $service_enable        = true,
    Boolean                    $config_service_notify = true,
    Optional[Stdlib::Unixpath] $conf_dir              = undef,
    Stdlib::Unixpath           $config_dir            = $conf_dir ? {
        undef   => '/etc/clickhouse-server',
        default => $conf_d_dir,
    },
    Optional[Stdlib::Unixpath] $conf_d_dir            = undef,
    Stdlib::Unixpath           $config_d_dir          = $conf_d_dir ? {
        undef   => "${config_dir}/config.d",
        default => $conf_d_dir,
    },
    Stdlib::Unixpath           $users_d_dir           = "${config_dir}/users.d",
) inherits clickhouse {

    # TODO: remove it in 3 releases
    if ($conf_d_dir) {
        notify { 'conf_d deprecation':
            message  => @("END")
                Parameter conf_d_dir is deprecated, use config_d_dir
                Be aware that after remove it the ${conf_d_dir} will be removed as well, you shouldn't use it.
                See https://clickhouse.yandex/docs/en/operations/configuration_files
                | END
            ,
            loglevel => 'warning',
        }

        file { $conf_d_dir:
            ensure  => 'directory',
            recurse => true,
            purge   => true,
            force   => true,
            owner   => $clickhouse::user,
            group   => $clickhouse::group,
            require => Package[$package_name],
        }
    } else {
        file { "${config_dir}/conf.d":
            ensure => 'absent',
        }

        file { $config_d_dir:
            ensure  => 'directory',
            recurse => true,
            purge   => true,
            force   => true,
            owner   => $clickhouse::user,
            group   => $clickhouse::group,
            require => Package[$package_name],
        }
    }

    package { $package_name:
        ensure => $package_ensure,
    }

    file { $users_d_dir:
        ensure  => 'directory',
        recurse => true,
        purge   => true,
        force   => true,
        owner   => $clickhouse::user,
        group   => $clickhouse::group,
        require => Package[$package_name],
    }

    service { $service_name:
        ensure    => $service_ensure,
        enable    => $service_enable,
        subscribe => Package[$package_name],
    }
}