Puppet Class: ceph::repo

Inherits:
ceph::params
Defined in:
manifests/repo.pp

Overview

Copyright © 2013, 2014 iWeb Technologies Inc.

Copyright (C) 2013 Cloudwatt <libre.licensing@cloudwatt.com>
Copyright (C) 2014 Nine Internet Solutions AG
Copyright (C) 2014 Catalyst IT Limited
Copyright (C) 2015 Red Hat

Licensed under the Apache License, Version 2.0 (the "License");
you may not use this file except in compliance with the License.
You may obtain a copy of the License at

    http://www.apache.org/licenses/LICENSE-2.0

Unless required by applicable law or agreed to in writing, software
distributed under the License is distributed on an "AS IS" BASIS,
WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
See the License for the specific language governing permissions and
limitations under the License.

Author: Loic Dachary <loic@dachary.org> Author: Francois Charlier <francois.charlier@enovance.com> Author: David Moreau Simard <dmsimard@iweb.com> Author: Andrew Woodward <awoodward@mirantis.com> Author: David Gurtner <aldavud@crimson.ch> Author: Ricardo Rocha <ricardo@catalyst.net.nz> Author: Emilien Macchi <emilien@redhat.com>

Class: ceph::repo

Configure ceph APT repo for Ceph

Parameters:

ensure

The ensure state for package ressources.

Optional. Defaults to 'present'.
release

The name of the Ceph release to install

Optional. Default to 'nautilus' in ceph::params.
proxy

Proxy URL to be used for the yum repository, useful if you’re behind a corporate firewall

Optional. Defaults to 'undef'
proxy_username

The username to be used for the proxy if one should be required

Optional. Defaults to 'undef'
proxy_password

The password to be used for the proxy if one should be required

Optional. Defaults to 'undef'
enable_epel

Whether or not enable EPEL repository.

Optional. Defaults to True
enable_sig

Whether or not enable SIG repository.

CentOS SIG repository contains Ceph packages built by CentOS community.
https://wiki.centos.org/SpecialInterestGroup/Storage/
Optional. Defaults to False in ceph::params.
stream

Whether this is CentOS Stream or not. This parameter is used in CentOS only.

Optional. Defaults to False.
ceph_mirror

Ceph mirror used to download packages.

Optional. Defaults to undef.

DEPRECATED PARAMETERS

fastcgi

Install Ceph fastcgi apache module for Ceph

Optional. Defaults to 'false'

Parameters:

  • ensure (Any) (defaults to: present)
  • release (String[1]) (defaults to: $ceph::params::release)
  • proxy (Any) (defaults to: undef)
  • proxy_username (Any) (defaults to: undef)
  • proxy_password (Any) (defaults to: undef)
  • enable_epel (Boolean) (defaults to: true)
  • enable_sig (Boolean) (defaults to: $ceph::params::enable_sig)
  • stream (Boolean) (defaults to: false)
  • ceph_mirror (Any) (defaults to: undef)
  • fastcgi (Boolean) (defaults to: false) 


67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
 
# File 'manifests/repo.pp', line 67

