Puppet Class: ceilometer::agent::polling

Inherits:
ceilometer
Defined in:
manifests/agent/polling.pp

Overview

Class: ceilometer::agent::polling

Installs/configures the ceilometer polling agent

Parameters:

enabled

(Optional) Should the service be enabled. Defaults to true.

manage_service

(Optional) Whether the service should be managed by Puppet. Defaults to true.

separate_services

(Optional) Use separate services for individual namespace. Defaults to false.

package_ensure

(Optional) ensure state for package. Defaults to ‘present’

manage_user

(Optional) Should the system user should be managed. When this flag is true then the class ensures the ceilometer user belongs to nova/libvirt group. Defaults to true.

central_namespace

(Optional) Use central namespace for polling agent. Defaults to true.

compute_namespace

(Optional) Use compute namespace for polling agent. Defaults to true.

ipmi_namespace

(Optional) Use ipmi namespace for polling agent. Defaults to true.

instance_discovery_method

(Optional) method to discovery instances running on compute node Defaults to $facts

* naive: poll nova to get all instances
* workload_partitioning: poll nova to get instances of the compute
* libvirt_metadata: get instances from libvirt metadata
  but without instance metadata (recommended for Gnocchi backend).
resource_update_interval

(Optional) New instances will be discovered periodically based on this option (in seconds). Defaults to $facts.

resource_cache_expiry

(Optional) The expiry to totally refresh the instances resource cache. Defaults to $facts.

manage_polling

(Optional) Whether to manage polling.yaml Defaults to false

polling_interval

(Optional) Number of seconds between polling cycle Defaults to 600 seconds, used only if manage_polling is true.

polling_meters

(Optional) Array of strings with meters to add to the polling.yaml file, used only if manage_polling is true. Defaults to $::ceilometer::params::polling_meters

polling_config

(Optional) A hash of the polling.yaml configuration. This is used only if manage_polling is true. Defaults to undef

batch_size

(Optional) Batch size of samples to send to notification agent. Defaults to $facts

tenant_name_discovery

(optional) Identify user and project names from polled metrics. Defaults to $facts.

Parameters:

  • manage_service (Any) (defaults to: true)
  • enabled (Any) (defaults to: true)
  • separate_services (Any) (defaults to: false)
  • package_ensure (Any) (defaults to: 'present')
  • manage_user (Any) (defaults to: true)
  • central_namespace (Any) (defaults to: true)
  • compute_namespace (Any) (defaults to: true)
  • ipmi_namespace (Any) (defaults to: true)
  • instance_discovery_method (Any) (defaults to: $facts['os_service_default'])
  • resource_update_interval (Any) (defaults to: $facts['os_service_default'])
  • resource_cache_expiry (Any) (defaults to: $facts['os_service_default'])
  • manage_polling (Any) (defaults to: false)
  • polling_interval (Any) (defaults to: 600)
  • polling_meters (Any) (defaults to: $::ceilometer::params::polling_meters)
  • polling_config (Any) (defaults to: undef)
  • batch_size (Any) (defaults to: $facts['os_service_default'])
  • tenant_name_discovery (Any) (defaults to: $facts['os_service_default']) 


84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
 
# File 'manifests/agent/polling.pp', line 84

