Puppet Class: tripleo::profile::base::neutron
- Defined in:
- manifests/profile/base/neutron.pp
Overview
Copyright 2016 Red Hat, Inc.
Licensed under the Apache License, Version 2.0 (the “License”); you may not use this file except in compliance with the License. You may obtain a copy of the License at
http://www.apache.org/licenses/LICENSE-2.0
Unless required by applicable law or agreed to in writing, software distributed under the License is distributed on an “AS IS” BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the License for the specific language governing permissions and limitations under the License.
Class: tripleo::profile::base::neutron
Neutron server profile for tripleo
Parameters
- step
-
(Optional) The current step of the deployment Defaults to Integer(lookup(‘step’))
- oslomsg_rpc_proto
-
Protocol driver for the oslo messaging rpc service Defaults to lookup(‘oslo_messaging_rpc_scheme’, undef, undef, ‘rabbit’)
- oslomsg_rpc_hosts
-
list of the oslo messaging rpc host fqdns Defaults to any2array(lookup(‘oslo_messaging_rpc_node_names’, undef, undef, undef))
- oslomsg_rpc_port
-
IP port for oslo messaging rpc service Defaults to lookup(‘oslo_messaging_rpc_port’, undef, undef, ‘5672’)
- oslomsg_rpc_username
-
Username for oslo messaging rpc service Defaults to lookup(‘oslo_messaging_rpc_user_name’, undef, undef, ‘guest’)
- oslomsg_rpc_password
-
Password for oslo messaging rpc service Defaults to lookup(‘oslo_messaging_rpc_password’)
- oslomsg_rpc_use_ssl
-
Enable ssl oslo messaging services Defaults to lookup(‘oslo_messaging_rpc_use_ssl’, undef, undef, ‘0’)
- oslomsg_notify_proto
-
Protocol driver for the oslo messaging notify service Defaults to lookup(‘oslo_messaging_notify_scheme’, undef, undef, ‘rabbit’)
- oslomsg_notify_hosts
-
list of the oslo messaging notify host fqdns Defaults to any2array(lookup(‘oslo_messaging_notify_node_names’, undef, undef, undef))
- oslomsg_notify_port
-
IP port for oslo messaging notify service Defaults to lookup(‘oslo_messaging_notify_port’, undef, undef, ‘5672’)
- oslomsg_notify_username
-
Username for oslo messaging notify service Defaults to lookup(‘oslo_messaging_notify_user_name’, undef, undef, ‘guest’)
- oslomsg_notify_password
-
Password for oslo messaging notify service Defaults to lookup(‘oslo_messaging_notify_password’)
- oslomsg_notify_use_ssl
-
Enable ssl oslo messaging services Defaults to lookup(‘oslo_messaging_notify_use_ssl’, undef, undef, ‘0’)
- dhcp_agents_per_network
-
(Optional) TripleO configured number of DHCP agents to use per network. If left to the default value, neutron will be configured with the number of DHCP agents being deployed. Defaults to undef
- dhcp_nodes
-
(Optional) List of nodes running the DHCP agent. Used to set neutron’s dhcp_agents_per_network value to the number of available agents. Defaults to lookup(‘neutron_dhcp_short_node_names’) or []
- container_cli
-
(Optional) A container CLI to be used with the wrapper tooling to manage containers controlled by Neutron/OVN l3/dhcp/metadata agents. Accepts only ‘podman’ Defaults to lookup(‘container_cli’, undef, undef, ‘podman’).
91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 |
# File 'manifests/profile/base/neutron.pp', line 91
class tripleo::profile::base::neutron (
$step = Integer(lookup('step')),
$oslomsg_rpc_proto = lookup('oslo_messaging_rpc_scheme', undef, undef, 'rabbit'),
$oslomsg_rpc_hosts = any2array(lookup('oslo_messaging_rpc_node_names', undef, undef, undef)),
$oslomsg_rpc_password = lookup('oslo_messaging_rpc_password'),
$oslomsg_rpc_port = lookup('oslo_messaging_rpc_port', undef, undef, '5672'),
$oslomsg_rpc_username = lookup('oslo_messaging_rpc_user_name', undef, undef, 'guest'),
$oslomsg_rpc_use_ssl = lookup('oslo_messaging_rpc_use_ssl', undef, undef, '0'),
$oslomsg_notify_proto = lookup('oslo_messaging_notify_scheme', undef, undef, 'rabbit'),
$oslomsg_notify_hosts = any2array(lookup('oslo_messaging_notify_node_names', undef, undef, undef)),
$oslomsg_notify_password = lookup('oslo_messaging_notify_password'),
$oslomsg_notify_port = lookup('oslo_messaging_notify_port', undef, undef, '5672'),
$oslomsg_notify_username = lookup('oslo_messaging_notify_user_name', undef, undef, 'guest'),
$oslomsg_notify_use_ssl = lookup('oslo_messaging_notify_use_ssl', undef, undef, '0'),
$dhcp_agents_per_network = undef,
$dhcp_nodes = lookup('neutron_dhcp_short_node_names', undef, undef, []),
$container_cli = lookup('container_cli', undef, undef, 'podman'),
) {
if $step >= 3 {
# NOTE(bogdando) validate_* is deprecated and we do not want to use it here
if !($container_cli in ['podman']) {
fail("container_cli (${container_cli}) is not supported!")
}
$oslomsg_rpc_use_ssl_real = sprintf('%s', bool2num(str2bool($oslomsg_rpc_use_ssl)))
$oslomsg_notify_use_ssl_real = sprintf('%s', bool2num(str2bool($oslomsg_notify_use_ssl)))
$dhcp_agent_count = size($dhcp_nodes)
if $dhcp_agents_per_network {
$dhcp_agents_per_net = $dhcp_agents_per_network
if ($dhcp_agents_per_net > $dhcp_agent_count) {
warning("dhcp_agents_per_network (${dhcp_agents_per_net}) is greater\
than the number of deployed dhcp agents (${dhcp_agent_count})")
}
}
elsif $dhcp_agent_count > 0 {
$dhcp_agents_per_net = $dhcp_agent_count
}
if lookup('nova_is_additional_cell', undef, undef, undef) {
$oslomsg_rpc_hosts_real = delete($oslomsg_rpc_hosts, any2array(lookup('oslo_messaging_rpc_cell_node_names', undef, undef, undef)))
} else {
$oslomsg_rpc_hosts_real = $oslomsg_rpc_hosts
}
class { 'neutron' :
default_transport_url => os_transport_url({
'transport' => $oslomsg_rpc_proto,
'hosts' => $oslomsg_rpc_hosts_real,
'port' => $oslomsg_rpc_port,
'username' => $oslomsg_rpc_username,
'password' => $oslomsg_rpc_password,
'ssl' => $oslomsg_rpc_use_ssl_real,
}),
notification_transport_url => os_transport_url({
'transport' => $oslomsg_notify_proto,
'hosts' => $oslomsg_notify_hosts,
'port' => $oslomsg_notify_port,
'username' => $oslomsg_notify_username,
'password' => $oslomsg_notify_password,
'ssl' => $oslomsg_notify_use_ssl_real,
}),
dhcp_agents_per_network => $dhcp_agents_per_net,
}
include neutron::config
include neutron::logging
}
}
|