Defined Type: nginx::resource::vhost

Defined in:
manifests/resource/vhost.pp

Overview

define: nginx::resource::vhost

This definition creates a virtual host

Parameters:

[*ensure*]              - Enables or disables the specified vhost
  (present|absent)
[*listen_ip*]           - Default IP Address for NGINX to listen with this
  vHost on. Defaults to all interfaces (*)
[*listen_port*]         - Default IP Port for NGINX to listen with this
  vHost on. Defaults to TCP 80
[*listen_options*]      - Extra options for listen directive like
  'default' to catchall. Undef by default.
[*listen_unix_socket_enable*] - BOOL value to enable/disable UNIX socket
  listening support (false|true).
[*listen_unix_socket*]  - Default unix socket for NGINX to listen with this
  vHost on. Defaults to UNIX /var/run/nginx.sock
[*listen_unix_socket_options*] - Extra options for listen directive like
  'default' to catchall. Undef by default.
[*location_allow*]      - Array: Locations to allow connections from.
[*location_deny*]       - Array: Locations to deny connections from.
[*ipv6_enable*]         - BOOL value to enable/disable IPv6 support
  (false|true). Module will check to see if IPv6 support exists on your
  system before enabling.
[*ipv6_listen_ip*]      - Default IPv6 Address for NGINX to listen with
  this vHost on. Defaults to all interfaces (::)
[*ipv6_listen_port*]    - Default IPv6 Port for NGINX to listen with this
  vHost on. Defaults to TCP 80
[*ipv6_listen_options*] - Extra options for listen directive like 'default'
  to catchall. Template will allways add ipv6only=on. While issue
  jfryman/puppet-nginx#30 is discussed, default value is 'default'.
[*add_header*]          - Hash: Adds headers to the HTTP response when
  response code is equal to 200, 204, 301, 302 or 304.
[*index_files*]         - Default index files for NGINX to read when
  traversing a directory
[*autoindex*]           - Set it on 'on' or 'off 'to activate/deactivate
                          autoindex directory listing. Undef by default.
[*proxy*]               - Proxy server(s) for the root location to connect
  to.  Accepts a single value, can be used in conjunction with
  nginx::resource::upstream
[*proxy_read_timeout*]  - Override the default the proxy read timeout value
  of 90 seconds
[*proxy_redirect*]      - Override the default proxy_redirect value of off.
[*resolver*]            - Array: Configures name servers used to resolve
  names of upstream servers into addresses.
[*fastcgi*]             - location of fastcgi (host:port)
[*fastcgi_params*]      - optional alternative fastcgi_params file to use
[*fastcgi_script*]      - optional SCRIPT_FILE parameter
[*ssl*]                 - Indicates whether to setup SSL bindings for this
  vhost.
[*ssl_cert*]            - Pre-generated SSL Certificate file to reference
  for SSL Support. This is not generated by this module.
[*ssl_client_cert*]     - Pre-generated SSL Certificate file to reference
  for client verify SSL Support. This is not generated by this module.
[*ssl_crl*]             - String: Specifies CRL path in file system
[*ssl_dhparam*]         - This directive specifies a file containing
  Diffie-Hellman key agreement protocol cryptographic parameters, in PEM
  format, utilized for exchanging session keys between server and client.
[*ssl_key*]             - Pre-generated SSL Key file to reference for SSL
  Support. This is not generated by this module.
[*ssl_port*]            - Default IP Port for NGINX to listen with this SSL
  vHost on. Defaults to TCP 443
[*ssl_protocols*]       - SSL protocols enabled. Defaults to 'TLSv1 TLSv1.1
  TLSv1.2'.
[*ssl_buffer_size*]     - Sets the size of the buffer used for sending data.
[*ssl_ciphers*]         - SSL ciphers enabled. Defaults to
  'ECDHE-RSA-AES128-GCM-SHA256:ECDHE-ECDSA-AES128-GCM-SHA256:ECDHE-RSA-AES256-GCM-SHA384:ECDHE-ECDSA-AES256-GCM-SHA384:DHE-RSA-AES128-GCM-SHA256:DHE-DSS-AES128-GCM-SHA256:kEDH+AESGCM:ECDHE-RSA-AES128-SHA256:ECDHE-ECDSA-AES128-SHA256:ECDHE-RSA-AES128-SHA:ECDHE-ECDSA-AES128-SHA:ECDHE-RSA-AES256-SHA384:ECDHE-ECDSA-AES256-SHA384:ECDHE-RSA-AES256-SHA:ECDHE-ECDSA-AES256-SHA:DHE-RSA-AES128-SHA256:DHE-RSA-AES128-SHA:DHE-DSS-AES128-SHA256:DHE-RSA-AES256-SHA256:DHE-DSS-AES256-SHA:DHE-RSA-AES256-SHA:AES128-GCM-SHA256:AES256-GCM-SHA384:AES128-SHA256:AES256-SHA256:AES128-SHA:AES256-SHA:AES:CAMELLIA:DES-CBC3-SHA:!aNULL:!eNULL:!EXPORT:!DES:!RC4:!MD5:!PSK:!aECDH:!EDH-DSS-DES-CBC3-SHA:!EDH-RSA-DES-CBC3-SHA:!KRB5-DES-CBC3-SHA'.
