Puppet Class: tripleo::profile::base::designate

Defined in:
manifests/profile/base/designate.pp

Overview

Copyright 2016 Red Hat, Inc.

Licensed under the Apache License, Version 2.0 (the “License”); you may not use this file except in compliance with the License. You may obtain a copy of the License at

http://www.apache.org/licenses/LICENSE-2.0

Unless required by applicable law or agreed to in writing, software distributed under the License is distributed on an “AS IS” BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the License for the specific language governing permissions and limitations under the License.

Class: tripleo::profile::base::designate

Designate server profile for tripleo

Parameters

step

(Optional) The current step of the deployment Defaults to hiera(‘step’)

oslomsg_rpc_proto

Protocol driver for the oslo messaging rpc service Defaults to hiera(‘oslo_messaging_rpc_scheme’, rabbit)

oslomsg_rpc_hosts

list of the oslo messaging rpc host fqdns Defaults to hiera(‘oslo_messaging_rpc_node_names’)

oslomsg_rpc_port

IP port for oslo messaging rpc service Defaults to hiera(‘oslo_messaging_rpc_port’, 5672)

oslomsg_rpc_username

Username for oslo messaging rpc service Defaults to hiera(‘oslo_messaging_rpc_user_name’, ‘guest’)

oslomsg_rpc_password

Password for oslo messaging rpc service Defaults to hiera(‘oslo_messaging_rpc_password’)

oslomsg_rpc_use_ssl

Enable ssl oslo messaging services Defaults to hiera(‘oslo_messaging_rpc_use_ssl’, ‘0’)

oslomsg_notify_proto

Protocol driver for the oslo messaging notify service Defaults to hiera(‘oslo_messaging_notify_scheme’, rabbit)

oslomsg_notify_hosts

list of the oslo messaging notify host fqdns Defaults to hiera(‘oslo_messaging_notify_node_names’)

oslomsg_notify_port

IP port for oslo messaging notify service Defaults to hiera(‘oslo_messaging_notify_port’, 5672)

oslomsg_notify_username

Username for oslo messaging notify service Defaults to hiera(‘oslo_messaging_notify_user_name’, ‘guest’)

oslomsg_notify_password

Password for oslo messaging notify service Defaults to hiera(‘oslo_messaging_notify_password’)

oslomsg_notify_use_ssl

Enable ssl oslo messaging services Defaults to hiera(‘oslo_messaging_notify_use_ssl’, ‘0’)

rndc_host

The address on which rndc should listen Defaults to undef

rndc_port

The port on which rndc should listen Defaults to 953

rndc_keys

A list of keys that rndc should accept Defaults to [‘rndc-key’]

rndc_allowed_addresses

A list of addresses that are allowed to send rndc commands Defaults to undef

Parameters:

  • step (Any) (defaults to: Integer(hiera('step')))
  • oslomsg_rpc_proto (Any) (defaults to: hiera('oslo_messaging_rpc_scheme', 'rabbit'))
  • oslomsg_rpc_hosts (Any) (defaults to: any2array(hiera('oslo_messaging_rpc_node_names', undef)))
  • oslomsg_rpc_password (Any) (defaults to: hiera('oslo_messaging_rpc_password'))
  • oslomsg_rpc_port (Any) (defaults to: hiera('oslo_messaging_rpc_port', '5672'))
  • oslomsg_rpc_username (Any) (defaults to: hiera('oslo_messaging_rpc_user_name', 'guest'))
  • oslomsg_rpc_use_ssl (Any) (defaults to: hiera('oslo_messaging_rpc_use_ssl', '0'))
  • oslomsg_notify_proto (Any) (defaults to: hiera('oslo_messaging_notify_scheme', 'rabbit'))
  • oslomsg_notify_hosts (Any) (defaults to: any2array(hiera('oslo_messaging_notify_node_names', undef)))
  • oslomsg_notify_password (Any) (defaults to: hiera('oslo_messaging_notify_password'))
  • oslomsg_notify_port (Any) (defaults to: hiera('oslo_messaging_notify_port', '5672'))
  • oslomsg_notify_username (Any) (defaults to: hiera('oslo_messaging_notify_user_name', 'guest'))
  • oslomsg_notify_use_ssl (Any) (defaults to: hiera('oslo_messaging_notify_use_ssl', '0'))
  • rndc_host (Any) (defaults to: undef)
  • rndc_port (Any) (defaults to: 953)
  • rndc_keys (Any) (defaults to: ['rndc-key'])
  • rndc_allowed_addresses (Any) (defaults to: undef) 


89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
 
# File 'manifests/profile/base/designate.pp', line 89

class tripleo::profile::base::designate (
  $step                    = Integer(hiera('step')),
  $oslomsg_rpc_proto       = hiera('oslo_messaging_rpc_scheme', 'rabbit'),
  $oslomsg_rpc_hosts       = any2array(hiera('oslo_messaging_rpc_node_names', undef)),
  $oslomsg_rpc_password    = hiera('oslo_messaging_rpc_password'),
  $oslomsg_rpc_port        = hiera('oslo_messaging_rpc_port', '5672'),
  $oslomsg_rpc_username    = hiera('oslo_messaging_rpc_user_name', 'guest'),
  $oslomsg_rpc_use_ssl     = hiera('oslo_messaging_rpc_use_ssl', '0'),
  $oslomsg_notify_proto    = hiera('oslo_messaging_notify_scheme', 'rabbit'),
  $oslomsg_notify_hosts    = any2array(hiera('oslo_messaging_notify_node_names', undef)),
  $oslomsg_notify_password = hiera('oslo_messaging_notify_password'),
  $oslomsg_notify_port     = hiera('oslo_messaging_notify_port', '5672'),
  $oslomsg_notify_username = hiera('oslo_messaging_notify_user_name', 'guest'),
  $oslomsg_notify_use_ssl  = hiera('oslo_messaging_notify_use_ssl', '0'),
  $rndc_host               = undef,
  $rndc_port               = 953,
  $rndc_keys               = ['rndc-key'],
  $rndc_allowed_addresses  = undef,
) {
  if $step >= 3 {
    $oslomsg_rpc_use_ssl_real = sprintf('%s', bool2num(str2bool($oslomsg_rpc_use_ssl)))
    $oslomsg_notify_use_ssl_real = sprintf('%s', bool2num(str2bool($oslomsg_notify_use_ssl)))
    class { 'designate' :
      default_transport_url      => os_transport_url({
        'transport' => $oslomsg_rpc_proto,
        'hosts'     => $oslomsg_rpc_hosts,
        'port'      => $oslomsg_rpc_port,
        'username'  => $oslomsg_rpc_username,
        'password'  => $oslomsg_rpc_password,
        'ssl'       => $oslomsg_rpc_use_ssl_real,
      }),
      notification_transport_url => os_transport_url({
        'transport' => $oslomsg_notify_proto,
        'hosts'     => $oslomsg_notify_hosts,
        'port'      => $oslomsg_notify_port,
        'username'  => $oslomsg_notify_username,
        'password'  => $oslomsg_notify_password,
        'ssl'       => $oslomsg_notify_use_ssl_real,
      }),
    }
    if ($rndc_host and $rndc_allowed_addresses) {
      class { 'designate::backend::bind9':
        rndc_controls => {
          $rndc_host => {
            'port'              => $rndc_port,
            'keys'              => $rndc_keys,
            'allowed_addresses' => $rndc_allowed_addresses,
          }
        },
      }
    } else {
      include designate::backend::bind9
    }
    include designate::config
    include designate::logging
  }
}