Puppet Class: openshift_origin::mcollective_server

Defined in:
manifests/mcollective_server.pp

Overview

Copyright 2013 Mojo Lingo LLC. Modifications by Red Hat, Inc.

Licensed under the Apache License, Version 2.0 (the "License");
you may not use this file except in compliance with the License.
You may obtain a copy of the License at

    http://www.apache.org/licenses/LICENSE-2.0

Unless required by applicable law or agreed to in writing, software
distributed under the License is distributed on an "AS IS" BASIS,
WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
See the License for the specific language governing permissions and
limitations under the License.



16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
 
# File 'manifests/mcollective_server.pp', line 16

class openshift_origin::mcollective_server {
  include openshift_origin::params

  package { "${::openshift_origin::params::ruby_scl_prefix}mcollective":
    alias   => 'mcollective',
    require => Class['openshift_origin::install_method'],
  }

  $cluster_members = $::openshift_origin::mcollective_cluster_members

  if $cluster_members {
    $pool_size = size($cluster_members)
  } else {
    $pool_size = '1'
  }

  # Ensure classes are run in order
  Class['Openshift_origin::Role']              -> Class['Openshift_origin::Mcollective_server']
  Class['Openshift_origin::Update_conf_files'] -> Class['Openshift_origin::Mcollective_server']

  file { "${::openshift_origin::params::ruby_scl_path_prefix}/var/run":
    ensure  => 'directory',
    require => Package['mcollective'],
  }

  file { 'mcollective server config':
    ensure  => present,
    path    => "${::openshift_origin::params::ruby_scl_path_prefix}/etc/mcollective/server.cfg",
    content => template('openshift_origin/mcollective/mcollective-server.cfg.erb'),
    owner   => 'root',
    group   => 'root',
    mode    => '0640',
    require => Package['mcollective'],
    notify  => Service["${::openshift_origin::params::ruby_scl_prefix}mcollective"],
  }

  if( $::operatingsystem == 'Fedora' ) {
    exec { 'systemd-daemon-reload':
      command     => '/usr/bin/systemctl daemon-reload',
      refreshonly => true,
    }

    $require_real = [
      File['mcollective server config', '/usr/lib/systemd/system/mcollective.service'],
      Exec['systemd-daemon-reload']
    ]

    file { '/usr/lib/systemd/system/mcollective.service':
      content => template('openshift_origin/mcollective/mcollective.service'),
      require => Package['mcollective'],
      notify  => Service["${::openshift_origin::params::ruby_scl_prefix}mcollective"]
    }
  } else {
    $require_real = File['mcollective server config']
  }

  service { "${::openshift_origin::params::ruby_scl_prefix}mcollective":
    ensure     => true,
    enable     => true,
    hasstatus  => true,
    hasrestart => true,
    require    => $require_real,
    provider   => $::openshift_origin::params::os_init_provider,
  }

  exec { 'openshift-facts':
    command     => "/usr/bin/oo-exec-ruby ${::openshift_origin::params::ruby_scl_path_prefix}/usr/libexec/mcollective/update_yaml.rb ${::openshift_origin::params::ruby_scl_path_prefix}/etc/mcollective/facts.yaml",
    environment => ['LANG=en_US.UTF-8', 'LC_ALL=en_US.UTF-8'],
    require     => [
      Package['openshift-origin-msg-node-mcollective'],
      Package['mcollective'],
      File['openshift node config'],
    ],
    refreshonly => true,
  }
}