[*ssl_stapling*]        - Bool: Enables or disables stapling of OCSP
  responses by the server. Defaults to false.
[*ssl_stapling_file*]   - String: When set, the stapled OCSP response
  will be taken from the specified file instead of querying the OCSP
  responder specified in the server certificate.
[*ssl_stapling_responder*] - String: Overrides the URL of the OCSP
  responder specified in the Authority Information Access certificate
  extension.
[*ssl_stapling_verify*] - Bool: Enables or disables verification of
  OCSP responses by the server. Defaults to false.
[*ssl_session_timeout*] - String: Specifies a time during which a client
  may reuse the session parameters stored in a cache. Defaults to 5m.
[*ssl_trusted_cert*]    - String: Specifies a file with trusted CA
  certificates in the PEM format used to verify client certificates and
  OCSP responses if ssl_stapling is enabled.
[*spdy*]                - Toggles SPDY protocol.
[*http2*]               - Toggles HTTP/2 protocol.
[*server_name*]         - List of vhostnames for which this vhost will
  respond. Default [$name].
[*www_root*]            - Specifies the location on disk for files to be
  read from. Cannot be set in conjunction with $proxy
[*rewrite_www_to_non_www*]  - Adds a server directive and rewrite rule to
  rewrite www.domain.com to domain.com in order to avoid duplicate
  content (SEO);
[*try_files*]               - Specifies the locations for files to be
  checked as an array. Cannot be used in conjuction with $proxy.
[*proxy_cache*]             - This directive sets name of zone for caching.
  The same zone can be used in multiple places.
[*proxy_cache_key*]     - Override the default proxy_cache_key of
  $scheme$proxy_host$request_uri
[*proxy_cache_use_stale*] - Override the default proxy_cache_use_stale value
  of off.
[*proxy_cache_valid*]       - This directive sets the time for caching
  different replies.
[*proxy_method*]            - If defined, overrides the HTTP method of the
  request to be passed to the backend.
[*proxy_set_body*]          - If defined, sets the body passed to the backend.
[*auth_basic*]              - This directive includes testing name and
   password with HTTP Basic Authentication.
[*auth_basic_user_file*]    - This directive sets the htpasswd filename for
  the authentication realm.
[*client_max_body_size*]    - This directive sets client_max_body_size.
[*client_body_timeout*]     - Sets how long the server will wait for a
   client body. Default is 60s
[*client_header_timeout*]     - Sets how long the server will wait for a
   client header. Default is 60s
[*raw_prepend*]            - A single string, or an array of strings to
  prepend to the server directive (after cfg prepend directives). NOTE:
  YOU are responsible for a semicolon on each line that requires one.
[*raw_append*]             - A single string, or an array of strings to
  append to the server directive (after cfg append directives). NOTE:
  YOU are responsible for a semicolon on each line that requires one.
[*location_raw_prepend*]          - A single string, or an array of strings
  to prepend to the location directive (after custom_cfg directives). NOTE:
  YOU are responsible for a semicolon on each line that requires one.
[*location_raw_append*]           - A single string, or an array of strings
  to append to the location directive (after custom_cfg directives). NOTE:
  YOU are responsible for a semicolon on each line that requires one.
[*vhost_cfg_append*]        - It expects a hash with custom directives to
  put after everything else inside vhost
[*vhost_cfg_prepend*]       - It expects a hash with custom directives to
  put before everything else inside vhost
[*vhost_cfg_ssl_append*]        - It expects a hash with custom directives to
  put after everything else inside vhost ssl
[*vhost_cfg_ssl_prepend*]       - It expects a hash with custom directives to
  put before everything else inside vhost ssl
[*rewrite_to_https*]        - Adds a server directive and rewrite rule to
  rewrite to ssl
[*include_files*]           - Adds include files to vhost
[*access_log*]              - Where to write access log. May add additional
  options like log format to the end.
[*error_log*]               - Where to write error log. May add additional
  options like error level to the end.
[*passenger_cgi_param*]     - Allows one to define additional CGI environment
  variables to pass to the backend application
