Puppet Class: vector::configure

Defined in:
manifests/configure.pp

Summary

Creates configuraton files, and creates systemd files if configured to do so

Overview

vector::configure



5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
 
# File 'manifests/configure.pp', line 5

class vector::configure {
  assert_private()
  $global_opts_file   = "${vector::config_dir}/global.yaml"

  file { $global_opts_file:
    ensure  => file,
    mode    => '0664',
    content => to_yaml($vector::global_options + { 'data_dir' => $vector::data_dir }),
    notify  => Class['vector::service'],
  }

  create_resources(vector::configfile, $vector::config_files)
  create_resources(vector::source,     $vector::sources)
  create_resources(vector::transform,  $vector::transforms)
  create_resources(vector::sink,       $vector::sinks)

  file { $vector::environment_file:
    ensure  => file,
    content => epp('vector/vector_env.epp'),
    notify  => Class['vector::service'],
  }

  if $vector::manage_systemd {
    $systemd_service_file = "/etc/systemd/system/${vector::service_name}.service"

    file { $systemd_service_file:
      ensure  => file,
      content => epp('vector/vector.service.epp'),
      notify  => Class['vector::service'],
    }

    $systemd_dropin_dir = "${systemd_service_file}.d"

    file { $systemd_dropin_dir:
      ensure  => directory,
      recurse => true,
      purge   => true,
    }

    File[$systemd_dropin_dir] -> Vector::Systemd_dropin<||> ~> Class['vector::service']

    create_resources(vector::systemd_dropin, $vector::systemd_dropins)
  }

  if $vector::notify_on_config_change {
    Vector::Configfile<||> ~> Class['vector::service']
    Vector::Source<||> ~> Class['vector::service']
    Vector::Transform<||> ~> Class['vector::service']
    Vector::Sink<||> ~> Class['vector::service']
  }
}