Puppet Class: prometheus::blackbox_exporter_etcd

Defined in:
manifests/blackbox_exporter_etcd.pp

Overview

exporter_# Sets up a blackbox exporter to forward etcd metrics from etcd nodes

Parameters:

  • download_url (String) (defaults to: 'https://github.com/jetstack-experimental/blackbox_exporter/releases/download/v#VERSION#/blackbox_exporter_#VERSION#_linux_amd64')
  • version (String) (defaults to: '0.4.0-jetstack')
  • config_dir (String) (defaults to: '/etc/blackbox_exporter')
  • port (Integer) (defaults to: 9115) 


2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
 
# File 'manifests/blackbox_exporter_etcd.pp', line 2

class prometheus::blackbox_exporter_etcd (
  String $download_url = 'https://github.com/jetstack-experimental/blackbox_exporter/releases/download/v#VERSION#/blackbox_exporter_#VERSION#_linux_amd64',
  String $version = '0.4.0-jetstack',
  String $config_dir = '/etc/blackbox_exporter',
  Integer $port = 9115,
)
{
  include ::prometheus

  $dest_dir = "/opt/blackbox_exporter-${version}"
  $systemd_path = $::prometheus::systemd_path

  $etcd_k8s_main_port = $::prometheus::etcd_k8s_main_port
  $etcd_k8s_events_port = $::prometheus::etcd_k8s_events_port
  $etcd_overlay_port = $::prometheus::etcd_overlay_port

  # Setup scrapes and rules for blackbox_etcd
  if $::prometheus::role == 'master' {
    include ::prometheus::server

    $blackbox_exporters = $::prometheus::etcd_cluster.map |$node| { "${node}:${port}" }

    prometheus::scrape_config { 'etcd-k8s-main':
      order  =>  140,
      config => {
        'metrics_path'    => '/probe',
        'params'          => { 'module' => ['etcd_k8s_main_proxy'] },
        'static_configs'  => [{
          'targets' => $blackbox_exporters,
          'labels'  => {'role' => 'etcd'},
        }],
        'relabel_configs' => [{
          'source_labels' => [],
          'regex'         => '(.*)',
          'target_label'  => '__param_target',
          'replacement'   => "https://127.0.0.1:${etcd_k8s_main_port}/metrics",
        }],
      }
    }

    prometheus::scrape_config { 'etcd-k8s-events':
      order  =>  150,
      config => {
        'metrics_path'    => '/probe',
        'params'          => { 'module' => ['etcd_k8s_events_proxy'] },
        'static_configs'  => [{
          'targets' => $blackbox_exporters,
          'labels'  => {'role' => 'etcd'},
        }],
        'relabel_configs' => [{
          'source_labels' => [],
          'regex'         => '(.*)',
          'target_label'  => '__param_target',
          'replacement'   => "https://127.0.0.1:${etcd_k8s_events_port}/metrics",
        }],
      }
    }

    prometheus::scrape_config { 'etcd-overlay':
      order  =>  160,
      config => {
        'metrics_path'    => '/probe',
        'params'          => { 'module' => ['etcd_overlay_proxy'] },
        'static_configs'  => [{
          'targets' => $blackbox_exporters,
          'labels'  => {'role' => 'etcd'},
        }],
        'relabel_configs' => [{
          'source_labels' => [],
          'regex'         => '(.*)',
          'target_label'  => '__param_target',
          'replacement'   => "https://127.0.0.1:${etcd_overlay_port}/metrics",
        }],
      }
    }

    prometheus::rule { 'EtcdDown':
      # TODO: we should limit this on the etcd jobs
      expr        => '(probe_success !=1 AND probe_success{instance=~".*etcd.*"})',
      for         => '2m',
      summary     => '{{$labels.instance}}: etcd server probe failed',
      description => '{{$labels.instance}}: etcd server probe failed for {{$labels.job}}',
      order       => 10,
    }

    prometheus::rule { 'EtcdNoLeader':
      # TODO: we should limit this on the etcd jobs
      expr        => '(etcd_server_has_leader != 1)',
      for         => '2m',
      summary     => '{{$labels.instance}}: etcd server has no leader',
      description => '{{$labels.instance}}: etcd cluster server has no leader',
      order       => 10,
    }
  }

  # Setup blackbox service on etcd nodes
  if $::prometheus::role == 'etcd' {
    $_download_url = regsubst($download_url, '#VERSION#' ,$version , 'G')

    file { $dest_dir:
      ensure => directory,
      mode   => '0755',
    }
    -> archive { "${dest_dir}/blackbox_exporter":
      ensure   => present,
      extract  => false,
      source   => $_download_url,
      provider => 'airworthy',
    }

    file { $config_dir:
      ensure => directory,
      mode   => '0755',
    }
    -> file { "${config_dir}/blackbox_exporter.yaml":
      ensure  => file,
      content => template('prometheus/blackbox_exporter.yaml.erb'),
    }

    file { "${systemd_path}/blackbox-exporter.service":
      ensure  => file,
      content => template('prometheus/blackbox_exporter.service.erb'),
    }
    ~> exec { "${module_name}-systemctl-daemon-reload":
      command     => '/usr/bin/systemctl daemon-reload',
      refreshonly => true,
    }

    service { 'blackbox-exporter':
      ensure    => running,
      enable    => true,
      subscribe => [
        Archive["${dest_dir}/blackbox_exporter"],
        File["${config_dir}/blackbox_exporter.yaml"],
        File["${systemd_path}/blackbox-exporter.service"]
      ],
    }
  }
}