[*passenger_set_header*]        - Allows one to set headers to pass to the
  backend application (Passenger 5.0+)
[*passenger_env_var*]       - Allows one to set environemnt variables to pass
  to the backend application (Passenger 5.0+)
[*log_by_lua*]              - Run the Lua source code inlined as the
  <lua-script-str> at the log request processing phase.
  This does not replace the current access logs, but runs after.
[*log_by_lua_file*]         - Equivalent to log_by_lua, except that the file
  specified by <path-to-lua-script-file> contains the Lua code, or, as from
  the v0.5.0rc32 release, the Lua/LuaJIT bytecode to be executed.
[*gzip_types*]              - Defines gzip_types, nginx default is text/html
[*owner*]                   - Defines owner of the .conf file
[*group*]                   - Defines group of the .conf file
[*mode*]                    - Defines mode of the .conf file
[*maintenance*]             - A boolean value to set a vhost in maintenance
[*maintenance_value*]       - Value to return when maintenance is on.
                              Default to return 503
[*locations*]               - Hash of vhosts ressources used by this vhost

Actions:

Requires:

Sample Usage:

nginx::resource::vhost { 'test2.local':
  ensure   => present,
  www_root => '/var/www/nginx-default',
  ssl      => true,
  ssl_cert => '/tmp/server.crt',
  ssl_key  => '/tmp/server.pem',
}