class ceph::repo (
  $ensure              = present,
  String[1] $release   = $ceph::params::release,
  $proxy               = undef,
  $proxy_username      = undef,
  $proxy_password      = undef,
  Boolean $enable_epel = true,
  Boolean $enable_sig  = $ceph::params::enable_sig,
  Boolean $stream      = false,
  $ceph_mirror         = undef,
  # DEPRECATED PARAMETERS
  Boolean $fastcgi     = false,
) inherits ceph::params {

  if $fastcgi and !$ceph::params::fastcgi_available {
    warning('The mod_fastcgi package is not available for this operating system version')
  }

  case $facts['os']['family'] {
    'Debian': {
      include apt

      if $ceph_mirror {
        $ceph_mirror_real = $ceph_mirror
      } else {
        $ceph_mirror_real = "http://download.ceph.com/debian-${release}/"
        apt::key { 'ceph':
          ensure => $ensure,
          id     => '08B73419AC32B4E966C1A330E84AC2C0460F3994',
          source => 'https://download.ceph.com/keys/release.asc',
          before => Apt::Source['ceph'],
        }
      }

      apt::source { 'ceph':
        ensure   => $ensure,
        location => $ceph_mirror_real,
        release  => $facts['os']['distro']['codename'],
        tag      => 'ceph',
      }

      if $fastcgi {
        apt::key { 'ceph-gitbuilder':
          ensure => $ensure,
          id     => 'FCC5CB2ED8E6F6FB79D5B3316EAEAE2203C3951A',
          server => 'keyserver.ubuntu.com',
        }

        apt::source { 'ceph-fastcgi':
          ensure   => $ensure,
          location => "http://gitbuilder.ceph.com/libapache-mod-fastcgi-deb-${facts['os']['distro']['codename']}-${facts['os']['hardware']}-basic/ref/master",
          release  => $facts['os']['distro']['codename'],
          require  => Apt::Key['ceph-gitbuilder'],
        }

      }

      Apt::Source<| tag == 'ceph' |> -> Package<| tag == 'ceph' |>
      Exec['apt_update'] -> Package<| tag == 'ceph' |>
    }

    'RedHat': {
      $el = $facts['os']['release']['major']

      # If you want to deploy Ceph using packages provided by CentOS SIG
      # https://wiki.centos.org/SpecialInterestGroup/Storage/
      if $enable_sig {
        if $facts['os']['name'] != 'CentOS' {
          warning("CentOS SIG repository is only supported on CentOS operating system, \
not on ${facts['os']['name']}, which can lead to packaging issues.")
        }
        if $ceph_mirror {
          $ceph_mirror_real = $ceph_mirror
        } else {
          # NOTE(tobias-urdin): mirror.centos.org doesnt have https support
          if $stream {
            if versioncmp($el, '9') >= 0 {
              $centos_mirror = 'https://mirror.stream.centos.org/SIGs'
            } else {
              $centos_mirror = 'http://mirror.centos.org/centos'
            }
            $ceph_mirror_real = "${centos_mirror}/${el}-stream/storage/x86_64/ceph-${release}/"
          } else {
            $ceph_mirror_real = "http://mirror.centos.org/centos/${el}/storage/x86_64/ceph-${release}/"
          }
        }
        yumrepo { 'ceph-storage-sig':
          ensure     => $ensure,
          baseurl    => $ceph_mirror_real,
          descr      => 'Ceph Storage SIG',
          mirrorlist => 'absent',
          gpgcheck   => '0',
        }
        # Make sure we install the repo before any Package resource
        Yumrepo['ceph-storage-sig'] -> Package<| tag == 'ceph' |>
      } else {
        # If you want to deploy Ceph using packages provided by ceph.com repositories.
        Yumrepo {
          proxy          => $proxy,
          proxy_username => $proxy_username,
          proxy_password => $proxy_password,
        }


        yumrepo { 'ext-ceph':
          ensure     => $ensure,
          descr      => "External Ceph ${release}",
          name       => "ext-ceph-${release}",
          baseurl    => "http://download.ceph.com/rpm-${release}/el${el}/\$basearch",
          gpgcheck   => '1',
          gpgkey     => 'https://download.ceph.com/keys/release.asc',
          mirrorlist => 'absent',
          priority   => '10', # prefer ceph repos over EPEL
          tag        => 'ceph',
        }

        yumrepo { 'ext-ceph-noarch':
          ensure     => $ensure,
          descr      => 'External Ceph noarch',
          name       => "ext-ceph-${release}-noarch",
          baseurl    => "http://download.ceph.com/rpm-${release}/el${el}/noarch",
          gpgcheck   => '1',
          gpgkey     => 'https://download.ceph.com/keys/release.asc',
          mirrorlist => 'absent',
          priority   => '10', # prefer ceph repos over EPEL
          tag        => 'ceph',
        }

        if $fastcgi {
          yumrepo { 'ext-ceph-fastcgi':
            ensure     => $ensure,
            descr      => 'FastCGI basearch packages for Ceph',
            name       => 'ext-ceph-fastcgi',
            baseurl    => "http://gitbuilder.ceph.com/mod_fastcgi-rpm-rhel${el}-x86_64-basic/ref/master",
            gpgcheck   => '1',
            gpgkey     => 'https://download.ceph.com/keys/autobuild.asc',
            mirrorlist => 'absent',
            priority   => '20', # prefer ceph repos over EPEL
            tag        => 'ceph',
          }
        }

        # prefer ceph.com repos over EPEL
        package { 'yum-plugin-priorities':
          ensure => present,
        }
      }

      if $enable_epel {
        yumrepo { "ext-epel-${el}":
          ensure     => $ensure,
          descr      => "External EPEL ${el}",
          name       => "ext-epel-${el}",
          baseurl    => absent,
          gpgcheck   => '1',
          gpgkey     => "https://dl.fedoraproject.org/pub/epel/RPM-GPG-KEY-EPEL-${el}",
          mirrorlist => "http://mirrors.fedoraproject.org/metalink?repo=epel-${el}&arch=\$basearch",
          priority   => '20', # prefer ceph repos over EPEL
          tag        => 'ceph',
          exclude    => 'python-ceph-compat python-rbd python-rados python-cephfs',
        }
      }

      Yumrepo<| tag == 'ceph' |> -> Package<| tag == 'ceph' |>
    }

    default: {
      fail("Unsupported osfamily: ${facts['os']['family']}")
    }
  }
}