Defined Type: openvpn::ca

Defined in:
manifests/ca.pp

Overview

Define: openvpn::ca

This define creates the openvpn ca and ssl certificates

Parameters

country

String. Country to be used for the SSL certificate

province

String. Province to be used for the SSL certificate

city

String. City to be used for the SSL certificate

organization

String. Organization to be used for the SSL certificate

email

String. Email address to be used for the SSL certificate

common_name

String. Common name to be used for the SSL certificate Default: server

group

String. User to drop privileges to after startup Default: depends on your $::osfamily

ssl_key_size

String. Length of SSL keys (in bits) generated by this module. Default: 1024

key_expire

String. The number of days to certify the server certificate for Default: 3650

ca_expire

String. The number of days to certify the CA certificate for Default: 3650

key_name

String. Value for name_default variable in openssl.cnf and

KEY_NAME in vars

Default: None

key_ou

String. Value for organizationalUnitName_default variable in openssl.cnf

and KEY_OU in vars

Default: None

key_cn

String. Value for commonName_default variable in openssl.cnf

and KEY_CN in vars

Default: None

tls_auth

Boolean. Determins if a tls key is generated Default: False

Examples

openvpn::ca {
  'my_user':
    server      => 'contractors',
    remote_host => 'vpn.mycompany.com'
 }

Authors

License

Copyright 2013 Raffael Schmid, <raffael@yux.ch>

Licensed under the Apache License, Version 2.0 (the “License”); you may not use this file except in compliance with the License. You may obtain a copy of the License at

www.apache.org/licenses/LICENSE-2.0

Unless required by applicable law or agreed to in writing, software distributed under the License is distributed on an “AS IS” BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the License for the specific language governing permissions and limitations under the License.

Parameters:

  • country (Any)
  • province (Any)
  • city (Any)
  • organization (Any)
  • email (Any)
  • common_name (Any) (defaults to: 'server')
  • group (Any) (defaults to: false)
  • ssl_key_size (Any) (defaults to: 1024)
  • ca_expire (Any) (defaults to: 3650)
  • key_expire (Any) (defaults to: 3650)
  • key_cn (Any) (defaults to: '')
  • key_name (Any) (defaults to: '')
  • key_ou (Any) (defaults to: '')
  • tls_auth (Any) (defaults to: false) 


92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
 
# File 'manifests/ca.pp', line 92

define openvpn::ca(
  $country,
  $province,
  $city,
  $organization,
  $email,
  $common_name  = 'server',
  $group        = false,
  $ssl_key_size = 1024,
  $ca_expire    = 3650,
  $key_expire   = 3650,
  $key_cn       = '',
  $key_name     = '',
  $key_ou       = '',
  $tls_auth     = false,
) {

  include openvpn

  $group_to_set = $group ? {
    false   => $openvpn::params::group,
    default => $group
  }

  File {
    group => $group_to_set,
  }

  $etc_directory = $::openvpn::params::etc_directory

  exec { "copy easy-rsa to openvpn config folder ${name}":
    command => "/bin/cp -r ${openvpn::params::easyrsa_source} ${etc_directory}/openvpn/${name}/easy-rsa",
    creates => "${etc_directory}/openvpn/${name}/easy-rsa",
    require => File["${etc_directory}/openvpn/${name}"],
  }

  file { [
    "${etc_directory}/openvpn/${name}/easy-rsa/clean-all",
    "${etc_directory}/openvpn/${name}/easy-rsa/build-dh",
    "${etc_directory}/openvpn/${name}/easy-rsa/pkitool",
  ]:
    ensure  => file,
    mode    => '0550',
    require => Exec["copy easy-rsa to openvpn config folder ${name}"],
  }

  file { "${etc_directory}/openvpn/${name}/easy-rsa/revoked":
    ensure  => directory,
    mode    => '0750',
    recurse => true,
    require => Exec["copy easy-rsa to openvpn config folder ${name}"],
  }

  file { "${etc_directory}/openvpn/${name}/easy-rsa/vars":
    ensure  => file,
    mode    => '0550',
    content => template('openvpn/vars.erb'),
    require => Exec["copy easy-rsa to openvpn config folder ${name}"],
  }

  file { "${etc_directory}/openvpn/${name}/easy-rsa/openssl.cnf":
    require => Exec["copy easy-rsa to openvpn config folder ${name}"],
  }

  if $openvpn::params::link_openssl_cnf == true {
    File["${etc_directory}/openvpn/${name}/easy-rsa/openssl.cnf"] {
      ensure => link,
      target => "${etc_directory}/openvpn/${name}/easy-rsa/openssl-1.0.0.cnf",
      before => Exec["initca ${name}"],
    }
  }

  exec { "generate dh param ${name}":
    command  => '. ./vars && ./clean-all && ./build-dh',
    cwd      => "${etc_directory}/openvpn/${name}/easy-rsa",
    creates  => "${etc_directory}/openvpn/${name}/easy-rsa/keys/dh${ssl_key_size}.pem",
    provider => 'shell',
    require  => File["${etc_directory}/openvpn/${name}/easy-rsa/vars"],
  }

  exec { "initca ${name}":
    command  => '. ./vars && ./pkitool --initca',
    cwd      => "${etc_directory}/openvpn/${name}/easy-rsa",
    creates  => "${etc_directory}/openvpn/${name}/easy-rsa/keys/ca.key",
    provider => 'shell',
    require  => Exec["generate dh param ${name}"],
  }

  exec { "generate server cert ${name}":
    command  => ". ./vars && ./pkitool --server ${common_name}",
    cwd      => "${etc_directory}/openvpn/${name}/easy-rsa",
    creates  => "${etc_directory}/openvpn/${name}/easy-rsa/keys/${common_name}.key",
    provider => 'shell',
    require  => Exec["initca ${name}"],
  }

  file { "${etc_directory}/openvpn/${name}/keys":
    ensure  => link,
    target  => "${etc_directory}/openvpn/${name}/easy-rsa/keys",
    require => Exec["copy easy-rsa to openvpn config folder ${name}"],
  }

  exec { "create crl.pem on ${name}":
    command  => ". ./vars && KEY_CN='' KEY_OU='' KEY_NAME='' KEY_ALTNAMES='' openssl ca -gencrl -out ${etc_directory}/openvpn/${name}/crl.pem -config ${etc_directory}/openvpn/${name}/easy-rsa/openssl.cnf",
    cwd      => "${etc_directory}/openvpn/${name}/easy-rsa",
    creates  => "${etc_directory}/openvpn/${name}/crl.pem",
    provider => 'shell',
    require  => Exec["generate server cert ${name}"],
  }

  file { "${etc_directory}/openvpn/${name}/crl.pem":
    mode    => '0640',
    group   =>  $group_to_set,
    require => Exec["create crl.pem on ${name}"],
  }

  if $tls_auth {
    exec { "generate tls key for ${name}":
      command  => 'openvpn --genkey --secret keys/ta.key',
      cwd      => "${etc_directory}/openvpn/${name}/easy-rsa",
      creates  => "${etc_directory}/openvpn/${name}/easy-rsa/keys/ta.key",
      provider => 'shell',
      require  => Exec["generate server cert ${name}"],
    }
  }

  file { "${etc_directory}/openvpn/${name}/easy-rsa/keys/crl.pem":
    ensure  => link,
    target  => "${etc_directory}/openvpn/${name}/crl.pem",
    require => Exec["create crl.pem on ${name}"],
  }

}