Parameters:

  • ensure (Any) (defaults to: 'present')
  • listen_ip (Any) (defaults to: '*')
  • listen_port (Any) (defaults to: '80')
  • listen_options (Any) (defaults to: undef)
  • listen_unix_socket_enable (Any) (defaults to: false)
  • listen_unix_socket (Any) (defaults to: '/var/run/nginx.sock')
  • listen_unix_socket_options (Any) (defaults to: undef)
  • location_allow (Any) (defaults to: [])
  • location_deny (Any) (defaults to: [])
  • ipv6_enable (Any) (defaults to: false)
  • ipv6_listen_ip (Any) (defaults to: '::')
  • ipv6_listen_port (Any) (defaults to: '80')
  • ipv6_listen_options (Any) (defaults to: 'default ipv6only=on')
  • add_header (Any) (defaults to: undef)
  • ssl (Any) (defaults to: false)
  • ssl_listen_option (Any) (defaults to: true)
  • ssl_cert (Any) (defaults to: undef)
  • ssl_client_cert (Any) (defaults to: undef)
  • ssl_dhparam (Any) (defaults to: undef)
  • ssl_key (Any) (defaults to: undef)
  • ssl_port (Any) (defaults to: '443')
  • ssl_protocols (Any) (defaults to: 'TLSv1 TLSv1.1 TLSv1.2')
  • ssl_buffer_size (Any) (defaults to: undef)
  • ssl_ciphers (Any) (defaults to: 'ECDHE-RSA-AES128-GCM-SHA256:ECDHE-ECDSA-AES128-GCM-SHA256:ECDHE-RSA-AES256-GCM-SHA384:ECDHE-ECDSA-AES256-GCM-SHA384:DHE-RSA-AES128-GCM-SHA256:DHE-DSS-AES128-GCM-SHA256:kEDH+AESGCM:ECDHE-RSA-AES128-SHA256:ECDHE-ECDSA-AES128-SHA256:ECDHE-RSA-AES128-SHA:ECDHE-ECDSA-AES128-SHA:ECDHE-RSA-AES256-SHA384:ECDHE-ECDSA-AES256-SHA384:ECDHE-RSA-AES256-SHA:ECDHE-ECDSA-AES256-SHA:DHE-RSA-AES128-SHA256:DHE-RSA-AES128-SHA:DHE-DSS-AES128-SHA256:DHE-RSA-AES256-SHA256:DHE-DSS-AES256-SHA:DHE-RSA-AES256-SHA:AES128-GCM-SHA256:AES256-GCM-SHA384:AES128-SHA256:AES256-SHA256:AES128-SHA:AES256-SHA:AES:CAMELLIA:DES-CBC3-SHA:!aNULL:!eNULL:!EXPORT:!DES:!RC4:!MD5:!PSK:!aECDH:!EDH-DSS-DES-CBC3-SHA:!EDH-RSA-DES-CBC3-SHA:!KRB5-DES-CBC3-SHA')
  • ssl_cache (Any) (defaults to: 'shared:SSL:10m')
  • ssl_crl (Any) (defaults to: undef)
  • ssl_stapling (Any) (defaults to: false)
  • ssl_stapling_file (Any) (defaults to: undef)
  • ssl_stapling_responder (Any) (defaults to: undef)
  • ssl_stapling_verify (Any) (defaults to: false)
  • ssl_session_timeout (Any) (defaults to: '5m')
  • ssl_trusted_cert (Any) (defaults to: undef)
  • spdy (Any) (defaults to: $::nginx::config::spdy)
  • http2 (Any) (defaults to: $::nginx::config::http2)
  • proxy (Any) (defaults to: undef)
  • proxy_redirect (Any) (defaults to: undef)
  • proxy_read_timeout (Any) (defaults to: $::nginx::config::proxy_read_timeout)
  • proxy_connect_timeout (Any) (defaults to: $::nginx::config::proxy_connect_timeout)
  • proxy_set_header (Any) (defaults to: $::nginx::config::proxy_set_header)
  • proxy_cache (Any) (defaults to: false)
  • proxy_cache_key (Any) (defaults to: undef)
  • proxy_cache_use_stale (Any) (defaults to: undef)
  • proxy_cache_valid (Any) (defaults to: false)
  • proxy_method (Any) (defaults to: undef)
  • proxy_set_body (Any) (defaults to: undef)
  • resolver (Any) (defaults to: [])
  • fastcgi (Any) (defaults to: undef)
  • fastcgi_params (Any) (defaults to: "${::nginx::config::conf_dir}/fastcgi_params")
  • fastcgi_script (Any) (defaults to: undef)
  • uwsgi (Any) (defaults to: undef)
  • uwsgi_params (Any) (defaults to: "${nginx::config::conf_dir}/uwsgi_params")
  • index_files (Any) (defaults to: [ 'index.html', 'index.htm', 'index.php'])
  • autoindex (Any) (defaults to: undef)
  • server_name (Any) (defaults to: [$name])
  • www_root (Any) (defaults to: undef)
  • rewrite_www_to_non_www (Any) (defaults to: false)
  • rewrite_to_https (Any) (defaults to: undef)
  • location_custom_cfg (Any) (defaults to: undef)
  • location_cfg_prepend (Any) (defaults to: undef)
  • location_cfg_append (Any) (defaults to: undef)
  • location_custom_cfg_prepend (Any) (defaults to: undef)
  • location_custom_cfg_append (Any) (defaults to: undef)
  • try_files (Any) (defaults to: undef)
  • auth_basic (Any) (defaults to: undef)
  • auth_basic_user_file (Any) (defaults to: undef)
  • client_body_timeout (Any) (defaults to: undef)
  • client_header_timeout (Any) (defaults to: undef)
  • client_max_body_size (Any) (defaults to: undef)
  • raw_prepend (Any) (defaults to: undef)
  • raw_append (Any) (defaults to: undef)
  • location_raw_prepend (Any) (defaults to: undef)
  • location_raw_append (Any) (defaults to: undef)
  • vhost_cfg_prepend (Any) (defaults to: undef)
  • vhost_cfg_append (Any) (defaults to: undef)
  • vhost_cfg_ssl_prepend (Any) (defaults to: undef)
  • vhost_cfg_ssl_append (Any) (defaults to: undef)
  • include_files (Any) (defaults to: undef)
  • access_log (Any) (defaults to: undef)
  • error_log (Any) (defaults to: undef)
  • format_log (Any) (defaults to: 'combined')
  • passenger_cgi_param (Any) (defaults to: undef)
  • passenger_set_header (Any) (defaults to: undef)
  • passenger_env_var (Any) (defaults to: undef)
  • log_by_lua (Any) (defaults to: undef)
  • log_by_lua_file (Any) (defaults to: undef)
  • use_default_location (Any) (defaults to: true)
  • rewrite_rules (Any) (defaults to: [])
  • string_mappings (Any) (defaults to: {})
  • geo_mappings (Any) (defaults to: {})
  • gzip_types (Any) (defaults to: undef)
  • owner (Any) (defaults to: $::nginx::config::global_owner)
  • group (Any) (defaults to: $::nginx::config::global_group)
  • mode (Any) (defaults to: $::nginx::config::global_mode)
  • maintenance (Any) (defaults to: false)
  • maintenance_value (Any) (defaults to: 'return 503')
  • locations (Any) (defaults to: {})


173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
# File 'manifests/resource/vhost.pp', line 173

