Defined Type: epics::ioc
- Defined in:
- manifests/ioc.pp
Summary
Manage an IOC instance.Overview
This type configures an IOC instance. It creates configuration files, populates them with the correct values, builds the IOC code (if desired) and ensures the IOC instance can be started as a service. The top-level IOC directory of the IOC is expected to be $iocbase/<ioc_name> where <ioc_name> is the title specified when instantiating the ‘epics::ioc’ resource.
IOCs are run in [procServ](github.com/ralphlange/procServ) to ease maintenance. They are started as a system service. On systems that use systemd as init system a systemd service file will be created for each IOC process. On systems using System-V-style init scripts this module relies on sysv-rc-softioc for creating the init scripts. It is possible to transition from one init system to another without modifying any Puppet code (just make sure to run Puppet after rebooting the machine to give the module the opportunity to make the required adjustments).
In contrast to libraries and regular applications which are installed from packages, IOCs applications are build on the target machine. This allows IOC engineers to fix problems in the EPICS run-time database quickly in the field without waiting for a potentially long-running CI pipeline. Of course this power comes with the responsibility to push these changes to the version control system before they are lost due to a broken drive.
### Environment Variables Some parameters of this class result in environment variables being set. Please refer to the following table for a list:
<table> <thead> <tr> <th>Parameter</th> <th>Sets Environment Variable</th> </tr> </thead> <tbody> <tr> <td>ca_addr_list</td> <td>EPICS_CA_ADDR_LIST</td> </tr> <tr> <td>ca_auto_addr_list</td> <td>EPICS_CA_AUTO_ADDR_LIST</td> </tr> <tr> <td>ca_max_array_bytes</td> <td>EPICS_CA_MAX_ARRAY_BYTES</td> </tr> <tr> <td>log_port</td> <td>EPICS_IOC_LOG_PORT</td> </tr> <tr> <td>log_server</td> <td>EPICS_IOC_LOG_INET</td> </tr> <tr> <td>ca_sec_file</td> <td>EPICS_CA_SEC_FILE</td> </tr> </tbody> </table> Environment variables that are not on this list can be set using the ‘env_vars’ parameter.
340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 466 467 468 469 470 471 472 473 474 475 476 477 478 479 480 481 482 483 484 485 486 487 488 489 490 491 492 493 494 495 496 497 498 499 500 501 502 503 504 505 506 507 508 509 510 511 512 513 514 515 516 517 518 519 520 521 522 523 524 525 526 527 528 529 530 531 532 533 534 535 536 537 538 539 540 541 542 543 544 545 546 547 548 549 550 551 552 553 |
# File 'manifests/ioc.pp', line 340
define epics::ioc(
Optional[Stdlib::Ensure::Service] $ensure = undef,
Optional[Boolean] $enable = undef,
Boolean $manage_autosave_dir = lookup('epics::ioc::manage_autosave_dir', Boolean),
Boolean $auto_restart_ioc = lookup('epics::ioc::auto_restart_ioc', Boolean),
String $autosave_base_dir = lookup('epics::ioc::autosave_base_dir', String),
String $bootdir = lookup('epics::ioc::bootdir', String),
Optional[String] $ca_addr_list = undef,
Optional[Boolean] $ca_auto_addr_list = undef,
Optional[Integer] $ca_max_array_bytes = undef,
String $startscript = lookup('epics::ioc::startscript', String),
Boolean $enable_console_port = lookup('epics::ioc::enable_console_port', Boolean),
Stdlib::Port $console_port = lookup('epics::ioc::console_port', Stdlib::Port),
Boolean $enable_unix_domain_socket = lookup('epics::ioc::enable_unix_domain_socket', Boolean),
String $unix_domain_socket = "softioc-${name}/procServ.sock",
Integer $coresize = lookup('epics::ioc::coresize', Integer),
Array[String] $cfg_append = lookup('epics::ioc::cfg_append', Array[String]),
Hash[String, Data, default, default] $env_vars = lookup('epics::ioc::env_vars', Hash[String, Data, default, default]),
Stdlib::Port $log_port = lookup('epics::ioc::log_port', Stdlib::Port),
Optional[Stdlib::Host] $log_server = lookup('epics::ioc::log_server', { 'value_type' => Optional[Stdlib::Host], 'default_value' => undef }),
Optional[String] $ca_sec_file = undef,
Stdlib::Absolutepath $procserv_log_file = "/var/log/softioc-${name}/procServ.log",
Boolean $logrotate_compress = lookup('epics::ioc::logrotate_compress', Boolean),
Integer $logrotate_rotate = lookup('epics::ioc::logrotate_rotate', Integer),
String $logrotate_size = lookup('epics::ioc::logrotate_size', String),
Boolean $run_make = lookup('epics::ioc::run_make', Boolean),
Boolean $run_make_after_pkg_update = lookup('epics::ioc::run_make_after_pkg_update', Boolean),
Optional[Integer] $uid = undef,
String $username = lookup('epics::ioc::username', { 'default_value' => "softioc-${name}" }),
Boolean $manage_user = lookup('epics::ioc::manage_user', Boolean),
Array[String] $systemd_after = lookup('epics::ioc::systemd_after', Array[String]),
Array[String] $systemd_requires = lookup('epics::ioc::systemd_requires', Array[String]),
Array[String] $systemd_requires_mounts_for = lookup('epics::ioc::systemd_requires_mounts_for', Array[String]),
Array[String] $systemd_wants = lookup('epics::ioc::systemd_wants', Array[String]),
)
{
require "::${module_name}"
include "::${module_name}::ioc::software"
include "::${module_name}::carepeater"
$real_systemd_after = $systemd_after << 'caRepeater.service'
$real_systemd_wants = $systemd_wants << 'caRepeater.service'
$abstopdir = "${epics::iocbase}/${name}"
if($bootdir) {
$absbootdir = "${abstopdir}/${bootdir}"
} else {
$absbootdir = $abstopdir
}
if $ca_addr_list {
$env_vars2 = merge($env_vars, {'EPICS_CA_ADDR_LIST' => $ca_addr_list})
} else {
$env_vars2 = $env_vars
}
if $ca_auto_addr_list {
$auto_addr_list_str = $ca_auto_addr_list ? {
true => 'YES',
false => 'NO',
}
$env_vars3 = merge($env_vars2, {'EPICS_CA_AUTO_ADDR_LIST' => $auto_addr_list_str})
} else {
$env_vars3 = $env_vars2
}
if $ca_max_array_bytes {
$env_vars4 = merge($env_vars3, {'EPICS_CA_MAX_ARRAY_BYTES' => $ca_max_array_bytes})
} else {
$env_vars4 = $env_vars3
}
$env_vars5 = merge($env_vars4, {'EPICS_IOC_LOG_PORT' => $log_port})
if $log_server {
$env_vars6 = merge($env_vars5, {'EPICS_IOC_LOG_INET' => $log_server})
} else {
$env_vars6 = $env_vars5
}
if $ca_sec_file {
$env_vars7 = merge($env_vars6, {'EPICS_CA_SEC_FILE' => $ca_sec_file})
} else {
$env_vars7 = $env_vars6
}
if $manage_autosave_dir {
$real_env_vars = merge($env_vars7, {'AUTOSAVE_DIR' => "${autosave_base_dir}/softioc-${name}"})
} else {
$real_env_vars = $env_vars7
}
if $enable_console_port {
include "::${module_name}::ioc::telnet"
}
if $enable_unix_domain_socket {
include "::${module_name}::ioc::unix_domain_socket"
}
if $run_make {
exec { "build IOC ${name}":
command => '/usr/bin/make distclean all',
cwd => $abstopdir,
umask => '002',
unless => '/usr/bin/make CHECK_RELEASE=NO CHECK_RELEASE_NO= --question',
require => Class["::${module_name}::ioc::software"],
subscribe => Package['epics-dev'],
}
}
if $manage_user {
user { $username:
comment => "${name} IOC",
home => "/epics/iocs/${name}",
groups => 'softioc',
uid => $uid,
before => Service["softioc-${name}"],
}
}
if($manage_autosave_dir) {
file { "${autosave_base_dir}/softioc-${name}":
ensure => directory,
owner => $username,
group => 'softioc',
mode => '0775',
before => Service["softioc-${name}"],
}
}
case $::service_provider {
'systemd': {
$absstartscript = "${absbootdir}/${startscript}"
systemd::unit_file { "softioc-${name}.service":
content => template("${module_name}/etc/systemd/system/ioc.service"),
notify => Service["softioc-${name}"],
}
$postrotate = "/bin/systemctl kill --signal=HUP --kill-who=main softioc-${name}.service"
}
'init', 'debian': {
file { "/etc/iocs/${name}":
ensure => directory,
group => 'softioc',
}
file { "/etc/iocs/${name}/config":
ensure => present,
content => template("${module_name}/etc/iocs/ioc_config"),
notify => Service["softioc-${name}"],
}
exec { "create init script for softioc ${name}":
command => "/usr/bin/manage-iocs install ${name}",
require => File["/etc/iocs/${name}/config"],
creates => "/etc/init.d/softioc-${name}",
before => Service["softioc-${name}"],
}
$postrotate = "/bin/kill --signal=HUP `cat /run/softioc-${name}.pid`"
}
default: {
fail("Module '${module_name}' doesn't support service provider '${::service_provider}', yet. Pull-requests welcome ;-)")
}
}
file { "/var/log/softioc-${name}":
ensure => directory,
owner => $username,
group => 'softioc',
mode => '2755',
}
logrotate::rule { "softioc-${name}":
path => $procserv_log_file,
rotate_every => 'day',
rotate => $logrotate_rotate,
size => $logrotate_size,
missingok => true,
ifempty => false,
postrotate => $postrotate,
compress => $logrotate_compress,
}
service { "softioc-${name}":
ensure => $ensure,
enable => $enable,
hasrestart => true,
hasstatus => true,
provider => $::service_provider,
require => [
Class["::${module_name}::carepeater"],
Class["::${module_name}::ioc::software"],
File["/var/log/softioc-${name}"],
],
}
if $::service_provider == 'systemd' {
Class['systemd::systemctl::daemon_reload'] -> Service["softioc-${name}"]
}
if $run_make and $run_make_after_pkg_update {
Package <| tag == 'epics_ioc_pkg' |> ~> Exec["build IOC ${name}"]
} elsif !$run_make and $run_make_after_pkg_update {
fail("Module '${module_name}': run_make_after_pkg_update => true cannot be combined with run_make => false")
}
if $run_make and $auto_restart_ioc {
Exec["build IOC ${name}"] ~> Service["softioc-${name}"]
} elsif !$run_make and $auto_restart_ioc {
fail("Module '${module_name}': auto_restart_ioc => true cannot be combined with run_make => false")
}
}
|