Puppet Class: cinder::volume

Defined in:
manifests/volume.pp

Overview

Class: cinder::volume

Parameters

package_ensure

(Optional) The state of the package. Defaults to ‘present’.

enabled

(Optional) The state of the service (boolean value) Defaults to true.

manage_service

(Optional) Whether to start/stop the service (boolean value) Defaults to true.

volume_clear

(Optional) Method used to wipe old volumes. Defaults to $::os_service_default.

volume_clear_size

(Optional) Size in MiB to wipe at start of old volumes. Set to ‘0’ means all. Defaults to $::os_service_default.

volume_clear_ionice

(Optional) The flag to pass to ionice to alter the i/o priority of the process used to zero a volume after deletion, for example “-c3” for idle only priority. Defaults to $::os_service_default.

Parameters:

  • package_ensure (Any) (defaults to: 'present')
  • enabled (Any) (defaults to: true)
  • manage_service (Any) (defaults to: true)
  • volume_clear (Any) (defaults to: $::os_service_default)
  • volume_clear_size (Any) (defaults to: $::os_service_default)
  • volume_clear_ionice (Any) (defaults to: $::os_service_default) 


32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
 
# File 'manifests/volume.pp', line 32

class cinder::volume (
  $package_ensure      = 'present',
  $enabled             = true,
  $manage_service      = true,
  $volume_clear        = $::os_service_default,
  $volume_clear_size   = $::os_service_default,
  $volume_clear_ionice = $::os_service_default,
) {

  include ::cinder::deps
  include ::cinder::params

  validate_bool($manage_service)
  validate_bool($enabled)

  if $::cinder::params::volume_package {
    package { 'cinder-volume':
      ensure => $package_ensure,
      name   => $::cinder::params::volume_package,
      tag    => ['openstack', 'cinder-package'],
    }
  }

  if $manage_service {
    if $enabled {
      $ensure = 'running'
    } else {
      $ensure = 'stopped'
    }
  }

  service { 'cinder-volume':
    ensure    => $ensure,
    name      => $::cinder::params::volume_service,
    enable    => $enabled,
    hasstatus => true,
    tag       => 'cinder-service',
  }

  cinder_config {
    'DEFAULT/volume_clear':        value => $volume_clear;
    'DEFAULT/volume_clear_size':   value => $volume_clear_size;
    'DEFAULT/volume_clear_ionice': value => $volume_clear_ionice;
  }
}