Defined Type: openiosds::zookeeper

Defined in:
manifests/zookeeper.pp

Overview

Configure and install an OpenIO zookeeper service

Parameters:

  • action (Any) (defaults to: 'create')
  • type (Any) (defaults to: 'zookeeper')
  • num (Any) (defaults to: '0')
  • ns (Any) (defaults to: undef)
  • ipaddress (Any) (defaults to: $::ipaddress)
  • port (Any) (defaults to: $::openiosds::params::zookeeper_port)
  • tickTime (Any) (defaults to: '2000')
  • initLimit (Any) (defaults to: '10')
  • syncLimit (Any) (defaults to: '5')
  • maxClientCnxns (Any) (defaults to: '200')
  • servers (Any) (defaults to: undef)
  • autopurge_snapretaincount (Any) (defaults to: '3')
  • autopurge_purgeinterval (Any) (defaults to: '1')
  • bootstrap (Any) (defaults to: false)
  • myid (Any) (defaults to: undef)
  • dataDir (Any) (defaults to: undef)
  • logdir (Any) (defaults to: undef)
  • logprop (Any) (defaults to: 'INFO,ROLLINGFILE')
  • logMaxFileSize (Any) (defaults to: '10MB')
  • no_exec (Any) (defaults to: false) 


2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
 
# File 'manifests/zookeeper.pp', line 2

