Puppet Class: manila::scheduler

Defined in:
manifests/scheduler.pp

Overview

Class: manila::scheduler

Install and manage Manila scheduler.

Parameters

driver

(Optional) Default scheduler driver to use Defaults to $facts.

host_manager

(Optional) The scheduler host manager class to use Defaults to $facts.

max_attempts

(Optional) Maximum number of attempts to schedule a share Defaults to $facts.

package_ensure

(Optional) The state of the scheduler package Defaults to ‘present’.

enabled

(Optional) Whether to run the scheduler service Defaults to true.

manage_service

(Optional) Whether to start/stop the service Defaults to true.

DEPRECATED PARAMETERS

scheduler_driver

(Optional) Default scheduler driver to use Defaults to undef

Parameters:

  • driver (Any) (defaults to: $facts['os_service_default'])
  • host_manager (Any) (defaults to: $facts['os_service_default'])
  • max_attempts (Any) (defaults to: $facts['os_service_default'])
  • package_ensure (Any) (defaults to: 'present')
  • enabled (Boolean) (defaults to: true)
  • manage_service (Boolean) (defaults to: true)
  • scheduler_driver (Any) (defaults to: undef) 


37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
 
# File 'manifests/scheduler.pp', line 37

class manila::scheduler (
  $driver                 = $facts['os_service_default'],
  $host_manager           = $facts['os_service_default'],
  $max_attempts           = $facts['os_service_default'],
  $package_ensure         = 'present',
  Boolean $enabled        = true,
  Boolean $manage_service = true,
  # DEPRECATED PARAMETERS
  $scheduler_driver       = undef
) {

  include manila::deps
  include manila::params

  if $scheduler_driver != undef {
    warning("The scheduler_driver parameter has been deprecated. \
Use the driver parameter instead")
    $driver_real = $scheduler_driver
  } else {
    $driver_real = $driver
  }

  manila_config {
    'DEFAULT/scheduler_driver':       value => $driver_real;
    'DEFAULT/scheduler_host_manager': value => $host_manager;
    'DEFAULT/scheduler_max_attempts': value => $max_attempts;
  }

  if $::manila::params::scheduler_package {
    package { 'manila-scheduler':
      ensure => $package_ensure,
      name   => $::manila::params::scheduler_package,
      tag    => ['openstack', 'manila-package'],
    }
  }

  if $manage_service {
    if $enabled {
      $ensure = 'running'
    } else {
      $ensure = 'stopped'
    }

    service { 'manila-scheduler':
      ensure    => $ensure,
      name      => $::manila::params::scheduler_service,
      enable    => $enabled,
      hasstatus => true,
      tag       => 'manila-service',
    }
  }
}