Puppet Class: ironic::pxe

Inherits:
ironic::params
Defined in:
manifests/pxe.pp

Overview

Set up PXE boot for Ironic

Parameters

package_ensure

(optional) Control the ensure parameter for the package resource Defaults to ‘present’

manage_service

(optional) Whether the service should be managed by Puppet. Defaults to true.

enabled

(optional) Define if the service must be enabled or not. Defaults to true.

tftp_root

(optional) Folder location to deploy PXE boot files Defaults to ‘/tftpboot’

http_root

(optional) Folder location to deploy HTTP PXE boot Defaults to ‘/httpboot’

http_port

(optional) port used by the HTTP service serving introspection and deployment images. Defaults to 8088

pxelinux_path

(optional) Path to directory containing pxelinux.0 . Setting this to False will skip syslinux related resources. Defaults to ‘$::ironic::params::pxelinux_path’

syslinux_path

(optional) Path to directory containing syslinux files. Setting this to False will skip syslinux related resources. Defaults to ‘$::ironic::params::syslinux_path’

syslinux_files

(optional) Array of PXE boot files to copy from $syslinux_path to $tftp_root. Defaults to ‘$::ironic::params::syslinux_files’

tftp_bind_host

(optional) The IP address TFTP server will listen on for TFTP. Defaults to undef (listen on all ip addresses).

ipxe_name_base

(optional) Beginning of the source file name which is copied to $tftproot/ipxe.efi. Setting this to ‘ipxe-snponly’ on CentOS/RHEL would results in the source file being /usr/share/ipxe/ipxe-snponly-x86_64.efi. Defaults to $::ironic::params::ipxe_name_base

uefi_ipxe_bootfile_name

(optional) Name of efi file used to boot servers with iPXE + UEFI. This should be consistent with the uefi_ipxe_bootfile_name parameter in pxe driver. Defaults to $::ironic::params::uefi_ipxe_bootfile_name

uefi_pxe_bootfile_name

(optional) Name of efi file used to boot servers with PXE + UEFI. This should be consistent with the uefi_pxe_bootfile_name parameter in pxe driver. Defaults to $::ironic::params::uefi_pxe_bootfile_name

tftp_use_xinetd

(optional) Override wheter to use xinetd instead of dnsmasq as the tftp service facilitator. Defaults to ironic::params::xinetd_available

dnsmasq_log_facility

(optional) Log facility of the dnsmasq process to server tftp server. Defaults to undef

manage_http_server

(optional) Set up Apache HTTP Server. Defaults to true

Parameters:

  • package_ensure (Any) (defaults to: 'present')
  • manage_service (Boolean) (defaults to: true)
  • enabled (Boolean) (defaults to: true)
  • tftp_root (Any) (defaults to: '/tftpboot')
  • http_root (Any) (defaults to: '/httpboot')
  • http_port (Any) (defaults to: 8088)
  • pxelinux_path (Any) (defaults to: $::ironic::params::pxelinux_path)
  • syslinux_path (Any) (defaults to: $::ironic::params::syslinux_path)
  • syslinux_files (Any) (defaults to: $::ironic::params::syslinux_files)
  • tftp_bind_host (Any) (defaults to: undef)
  • ipxe_name_base (Any) (defaults to: $::ironic::params::ipxe_name_base)
  • uefi_ipxe_bootfile_name (Any) (defaults to: $::ironic::params::uefi_ipxe_bootfile_name)
  • uefi_pxe_bootfile_name (Any) (defaults to: $::ironic::params::uefi_pxe_bootfile_name)
  • tftp_use_xinetd (Boolean) (defaults to: $::ironic::params::xinetd_available)
  • dnsmasq_log_facility (Any) (defaults to: undef)
  • manage_http_server (Boolean) (defaults to: true) 


94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
 
# File 'manifests/pxe.pp', line 94