define openiosds::zookeeper (
  $action                    = 'create',
  $type                      = 'zookeeper',
  $num                       = '0',

  $ns                        = undef,
  $ipaddress                 = $::ipaddress,
  $port                      = $::openiosds::params::zookeeper_port,
  $tickTime                  = '2000',
  $initLimit                 = '10',
  $syncLimit                 = '5',
  $maxClientCnxns            = '200',
  $servers                   = undef,
  $autopurge_snapretaincount = '3',
  $autopurge_purgeinterval   = '1',
  $bootstrap                 = false,
  $myid                      = undef,
  $dataDir                   = undef,
  $logdir                    = undef,
  $logprop                   = 'INFO,ROLLINGFILE',
  $logMaxFileSize            = '10MB',

  $no_exec                   = false,
) {

  if ! defined(Class['openiosds']) {
    include openiosds
  }

  # OS dependent parameters
  case $::osfamily {
    'Debian': {
      $classpath = '/etc/zookeeper/conf:/usr/share/java/jline.jar:/usr/share/java/log4j-1.2.jar:/usr/share/java/xercesImpl.jar:/usr/share/java/xmlParserAPIs.jar:/usr/share/java/netty.jar:/usr/share/java/slf4j-api.jar:/usr/share/java/slf4j-log4j12.jar:/usr/share/java/zookeeper.jar'
      $packages = ['zookeeperd','python-zookeeper']
    }
    'RedHat': {
      case $::operatingsystem {
        'Fedora': {
          case $::operatingsystemrelease {
            '21': {$classpath = '/usr/share/java/log4j12-1.2.17.jar:/usr/share/java/zookeeper/zookeeper.jar:/usr/share/java/slf4j/slf4j-simple.jar:/usr/share/java/slf4j/api.jar:/usr/share/java/slf4j/nop.jar:/usr/share/java/slf4j/slf4j-api.jar:/usr/share/java/slf4j/slf4j-nop.jar:/usr/share/java/slf4j/simple.jar:/usr/share/java/slf4j/slf4j-api.jar:/usr/lib/java/jline1/jline-1.0.jar:/usr/share/java/netty3-3.6.6.jar'}
            default: {
                $classpath = '/usr/share/zookeeper/log4j-1.2.16.jar:/usr/share/zookeeper/netty-3.7.0.Final.jar:/usr/share/zookeeper/slf4j-api-1.6.1.jar:/usr/share/zookeeper/slf4j-log4j12-1.6.1.jar:/usr/share/zookeeper/zookeeper-3.4.8.jar'
            }
          }
          $packages = ['zookeeper','java-1.8.0-openjdk-headless','python-zookeeper']
        }
        default: {
          $classpath = '/usr/share/zookeeper/log4j-1.2.16.jar:/usr/share/zookeeper/netty-3.7.0.Final.jar:/usr/share/zookeeper/slf4j-api-1.6.1.jar:/usr/share/zookeeper/slf4j-log4j12-1.6.1.jar:/usr/share/zookeeper/zookeeper-3.4.8.jar'
          $packages = ['zookeeper','java-1.8.0-openjdk-headless','python-ZooKeeper']
        }
      }
    }
  }

  # Validation
  $actions = ['create','remove']
  validate_re($action,$actions,"${action} is invalid.")
  validate_string($type)
  validate_integer($num)

  validate_string($ns)
  if ! has_interface_with('ipaddress',$ipaddress) { fail("${ipaddress} is invalid.") }
  validate_integer($port)

  if $servers {
    if is_string($servers) { $servers_array = split($servers,'[;,]') }
    elsif is_array($servers) { $servers_array = $servers }
    else { fail("${servers} is not an array.") }
  }
  validate_integer($autopurge_snapretaincount)
  validate_integer($autopurge_purgeinterval)
  if $myid { validate_integer($myid) }
  if $dataDir {
    $_dataDir = $dataDir
    $rootDir = dirname($_dataDir)
  } else {
    $_dataDir = "${openiosds::sharedstatedir}/${ns}/${type}-${num}/data"
    $rootDir = "${openiosds::sharedstatedir}/${ns}/${type}-${num}"
  }
  if $logdir { $_logdir = $logdir }
  else { $_logdir = "${openiosds::logdir}/${ns}/${type}-${num}" }
  validate_string($logprop)
  validate_string($logMaxFileSize)

  # Namespace
  if $action == 'create' {
    if ! defined(Openiosds::Namespace[$ns]) {
      fail('You must include the namespace class before using OpenIO defined types.')
    }
  }

  # Packages
  # openjdk mandatory for zookeeper. gcj is bullhsit
  package { $packages:
    ensure        => $openiosds::package_ensure,
    allow_virtual => false,
  } ->
  # Service
  openiosds::service {"${ns}-${type}-${num}":
    action => $action,
    type   => $type,
    num    => $num,
    ns     => $ns,
    volume => $rootDir,
  } ->
  # Data path
  file { $_dataDir:
    ensure  => $openiosds::directory_ensure,
    owner   => $openiosds::user,
    group   => $openiosds::group,
    mode    => $openiosds::directory_mode,
    require => Openiosds::Service["${ns}-${type}-${num}"]
  }
  # Configuration files
  file { "${openiosds::sysconfdir}/${ns}/${type}-${num}/zoo.cfg":
    ensure  => $openiosds::file_ensure,
    owner   => $openiosds::user,
    group   => $openiosds::group,
    content => template('openiosds/zoo.cfg.erb'),
    require => [Package[$packages],File[$_dataDir]],
    notify  => Gridinit::Program["${ns}-${type}-${num}"],
  }
  file { "${openiosds::sysconfdir}/${ns}/${type}-${num}/java.env":
    ensure  => $openiosds::file_ensure,
    owner   => $openiosds::user,
    group   => $openiosds::group,
    content => template('openiosds/zookeeper_java.env.erb'),
    require => [Package[$packages],File[$_dataDir]],
    notify  => Gridinit::Program["${ns}-${type}-${num}"],
  }
  file { "${openiosds::sysconfdir}/${ns}/${type}-${num}/log4j.properties":
    ensure  => $openiosds::file_ensure,
    owner   => $openiosds::user,
    group   => $openiosds::group,
    content => template('openiosds/zookeeper_log4j.properties.erb'),
    require => [Package[$packages],File[$_dataDir]],
    notify  => Gridinit::Program["${ns}-${type}-${num}"],
  }
  gridinit::program { "${ns}-${type}-${num}":
    action  => $action,
    command => "java -Dzookeeper.log.dir=${_logdir} -Dzookeeper.root.logger=${logprop} -cp ${openiosds::sysconfdir}/${ns}/${type}-${num}:${classpath} -Dcom.sun.management.jmxremote -Dcom.sun.management.jmxremote.local.only=false org.apache.zookeeper.server.quorum.QuorumPeerMain ${openiosds::sysconfdir}/${ns}/${type}-${num}/zoo.cfg",
    group   => "${ns},${type},${type}-${num}",
    uid     => $openiosds::user,
    gid     => $openiosds::group,
    no_exec => $no_exec,
  }
  # ZooKeeper Bootstrap
  if $bootstrap {
    exec { 'bootstrap':
      command => "/bin/sleep 10 && ${openiosds::bindir}/zk-bootstrap.py ${ns}",
      onlyif  => "/usr/bin/test -r ${openiosds::sysconfdir_globald}/${ns}",
      unless  => "/bin/sleep 3 && echo \"ls /hc/ns/${ns}\" | ${openiosds::bindir}/zkCli.sh -server ${ipaddress}:${port} | grep srv" ,
      require => [Gridinit::Program["${ns}-${type}-${num}"],Openiosds::Namespace[$ns]],
    }
  }
  if $myid {
    file {"${openiosds::sharedstatedir}/${ns}/${type}-${num}/data/myid":
      ensure  => $openiosds::file_ensure,
      owner   => $openiosds::user,
      group   => $openiosds::group,
      content => $myid,
    }
  }

}