Puppet Class: ganglia::gmond

Inherits:
ganglia::params
Defined in:
manifests/gmond.pp

Summary

ganglia::gmond Manages ganglia gmond & gmetad daemons + web front end

Overview

Parameters:

  • globals_deaf (String[1]) (defaults to: 'no')
  • globals_host_dmax (String[1]) (defaults to: '0')
  • globals_send_metadata_interval (String[1]) (defaults to: '300')
  • globals_override_hostname (Optional[Stdlib::Fqdn]) (defaults to: undef)
  • globals_user (String[1]) (defaults to: 'ganglia')
  • globals_max_udp_msg_len (Integer) (defaults to: 1472)
  • cluster_name (String[1]) (defaults to: 'unspecified')
  • cluster_owner (String[1]) (defaults to: 'unspecified')
  • cluster_latlong (String[1]) (defaults to: 'unspecified')
  • cluster_url (Optional[Variant[Stdlib::HTTPUrl,Stdlib::Fqdn]]) (defaults to: undef)
  • host_location (String[1]) (defaults to: 'unspecified')
  • udp_send_channel (Array[Hash]) (defaults to: [{ mcast_join => '239.2.11.71', port => 8649, ttl => 1 }])
  • udp_recv_channel (Array[Hash]) (defaults to: [{ mcast_join => '239.2.11.71', port => 8649, bind => '239.2.11.71' }])
  • tcp_accept_channel (Array[Hash]) (defaults to: [{ port => 8659 }])
  • gmond_package_name (Variant[String[1], Array[String[1]]]) (defaults to: $ganglia::params::gmond_package_name)
  • gmond_package_ensure (String[1]) (defaults to: 'present')
  • gmond_service_name (String[1]) (defaults to: $ganglia::params::gmond_service_name)
  • gmond_service_config (String[1]) (defaults to: $ganglia::params::gmond_service_config)
  • gmond_status_command (String[1]) (defaults to: $ganglia::params::gmond_status_command)

See Also:



27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
 
# File 'manifests/gmond.pp', line 27

class ganglia::gmond (
  String[1] $globals_deaf                                      = 'no',
  String[1] $globals_host_dmax                                 = '0',
  String[1] $globals_send_metadata_interval                    = '300',
  Optional[Stdlib::Fqdn] $globals_override_hostname            = undef,
  String[1] $globals_user                                      = 'ganglia',
  Integer $globals_max_udp_msg_len                             = 1472,
  String[1] $cluster_name                                      = 'unspecified',
  String[1] $cluster_owner                                     = 'unspecified',
  String[1] $cluster_latlong                                   = 'unspecified',
  Optional[Variant[Stdlib::HTTPUrl,Stdlib::Fqdn]] $cluster_url = undef,
  String[1] $host_location                                     = 'unspecified',
  Array[Hash] $udp_send_channel                                = [{ mcast_join => '239.2.11.71', port => 8649, ttl => 1 }],
  Array[Hash] $udp_recv_channel                                = [{ mcast_join => '239.2.11.71', port => 8649, bind => '239.2.11.71' }],
  Array[Hash] $tcp_accept_channel                              = [{ port => 8659 }],
  Variant[String[1], Array[String[1]]] $gmond_package_name     = $ganglia::params::gmond_package_name,
  String[1] $gmond_package_ensure                              = 'present',
  String[1] $gmond_service_name                                = $ganglia::params::gmond_service_name,
  String[1] $gmond_service_config                              = $ganglia::params::gmond_service_config,
  String[1] $gmond_status_command                              = $ganglia::params::gmond_status_command,
) inherits ganglia::params {
  if ($ganglia::params::gmond_status_command) {
    $hasstatus = false
  } else {
    $hasstatus = true
  }

  package { $gmond_package_name:
    ensure => $gmond_package_ensure,
    notify => Service[$gmond_service_name],
  }

  file { $gmond_service_config:
    ensure  => file,
    owner   => 'root',
    group   => 'root',
    mode    => '0644',
    content => template($ganglia::params::gmond_service_erb),
    require => Package[$gmond_package_name],
    notify  => Service[$gmond_service_name],
  }
  service { $gmond_service_name:
    ensure     => running,
    hasstatus  => $hasstatus,
    hasrestart => true,
    enable     => true,
    status     => $gmond_status_command,
  }
}