class ceilometer::agent::polling (
  $manage_service            = true,
  $enabled                   = true,
  $separate_services         = false,
  $package_ensure            = 'present',
  $manage_user               = true,
  $central_namespace         = true,
  $compute_namespace         = true,
  $ipmi_namespace            = true,
  $instance_discovery_method = $facts['os_service_default'],
  $resource_update_interval  = $facts['os_service_default'],
  $resource_cache_expiry     = $facts['os_service_default'],
  $manage_polling            = false,
  $polling_interval          = 600,
  $polling_meters            = $::ceilometer::params::polling_meters,
  $polling_config            = undef,
  $batch_size                = $facts['os_service_default'],
  $tenant_name_discovery     = $facts['os_service_default'],
) inherits ceilometer {

  include ceilometer::deps
  include ceilometer::params

  validate_legacy(Boolean, 'validate_bool', $manage_service)
  validate_legacy(Boolean, 'validate_bool', $enabled)
  validate_legacy(Boolean, 'validate_bool', $separate_services)
  validate_legacy(Boolean, 'validate_bool', $manage_user)
  validate_legacy(Boolean, 'validate_bool', $central_namespace)
  validate_legacy(Boolean, 'validate_bool', $compute_namespace)
  validate_legacy(Boolean, 'validate_bool', $ipmi_namespace)
  validate_legacy(Boolean, 'validate_bool', $manage_polling)

  if $central_namespace {
    $central_namespace_name = 'central'
    ceilometer_config {
      # set `tenant_name_discovery` parameter only on the nodes
      # where central namespace is enabled
      'DEFAULT/tenant_name_discovery': value => $tenant_name_discovery;
    }
  } else {
    $central_namespace_name = undef
    ceilometer_config {
      'DEFAULT/tenant_name_discovery': ensure => absent;
    }
  }

  if $compute_namespace {
    if $manage_user {
      # The ceilometer user created by the ceilometer-common package does not
      # belong to nova/libvirt group. That group membership is required so that
      # the ceilometer user can access libvirt to gather some metrics.
      $ceilometer_groups = delete_undef_values([
        'nova',
        $::ceilometer::params::libvirt_group
      ])

      user { 'ceilometer':
        ensure  => present,
        name    => 'ceilometer',
        gid     => 'ceilometer',
        groups  => $ceilometer_groups,
        require => Anchor['ceilometer::install::end'],
        before  => Anchor['ceilometer::service::begin'],
      }

      if $::ceilometer::params::libvirt_group {
        Package <| title == 'libvirt' |> -> User['ceilometer']
      }
      Package <| title == 'nova-common' |> -> User['ceilometer']

      User['ceilometer'] -> Anchor['ceilometer::service::begin']
    }

    $compute_namespace_name = 'compute'
    ceilometer_config {
      'compute/instance_discovery_method': value => $instance_discovery_method;
      'compute/resource_update_interval':  value => $resource_update_interval;
      'compute/resource_cache_expiry':     value => $resource_cache_expiry;
    }
  } else {
    $compute_namespace_name = undef
    ceilometer_config {
      'compute/instance_discovery_method': ensure => absent;
      'compute/resource_update_interval':  ensure => absent;
      'compute/resource_cache_expiry':     ensure => absent;
    }
  }

  if $ipmi_namespace {
    $ipmi_namespace_name = 'ipmi'
  } else {
    $ipmi_namespace_name = undef
  }

  if $separate_services {
    if $central_namespace {
      package { 'ceilometer-central':
        ensure => $package_ensure,
        name   =>  $::ceilometer::params::agent_central_package_name,
        tag    => ['openstack', 'ceilometer-package'],
      }
    }

    if $compute_namespace {
      package { 'ceilometer-compute':
        ensure => $package_ensure,
        name   =>  $::ceilometer::params::agent_compute_package_name,
        tag    => ['openstack', 'ceilometer-package'],
      }
    }

    if $ipmi_namespace {
      package { 'ceilometer-ipmi':
        ensure => $package_ensure,
        name   =>  $::ceilometer::params::agent_ipmi_package_name,
        tag    => ['openstack', 'ceilometer-package'],
      }
    }

  } else {
    package { 'ceilometer-polling':
      ensure => $package_ensure,
      name   => $::ceilometer::params::agent_polling_package_name,
      tag    => ['openstack', 'ceilometer-package'],
    }
  }

  $namespaces_real = delete_undef_values([
    $central_namespace_name,
    $compute_namespace_name,
    $ipmi_namespace_name
  ])

  if empty($namespaces_real) or $separate_services {
    ceilometer_config {
      'DEFAULT/polling_namespaces': ensure => absent
    }
  } else {
    ceilometer_config {
      'DEFAULT/polling_namespaces': value => join($namespaces_real, ',')
    }
  }

  ceilometer_config {
    'polling/batch_size': value => $batch_size
  }

  if $manage_service {
    if $enabled {
      $service_ensure = 'running'
    } else {
      $service_ensure = 'stopped'
    }

    if $separate_services {
      if $central_namespace {
        service { 'ceilometer-central':
          ensure     => $service_ensure,
          name       => $::ceilometer::params::agent_central_service_name,
          enable     => $enabled,
          hasstatus  => true,
          hasrestart => true,
          tag        => 'ceilometer-service',
        }
      }
      if $compute_namespace {
        service { 'ceilometer-compute':
          ensure     => $service_ensure,
          name       => $::ceilometer::params::agent_compute_service_name,
          enable     => $enabled,
          hasstatus  => true,
          hasrestart => true,
          tag        => 'ceilometer-service',
        }
      }
      if $ipmi_namespace {
        service { 'ceilometer-ipmi':
          ensure     => $service_ensure,
          name       => $::ceilometer::params::agent_ipmi_service_name,
          enable     => $enabled,
          hasstatus  => true,
          hasrestart => true,
          tag        => 'ceilometer-service',
        }
      }
    } else {
      service { 'ceilometer-polling':
        ensure     => $service_ensure,
        name       => $::ceilometer::params::agent_polling_service_name,
        enable     => $enabled,
        hasstatus  => true,
        hasrestart => true,
        tag        => 'ceilometer-service',
      }
    }
  }

  if $manage_polling {
    if $polling_config {
      validate_legacy(Hash, 'validate_hash', $polling_config)
      $polling_content = to_yaml($polling_config)
    } else {
      $polling_content = template('ceilometer/polling.yaml.erb')
    }

    file { 'polling':
      ensure                  => present,
      path                    => $::ceilometer::params::polling,
      content                 => $polling_content,
      mode                    => '0640',
      owner                   => 'root',
      group                   => $::ceilometer::params::group,
      selinux_ignore_defaults => true,
      tag                     => 'ceilometer-yamls',
    }
  }
}