define nginx::resource::vhost (
  $ensure                       = 'present',
  $listen_ip                    = '*',
  $listen_port                  = '80',
  $listen_options               = undef,
  $listen_unix_socket_enable    = false,
  $listen_unix_socket           = '/var/run/nginx.sock',
  $listen_unix_socket_options   = undef,
  $location_allow               = [],
  $location_deny                = [],
  $ipv6_enable                  = false,
  $ipv6_listen_ip               = '::',
  $ipv6_listen_port             = '80',
  $ipv6_listen_options          = 'default ipv6only=on',
  $add_header                   = undef,
  $ssl                          = false,
  $ssl_listen_option            = true,
  $ssl_cert                     = undef,
  $ssl_client_cert              = undef,
  $ssl_dhparam                  = undef,
  $ssl_key                      = undef,
  $ssl_port                     = '443',
  $ssl_protocols                = 'TLSv1 TLSv1.1 TLSv1.2',
  $ssl_buffer_size              = undef,
  $ssl_ciphers                  = 'ECDHE-RSA-AES128-GCM-SHA256:ECDHE-ECDSA-AES128-GCM-SHA256:ECDHE-RSA-AES256-GCM-SHA384:ECDHE-ECDSA-AES256-GCM-SHA384:DHE-RSA-AES128-GCM-SHA256:DHE-DSS-AES128-GCM-SHA256:kEDH+AESGCM:ECDHE-RSA-AES128-SHA256:ECDHE-ECDSA-AES128-SHA256:ECDHE-RSA-AES128-SHA:ECDHE-ECDSA-AES128-SHA:ECDHE-RSA-AES256-SHA384:ECDHE-ECDSA-AES256-SHA384:ECDHE-RSA-AES256-SHA:ECDHE-ECDSA-AES256-SHA:DHE-RSA-AES128-SHA256:DHE-RSA-AES128-SHA:DHE-DSS-AES128-SHA256:DHE-RSA-AES256-SHA256:DHE-DSS-AES256-SHA:DHE-RSA-AES256-SHA:AES128-GCM-SHA256:AES256-GCM-SHA384:AES128-SHA256:AES256-SHA256:AES128-SHA:AES256-SHA:AES:CAMELLIA:DES-CBC3-SHA:!aNULL:!eNULL:!EXPORT:!DES:!RC4:!MD5:!PSK:!aECDH:!EDH-DSS-DES-CBC3-SHA:!EDH-RSA-DES-CBC3-SHA:!KRB5-DES-CBC3-SHA',
  $ssl_cache                    = 'shared:SSL:10m',
  $ssl_crl                      = undef,
  $ssl_stapling                 = false,
  $ssl_stapling_file            = undef,
  $ssl_stapling_responder       = undef,
  $ssl_stapling_verify          = false,
  $ssl_session_timeout          = '5m',
  $ssl_trusted_cert             = undef,
  $spdy                         = $::nginx::config::spdy,
  $http2                        = $::nginx::config::http2,
  $proxy                        = undef,
  $proxy_redirect               = undef,
  $proxy_read_timeout           = $::nginx::config::proxy_read_timeout,
  $proxy_connect_timeout        = $::nginx::config::proxy_connect_timeout,
  $proxy_set_header             = $::nginx::config::proxy_set_header,
  $proxy_cache                  = false,
  $proxy_cache_key              = undef,
  $proxy_cache_use_stale        = undef,
  $proxy_cache_valid            = false,
  $proxy_method                 = undef,
  $proxy_set_body               = undef,
  $resolver                     = [],
  $fastcgi                      = undef,
  $fastcgi_params               = "${::nginx::config::conf_dir}/fastcgi_params",
  $fastcgi_script               = undef,
  $uwsgi                        = undef,
  $uwsgi_params                 = "${nginx::config::conf_dir}/uwsgi_params",
  $index_files                  = [
    'index.html',
    'index.htm',
    'index.php'],
  $autoindex                    = undef,
  $server_name                  = [$name],
  $www_root                     = undef,
  $rewrite_www_to_non_www       = false,
  $rewrite_to_https             = undef,
  $location_custom_cfg          = undef,
  $location_cfg_prepend         = undef,
  $location_cfg_append          = undef,
  $location_custom_cfg_prepend  = undef,
  $location_custom_cfg_append   = undef,
  $try_files                    = undef,
  $auth_basic                   = undef,
  $auth_basic_user_file         = undef,
  $client_body_timeout          = undef,
  $client_header_timeout        = undef,
  $client_max_body_size         = undef,
  $raw_prepend                  = undef,
  $raw_append                   = undef,
  $location_raw_prepend         = undef,
  $location_raw_append          = undef,
  $vhost_cfg_prepend            = undef,
  $vhost_cfg_append             = undef,
  $vhost_cfg_ssl_prepend        = undef,
  $vhost_cfg_ssl_append         = undef,
  $include_files                = undef,
  $access_log                   = undef,
  $error_log                    = undef,
  $format_log                   = 'combined',
  $passenger_cgi_param          = undef,
  $passenger_set_header         = undef,
  $passenger_env_var            = undef,
  $log_by_lua                   = undef,
  $log_by_lua_file              = undef,
  $use_default_location         = true,
  $rewrite_rules                = [],
  $string_mappings              = {},
  $geo_mappings                 = {},
  $gzip_types                   = undef,
  $owner                        = $::nginx::config::global_owner,
  $group                        = $::nginx::config::global_group,
  $mode                         = $::nginx::config::global_mode,
  $maintenance                  = false,
  $maintenance_value            = 'return 503',
  $locations                    = {}
) {

  validate_re($ensure, '^(present|absent)$',
    "${ensure} is not supported for ensure. Allowed values are 'present' and 'absent'.")
  if !(is_array($listen_ip) or is_string($listen_ip)) {
    fail('$listen_ip must be a string or array.')
  }
  if !is_integer($listen_port) {
    fail('$listen_port must be an integer.')
  }
  if ($listen_options != undef) {
    validate_string($listen_options)
  }
  validate_bool($listen_unix_socket_enable)
  if !(is_array($listen_unix_socket) or is_string($listen_unix_socket)) {
    fail('$listen_unix_socket must be a string or array.')
  }
  if ($listen_unix_socket_options != undef) {
    validate_string($listen_unix_socket_options)
  }
  validate_array($location_allow)
  validate_array($location_deny)
  validate_bool($ipv6_enable)
  if !(is_array($ipv6_listen_ip) or is_string($ipv6_listen_ip)) {
    fail('$ipv6_listen_ip must be a string or array.')
  }
  if !is_integer($ipv6_listen_port) {
    fail('$ipv6_listen_port must be an integer.')
  }
  validate_string($ipv6_listen_options)
  if ($add_header != undef) {
    validate_hash($add_header)
  }
  validate_bool($ssl)
  if ($ssl_cert != undef) {
    validate_string($ssl_cert)
  }
  if ($ssl_client_cert != undef) {
    validate_string($ssl_client_cert)
  }
  if ($ssl_crl != undef) {
    validate_string($ssl_crl)
  }
  validate_bool($ssl_listen_option)
  if ($ssl_dhparam != undef) {
    validate_string($ssl_dhparam)
  }
  if ($ssl_key != undef) {
    validate_string($ssl_key)
  }
  if !is_integer($ssl_port) {
    fail('$ssl_port must be an integer.')
  }
  validate_string($ssl_protocols)
  validate_string($ssl_ciphers)
  validate_string($ssl_cache)
  validate_bool($ssl_stapling)
  if ($ssl_stapling_file != undef) {
    validate_string($ssl_stapling_file)
  }
  if ($ssl_stapling_responder != undef) {
    validate_string($ssl_stapling_responder)
  }
  validate_bool($ssl_stapling_verify)
  validate_string($ssl_session_timeout)
  if ($ssl_trusted_cert != undef) {
    validate_string($ssl_trusted_cert)
  }
  validate_string($spdy)
  if ($proxy != undef) {
    validate_string($proxy)
  }
  validate_string($proxy_read_timeout)
  if ($proxy_redirect != undef) {
    validate_string($proxy_redirect)
  }
  validate_array($proxy_set_header)
  if ($proxy_cache != false) {
    validate_string($proxy_cache)
  }
  if ($proxy_cache_key != undef) {
    validate_string($proxy_cache_key)
  }
  if ($proxy_cache_use_stale != undef) {
    validate_string($proxy_cache_use_stale)
  }
  if ($proxy_cache_valid != false) {
    validate_string($proxy_cache_valid)
  }
  if ($proxy_method != undef) {
    validate_string($proxy_method)
  }
  if ($proxy_set_body != undef) {
    validate_string($proxy_set_body)
  }
  validate_array($resolver)
  if ($fastcgi != undef) {
    validate_string($fastcgi)
  }
  validate_string($fastcgi_params)
  if ($fastcgi_script != undef) {
    validate_string($fastcgi_script)
  }
  if ($uwsgi != undef) {
    validate_string($uwsgi)
  }
  validate_string($uwsgi_params)
  validate_array($index_files)
  if ($autoindex != undef) {
    validate_string($autoindex)
  }
  validate_array($server_name)
  if ($www_root != undef) {
    validate_string($www_root)
  }
  validate_bool($rewrite_www_to_non_www)
  if ($rewrite_to_https != undef) {
    validate_bool($rewrite_to_https)
  }
  if ($raw_prepend != undef) {
    if (is_array($raw_prepend)) {
      validate_array($raw_prepend)
    } else {
      validate_string($raw_prepend)
    }
  }
  if ($raw_append != undef) {
    if (is_array($raw_append)) {
      validate_array($raw_append)
    } else {
      validate_string($raw_append)
    }
  }
  if ($location_raw_prepend != undef) {
    if (is_array($location_raw_prepend)) {
      validate_array($location_raw_prepend)
    } else {
      validate_string($location_raw_prepend)
    }
  }
  if ($location_raw_append != undef) {
    if (is_array($location_raw_append)) {
      validate_array($location_raw_append)
    } else {
      validate_string($location_raw_append)
    }
  }
  if ($location_custom_cfg != undef) {
    validate_hash($location_custom_cfg)
  }
  if ($location_cfg_prepend != undef) {
    validate_hash($location_cfg_prepend)
  }
  if ($location_cfg_append != undef) {
    validate_hash($location_cfg_append)
  }
  if ($try_files != undef) {
    validate_array($try_files)
  }
  if ($auth_basic != undef) {
    validate_string($auth_basic)
  }
  if ($auth_basic_user_file != undef) {
    validate_string($auth_basic_user_file)
  }
  if ($vhost_cfg_prepend != undef) {
    validate_hash($vhost_cfg_prepend)
  }
  if ($vhost_cfg_append != undef) {
    validate_hash($vhost_cfg_append)
  }
  if ($vhost_cfg_ssl_prepend != undef) {
    validate_hash($vhost_cfg_ssl_prepend)
  }
  if ($vhost_cfg_ssl_append != undef) {
    validate_hash($vhost_cfg_ssl_append)
  }
  if ($include_files != undef) {
    validate_array($include_files)
  }
  if ($access_log != undef) {
    validate_string($access_log)
  }
  if ($error_log != undef) {
    validate_string($error_log)
  }
  if ($passenger_cgi_param != undef) {
    validate_hash($passenger_cgi_param)
  }
  if ($passenger_set_header != undef) {
    validate_hash($passenger_set_header)
  }
  if ($passenger_env_var != undef) {
    validate_hash($passenger_env_var)
  }
  if ($log_by_lua != undef) {
    validate_string($log_by_lua)
  }
  if ($log_by_lua_file != undef) {
    validate_string($log_by_lua_file)
  }
  if ($client_body_timeout != undef) {
    validate_string($client_body_timeout)
  }
  if ($client_header_timeout != undef) {
    validate_string($client_header_timeout)
  }
  if ($gzip_types != undef) {
    validate_string($gzip_types)
  }
  validate_bool($use_default_location)
  validate_array($rewrite_rules)
  validate_hash($string_mappings)
  validate_hash($geo_mappings)
  validate_hash($locations)

  validate_string($owner)
  validate_string($group)
  validate_re($mode, '^\d{4}$',
    "${mode} is not valid. It should be 4 digits (0644 by default).")

  # Variables
  $vhost_dir = "${::nginx::config::conf_dir}/sites-available"
  $vhost_enable_dir = "${::nginx::config::conf_dir}/sites-enabled"
  $vhost_symlink_ensure = $ensure ? {
    'absent' => absent,
    default  => 'link',
  }

  $name_sanitized = regsubst($name, ' ', '_', 'G')
  $config_file = "${vhost_dir}/${name_sanitized}.conf"

  File {
    ensure => $ensure ? {
      'absent' => absent,
      default  => 'file',
    },
    notify => Class['::nginx::service'],
    owner  => $owner,
    group  => $group,
    mode   => $mode,
  }

  # Add IPv6 Logic Check - Nginx service will not start if ipv6 is enabled
  # and support does not exist for it in the kernel.
  if ($ipv6_enable == true) and (!$::ipaddress6) {
    warning('nginx: IPv6 support is not enabled or configured properly')
  }

  # Check to see if SSL Certificates are properly defined.
  if ($ssl == true) {
    if ($ssl_cert == undef) or ($ssl_key == undef) {
      fail('nginx: SSL certificate/key (ssl_cert/ssl_key) and/or SSL Private must be defined and exist on the target system(s)')
    }
  }

  # This was a lot to add up in parameter list so add it down here
  # Also opted to add more logic here and keep template cleaner which
  # unfortunately means resorting to the $varname_real thing
  $access_log_real = $access_log ? {
    'off'   => 'off',
    undef   => "${::nginx::config::log_dir}/${name_sanitized}.access.log ${format_log}",
    default => "${access_log} ${format_log}",
  }

  $error_log_real = $error_log ? {
    undef   => "${::nginx::config::log_dir}/${name_sanitized}.error.log",
    default => $error_log,
  }

  concat { $config_file:
    owner  => $owner,
    group  => $group,
    mode   => $mode,
    notify => Class['::nginx::service'],
  }

  $ssl_only = ($ssl == true) and ($ssl_port == $listen_port)

  if $use_default_location == true {
    # Create the default location reference for the vHost
    nginx::resource::location {"${name_sanitized}-default":
      ensure                      => $ensure,
      vhost                       => $name_sanitized,
      ssl                         => $ssl,
      ssl_only                    => $ssl_only,
      location                    => '/',
      location_allow              => $location_allow,
      location_deny               => $location_deny,
      proxy                       => $proxy,
      proxy_redirect              => $proxy_redirect,
      proxy_read_timeout          => $proxy_read_timeout,
      proxy_connect_timeout       => $proxy_connect_timeout,
      proxy_cache                 => $proxy_cache,
      proxy_cache_key             => $proxy_cache_key,
      proxy_cache_use_stale       => $proxy_cache_use_stale,
      proxy_cache_valid           => $proxy_cache_valid,
      proxy_method                => $proxy_method,
      proxy_set_header            => $proxy_set_header,
      proxy_set_body              => $proxy_set_body,
      fastcgi                     => $fastcgi,
      fastcgi_params              => $fastcgi_params,
      fastcgi_script              => $fastcgi_script,
      uwsgi                       => $uwsgi,
      uwsgi_params                => $uwsgi_params,
      try_files                   => $try_files,
      www_root                    => $www_root,
      autoindex                   => $autoindex,
      index_files                 => $index_files,
      location_custom_cfg         => $location_custom_cfg,
      location_cfg_prepend        => $location_cfg_prepend,
      location_cfg_append         => $location_cfg_append,
      location_custom_cfg_prepend => $location_custom_cfg_prepend,
      location_custom_cfg_append  => $location_custom_cfg_append,
      rewrite_rules               => $rewrite_rules,
      raw_prepend                 => $location_raw_prepend,
      raw_append                  => $location_raw_append,
      notify                      => Class['nginx::service'],
    }
    $root = undef
  } else {
    $root = $www_root
  }

  if $fastcgi != undef and !defined(File[$fastcgi_params]) {
    file { $fastcgi_params:
      ensure  => present,
      mode    => '0770',
      content => template('nginx/vhost/fastcgi_params.erb'),
    }
  }

  if $uwsgi != undef and !defined(File[$uwsgi_params]) {
    file { $uwsgi_params:
      ensure  => present,
      mode    => '0770',
      content => template('nginx/vhost/uwsgi_params.erb'),
    }
  }

  if ($listen_port != $ssl_port) {
    concat::fragment { "${name_sanitized}-header":
      target  => $config_file,
      content => template('nginx/vhost/vhost_header.erb'),
      order   => '001',
    }
  }

  # Create a proper file close stub.
  if ($listen_port != $ssl_port) {
    concat::fragment { "${name_sanitized}-footer":
      target  => $config_file,
      content => template('nginx/vhost/vhost_footer.erb'),
      order   => '699',
    }
  }

  # Create SSL File Stubs if SSL is enabled
  if ($ssl == true) {
    # Access and error logs are named differently in ssl template

    # This was a lot to add up in parameter list so add it down here
    # Also opted to add more logic here and keep template cleaner which
    # unfortunately means resorting to the $varname_real thing
    $ssl_access_log_real = $access_log ? {
      'off'   => 'off',
      undef   => "${::nginx::config::log_dir}/ssl-${name_sanitized}.access.log ${format_log}",
      default => "${access_log} ${format_log}",
    }

    $ssl_error_log_real = $error_log ? {
      undef   => "${::nginx::config::log_dir}/ssl-${name_sanitized}.error.log",
      default => $error_log,
    }

    concat::fragment { "${name_sanitized}-ssl-header":
      target  => $config_file,
      content => template('nginx/vhost/vhost_ssl_header.erb'),
      order   => '700',
    }
    concat::fragment { "${name_sanitized}-ssl-footer":
      target  => $config_file,
      content => template('nginx/vhost/vhost_ssl_footer.erb'),
      order   => '999',
    }
  }

  file{ "${name_sanitized}.conf symlink":
    ensure  => $vhost_symlink_ensure,
    path    => "${vhost_enable_dir}/${name_sanitized}.conf",
    target  => $config_file,
    require => Concat[$config_file],
    notify  => Class['::nginx::service'],
  }

  create_resources('::nginx::resource::map', $string_mappings)
  create_resources('::nginx::resource::geo', $geo_mappings)
  create_resources('::nginx::resource::location', $locations, {
    ensure   => $ensure,
    vhost    => $name_sanitized,
    ssl      => $ssl,
    ssl_only => $ssl_only,
    www_root => $www_root,
  })
}