Puppet Class: katello::repo

Defined in:
manifests/repo.pp

Summary

Manage the Katello repository

Overview

Parameters:

  • repo_version (Variant[Pattern[/^\d\.\d+$/], Enum['nightly']]) —

    The repository version to use

  • dist (String) (defaults to: "el${facts['os']['release']['major']}") —

    The distribution to use

  • gpgcheck (Boolean) (defaults to: false) —

    Whether GPG signatures need to be checked

  • gpgkey (String) (defaults to: 'absent') —

    The location of the GPG key



11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
 
# File 'manifests/repo.pp', line 11

class katello::repo (
  Variant[Pattern[/^\d\.\d+$/], Enum['nightly']] $repo_version,
  String $dist = "el${facts['os']['release']['major']}",
  Boolean $gpgcheck = false,
  String $gpgkey = 'absent',
) {
  yumrepo { 'katello':
    descr    => "katello ${repo_version}",
    baseurl  => "https://yum.theforeman.org/katello/${repo_version}/katello/${dist}/\$basearch/",
    gpgkey   => $gpgkey,
    gpgcheck => $gpgcheck,
    enabled  => true,
  }
  -> anchor { 'katello::repo': } # lint:ignore:anchor_resource

  Anchor <| title == 'foreman::repo' |> -> Yumrepo['katello']

  if $facts['os']['release']['major'] == '8' {
    package { 'katello-dnf-module':
      ensure      => $dist,
      name        => 'katello',
      enable_only => true,
      provider    => 'dnfmodule',
      require     => Yumrepo['katello'],
      before      => Anchor['katello::repo'],
    }
  }
}