Puppet Class: cubbystack::trove::conductor

Defined in:
manifests/trove/conductor.pp

Overview

Class: cubbystack::trove::conductor

Configures the trove-conductor.conf file

Parameters

settings

A hash of key => value settings to go in trove-conductor.conf

service_enable

The status of the trove-conductor service Defaults to true

config_file

The path to trove-conductor.conf Defaults to /etc/trove/trove-conductor.conf

Parameters:

  • settings (Any)
  • service_enable (Any) (defaults to: true)
  • config_file (Any) (defaults to: '/etc/trove/trove-conductor.conf') 


18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
 
# File 'manifests/trove/conductor.pp', line 18

class cubbystack::trove::conductor (
  $settings,
  $service_enable = true,
  $config_file    = '/etc/trove/trove-conductor.conf',
) {

  include ::cubbystack::params

  ## Meta settings and globals
  $tags = ['openstack', 'trove', 'trove-conductor']

  # Make sure Trove is installed before any configuration happens
  # Make sure Trove Conductor is configured before the service starts
  Package['trove-api'] -> Cubbystack_config<| tag == 'trove-conductor' |>
  Cubbystack_config<| tag == 'trove-conductor' |> -> Service['trove-conductor']

  # Restart trove after any config changes
  Cubbystack_config<| tag == 'trove-conductor' |> ~> Service['trove-conductor']

  File {
    ensure  => present,
    owner   => 'trove',
    group   => 'trove',
    mode    => '0640',
    tag     => $tags,
    notify  => Service['trove-conductor'],
    require => Package['trove-api'],
  }

  ## Trove Conductor configuration
  file { $config_file: }

  # Configure the Conductor service
  $settings.each |$setting, $value| {
    cubbystack_config { "${config_file}: ${setting}":
      value => $value,
      tag   => $tags,
    }
  }

  ## Trove Conductor service
  if ($service_enable) {
    $service_ensure = 'running'
  } else {
    $service_ensure = 'stopped'
  }

  service { 'trove-conductor':
    name       => $::cubbystack::params::trove_conductor_service_name,
    ensure     => $service_ensure,
    enable     => $service_enable,
    hasstatus  => true,
    hasrestart => true,
    tag        => $tags,
    provider   => $::cubbystack::params::service_provider,
    require    => Package['trove-api'],
  }

}