class ironic::pxe (
  $package_ensure             = 'present',
  Boolean $manage_service     = true,
  Boolean $enabled            = true,
  $tftp_root                  = '/tftpboot',
  $http_root                  = '/httpboot',
  $http_port                  = 8088,
  $pxelinux_path              = $::ironic::params::pxelinux_path,
  $syslinux_path              = $::ironic::params::syslinux_path,
  $syslinux_files             = $::ironic::params::syslinux_files,
  $tftp_bind_host             = undef,
  $ipxe_name_base             = $::ironic::params::ipxe_name_base,
  $uefi_ipxe_bootfile_name    = $::ironic::params::uefi_ipxe_bootfile_name,
  $uefi_pxe_bootfile_name     = $::ironic::params::uefi_pxe_bootfile_name,
  Boolean $tftp_use_xinetd    = $::ironic::params::xinetd_available,
  $dnsmasq_log_facility       = undef,
  Boolean $manage_http_server = true,
) inherits ironic::params {

  include ironic::deps
  include ironic::pxe::common

  $tftp_root_real = pick($::ironic::pxe::common::tftp_root, $tftp_root)
  $http_root_real = pick($::ironic::pxe::common::http_root, $http_root)
  $http_port_real = pick($::ironic::pxe::common::http_port, $http_port)
  $uefi_ipxe_bootfile_name_real = pick($::ironic::pxe::common::uefi_ipxe_bootfile_name, $uefi_ipxe_bootfile_name)
  $uefi_pxe_bootfile_name_real = pick($::ironic::pxe::common::uefi_pxe_bootfile_name, $uefi_pxe_bootfile_name)

  if $facts['os']['family'] == 'RedHat' {
    $arch = "-${facts['os']['architecture']}"
  } else {
    $arch = ''
  }

  file { $tftp_root_real:
    ensure  => 'directory',
    seltype => 'tftpdir_t',
    owner   => $::ironic::params::user,
    group   => $::ironic::params::group,
    require => Anchor['ironic::config::begin'],
    before  => Anchor['ironic::config::end'],
  }

  # NOTE(tkajinam): ironic-common package is also installed by the base ironic
  #                 class so here we need ensure_resource
  ensure_resource( 'package', 'ironic-common', {
    ensure => $package_ensure,
    name   => $::ironic::params::common_package_name,
    tag    => ['openstack', 'ironic-package'],
  })

  file { "${tftp_root_real}/pxelinux.cfg":
    ensure  => 'directory',
    seltype => 'tftpdir_t',
    owner   => $::ironic::params::user,
    group   => $::ironic::params::group,
    require => Anchor['ironic::install::end'],
    tag     => 'ironic-tftp-file',
  }

  if $tftp_use_xinetd {
    if ! $::ironic::params::xinetd_available {
      fail('xinetd is not available in this distro. Please use tftp_use_xinetd=false')
    }

    package { 'tftp-server':
      ensure => $package_ensure,
      name   => $::ironic::params::tftpd_package,
      tag    => ['openstack', 'ironic-ipxe', 'ironic-support-package'],
    }

    $options = "--map-file ${tftp_root_real}/map-file"

    include xinetd

    xinetd::service { 'tftp':
      port        => '69',
      bind        => $tftp_bind_host,
      protocol    => 'udp',
      server_args => "${options} ${tftp_root_real}",
      server      => '/usr/sbin/in.tftpd',
      socket_type => 'dgram',
      cps         => '100 2',
      per_source  => '11',
      wait        => 'yes',
      subscribe   => Anchor['ironic::install::end'],
    }

    file { "${tftp_root_real}/map-file":
      ensure  => 'present',
      content => "r ^([^/]) ${tftp_root_real}/\\1",
    }
  } else {
    if ! $::ironic::params::dnsmasq_tftp_package {
      fail('ironic-dnsmasq-tftp-server is not available in this distro. Please use tftp_use_xnetd=true')
    }

    # NOTE(tkajinam): We can't use puppet-xinetd for cleanup because the xinetd
    #                 class forcefully installs the xinetd package.
    warning('Any prior xinetd based tftp server should be disabled and removed from the system.')

    file { "${tftp_root_real}/map-file":
      ensure  => 'absent',
    }

    package { 'dnsmasq-tftp-server':
      ensure => $package_ensure,
      name   => $::ironic::params::dnsmasq_tftp_package,
      tag    => ['openstack', 'ironic-ipxe', 'ironic-support-package'],
    }

    file { '/etc/ironic/dnsmasq-tftp-server.conf':
      ensure  => 'present',
      mode    => '0644',
      owner   => 'root',
      group   => 'root',
      content => template('ironic/dnsmasq_tftp_server.erb'),
    }

    if $manage_service {
      if $enabled {
        $ensure = 'running'
      } else {
        $ensure = 'stopped'
      }

      service { 'dnsmasq-tftp-server':
        ensure    => $ensure,
        name      => $::ironic::params::dnsmasq_tftp_service,
        enable    => $enabled,
        hasstatus => true,
        subscribe => File['/etc/ironic/dnsmasq-tftp-server.conf'],
      }

      Package['dnsmasq-tftp-server'] ~> Service['dnsmasq-tftp-server']
      File[$tftp_root_real] -> Service['dnsmasq-tftp-server']
    }
  }

  # NOTE(tkajinam): Ubuntu/Debian requires a separate package for pxelinux.0
  #                 and the file is stored in a different path.
  if $pxelinux_path {
    if $ironic::params::pxelinux_package {
      package { 'pxelinux':
        ensure => $package_ensure,
        name   => $::ironic::params::pxelinux_package,
        tag    => ['openstack', 'ironic-ipxe', 'ironic-support-package'],
      }
    }

    ironic::pxe::tftpboot_file { 'pxelinux.0':
      source_directory      => $pxelinux_path,
      destination_directory => $tftp_root_real,
      require               => Anchor['ironic-inspector::install::end'],
    }
  }

  if $syslinux_path {
    package { 'syslinux':
      ensure => $package_ensure,
      name   => $::ironic::params::syslinux_package,
      tag    => ['openstack', 'ironic-ipxe', 'ironic-support-package'],
    }

    ironic::pxe::tftpboot_file { $syslinux_files:
      source_directory      => $syslinux_path,
      destination_directory => $tftp_root_real,
      require               => Anchor['ironic-inspector::install::end'],
    }
  }

  package { 'ipxe':
    ensure => $package_ensure,
    name   => $::ironic::params::ipxe_package,
    tag    => ['openstack', 'ironic-ipxe', 'ironic-support-package'],
  }

  file { "${tftp_root_real}/undionly.kpxe":
    ensure    => 'file',
    seltype   => 'tftpdir_t',
    owner     => $::ironic::params::user,
    group     => $::ironic::params::group,
    mode      => '0744',
    source    => "${::ironic::params::ipxe_rom_dir}/undionly.kpxe",
    backup    => false,
    show_diff => false,
    require   => Anchor['ironic-inspector::install::end'],
    tag       => 'ironic-tftp-file',
  }

  file { "${tftp_root_real}/${uefi_ipxe_bootfile_name_real}":
    ensure    => 'file',
    seltype   => 'tftpdir_t',
    owner     => $::ironic::params::user,
    group     => $::ironic::params::group,
    mode      => '0744',
    source    => "${::ironic::params::ipxe_rom_dir}/${ipxe_name_base}${arch}.efi",
    backup    => false,
    show_diff => false,
    require   => Anchor['ironic-inspector::install::end'],
    tag       => 'ironic-tftp-file',
  }

  ensure_resource( 'package', 'grub-efi', {
    ensure => $package_ensure,
    name   => $::ironic::params::grub_efi_package,
    tag    => ['openstack', 'ironic-support-package'],
  })

  file { "${tftp_root_real}/grubx64.efi":
    ensure    => 'file',
    seltype   => 'tftpdir_t',
    owner     => $::ironic::params::user,
    group     => $::ironic::params::group,
    mode      => '0744',
    source    => "${::ironic::params::grub_efi_file}",
    backup    => false,
    show_diff => false,
    require   => Anchor['ironic-inspector::install::end'],
    tag       => 'ironic-tftp-file',
  }

  ensure_resource( 'package', 'shim', {
    ensure => $package_ensure,
    name   => $::ironic::params::shim_package,
    tag    => ['openstack', 'ironic-support-package'],
  })

  file { "${tftp_root_real}/${uefi_pxe_bootfile_name_real}":
    ensure    => 'file',
    seltype   => 'tftpdir_t',
    owner     => $::ironic::params::user,
    group     => $::ironic::params::group,
    mode      => '0744',
    source    => "${::ironic::params::shim_file}",
    backup    => false,
    show_diff => false,
    require   => Anchor['ironic-inspector::install::end'],
    tag       => 'ironic-tftp-file',
  }

  File["${tftp_root_real}"] -> File<| tag == 'ironic-tftp-file' |>

  # HTTP server
  if $manage_http_server {
    file { $http_root_real:
      ensure  => 'directory',
      seltype => 'httpd_sys_content_t',
      owner   => $::ironic::params::user,
      group   => $::ironic::params::group,
      require => Anchor['ironic::config::begin'],
      before  => Anchor['ironic::config::end'],
    }

    include apache

    apache::vhost { 'ipxe_vhost':
      priority => 10,
      options  => ['-Indexes', '+FollowSymLinks'],
      docroot  => $http_root_real,
      port     => $http_port_real,
    }
  }
}