Defined Type: freeradius::policy

Defined in:
manifests/policy.pp

Overview

Install FreeRADIUS policies

Parameters:

  • source (Optional[String])
  • order (Optional[Integer]) (defaults to: 50)
  • ensure (Freeradius::Ensure) (defaults to: present) 


2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
 
# File 'manifests/policy.pp', line 2

define freeradius::policy (
  Optional[String] $source,
  Optional[Integer] $order   = 50,
  Freeradius::Ensure $ensure = present,
) {
  $fr_package  = $::freeradius::params::fr_package
  $fr_service  = $::freeradius::params::fr_service
  $fr_basepath = $::freeradius::params::fr_basepath
  $fr_group    = $::freeradius::params::fr_group

  # Install policy in policy.d
  file { "${fr_basepath}/policy.d/${name}":
    ensure  => $ensure,
    mode    => '0644',
    owner   => 'root',
    group   => $fr_group,
    source  => $source,
    require => [Package[$fr_package], Group[$fr_group]],
    notify  => Service[$fr_service],
  }

  # Reference policy.d in the global includes file
  # If no order priority is given, assume 50
  if ($ensure == 'present') {
    concat::fragment { "policy-${name}":
      target  => "${fr_basepath}/policy.conf",
      content => "\t\$INCLUDE ${fr_basepath}/policy.d/${name}\n",
      order   => $order,
      require => File["${fr_basepath}/policy.d/${name}"],
    }
  }
}