Puppet Class: vector::setup

Defined in:
manifests/setup.pp

Summary

sets up some directories for configurations to go into

Overview

vector::setup



5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
 
# File 'manifests/setup.pp', line 5

class vector::setup {
  assert_private()
  $topology_files_dir = "${vector::config_dir}/configs"
  $sources_dir        = "${topology_files_dir}/sources"
  $transforms_dir     = "${topology_files_dir}/transforms"
  $sinks_dir          = "${topology_files_dir}/sinks"

  file { $vector::data_dir:
    ensure => directory,
    owner  => $vector::user,
    mode   => $vector::data_dir_mode,
  }

  file { $vector::config_dir:
    ensure => directory,
    mode   => $vector::config_dir_mode,
  }
  -> file { $topology_files_dir:
    ensure  => directory,
    mode    => $vector::config_dir_mode,
    recurse => true,
    purge   => true,
  }
  -> file { [$sources_dir, $transforms_dir, $sinks_dir]:
    ensure  => directory,
    mode    => $vector::config_dir_mode,
    recurse => true,
    purge   => true,
  }

  File[$sources_dir, $transforms_dir, $sinks_dir] -> Vector::Source<||>
  File[$sources_dir, $transforms_dir, $sinks_dir] -> Vector::Sink<||>
  File[$sources_dir, $transforms_dir, $sinks_dir] -> Vector::Transform<||>

  if $vector::notify_on_config_change {
    File[$sources_dir, $transforms_dir, $sinks_dir] ~> Class['vector::service']
  }
}