Puppet Class: graphdb

Defined in:
manifests/init.pp

Summary

# This class is able to install or remove graphdb distribution on a node. It manages the status of the related service.

Overview

Parameters:

  • archive_dl_timeout (Integer) (defaults to: 600) —

    For http downloads you can set how long the exec resource may take. default: 600 seconds

  • data_dir (Stdlib::Absolutepath) (defaults to: '/var/lib/graphdb') —

    String. GraphDB data directory

  • edition (Optional[String]) (defaults to: undef) —

    String. GraphDB edition to install

  • ensure (Graphdb::Ensure) (defaults to: 'present') —

    String. Controls if the managed resources shall be present or absent. If set to absent:

    • The managed distribution is being uninstalled.

    • Any traces of installation will be purged as good as possible. This may include existing configuration files. The exact behavior is provider dependent. Q.v.:

    • System modifications (if any) will be reverted as good as possible (e.g. removal of created users, services, changed log settings, …).

    • This is thus destructive and should be used with care.

    Defaults to present.

  • graphdb_download_password (Optional[String]) (defaults to: undef) —

    For http downloads you can set password(basic auth credentials)

  • graphdb_download_user (Optional[String]) (defaults to: undef) —

    For http downloads you can set user(basic auth credentials)

  • graphdb_download_url (String) (defaults to: 'http://maven.ontotext.com/content/groups/all-onto/com/ontotext/graphdb') —

    Url to the archive to download. This can be a http or https resource for remote packages puppet:// resource or file:/ for local packages

  • graphdb_group (String[1,32]) (defaults to: 'graphdb') —

    String. The group GraphDB should run as. This also sets the file rights

  • graphdb_user (String[1,32]) (defaults to: 'graphdb') —

    String. The group GraphDB should run as. This also sets the file rights

  • import_dir (Stdlib::Absolutepath) (defaults to: "${install_dir}/import") —

    String. GraphDB import location

  • install_dir (Stdlib::Absolutepath) (defaults to: '/opt/graphdb') —

    String. GraphDB distribution location

  • java_home (Optional[Stdlib::Absolutepath]) (defaults to: undef) —

    String. The location of java installation

  • log_dir (Stdlib::Absolutepath) (defaults to: '/var/log/graphdb') —

    String. GraphDB log directory

  • manage_graphdb_user (Boolean) (defaults to: true) —

    Boolean. Whether this module manages GraphDB user

  • pid_dir (Stdlib::Absolutepath) (defaults to: '/var/run/graphdb') —

    String. GraphDB pid directory

  • purge_data_dir (Boolean) (defaults to: false) —

    Boolean. Purge data directory on removal

  • restart_on_change (Boolean) (defaults to: true) —

    Boolean that determines if the application should be automatically restarted whenever the configuration change. Enabling this setting will cause GraphDB to restart whenever there is cause to re-read configuration files, load new plugins, or start the service using an updated/changed executable. This may be undesireable in highly available environments.

  • status (Graphdb::Status) (defaults to: 'enabled') —

    String to define the status of the service. Possible values:

    • enabled: Service is running and will be started at boot time.

    • disabled: Service is stopped and will not be started at boot time.

    • running: Service is running but will not be started at boot time. You can use this to start a service on the first Puppet run instead of the system startup.

    • unmanaged: Service will not be started at boot time and Puppet does not care whether the service is running or not. For example, this may be useful if a cluster management software is used to decide when to start the service plus assuring it is running on the desired node.

    Defaults to enabled. The singular form (“service”) is used for the sake of convenience. Of course, the defined status affects all services if more than one is managed (see service.pp to check if this is the case).

  • tmp_dir (Stdlib::Absolutepath) (defaults to: '/var/tmp/graphdb') —

    String. The location of temporary files that this module will use

  • version (String) (defaults to: undef) —

    String. GraphDB version to install



97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
 
# File 'manifests/init.pp', line 97

class graphdb (
  Integer $archive_dl_timeout                 = 600,
  Stdlib::Absolutepath $data_dir              = '/var/lib/graphdb',
  Optional[String] $edition                   = undef,
  Graphdb::Ensure $ensure                     = 'present',
  Optional[String] $graphdb_download_password = undef,
  Optional[String] $graphdb_download_user     = undef,
  String $graphdb_download_url                = 'http://maven.ontotext.com/content/groups/all-onto/com/ontotext/graphdb',
  String[1,32] $graphdb_group                 = 'graphdb',
  String[1,32] $graphdb_user                  = 'graphdb',
  Stdlib::Absolutepath $install_dir           = '/opt/graphdb',
  Stdlib::Absolutepath $import_dir            = "${install_dir}/import",
  Optional[Stdlib::Absolutepath] $java_home   = undef,
  Stdlib::Absolutepath $log_dir               = '/var/log/graphdb',
  Boolean $manage_graphdb_user                = true,
  Stdlib::Absolutepath $pid_dir               = '/var/run/graphdb',
  Boolean $purge_data_dir                     = false,
  Boolean $restart_on_change                  = true,
  Graphdb::Status $status                     = 'enabled',
  Stdlib::Absolutepath $tmp_dir               = '/var/tmp/graphdb',
  String $version                             = undef,
) {
  #### Validate parameters

  if ($ensure == 'present') {
    if (!$version) {
      fail('"ensure" is set on present, you should provide "version"')
    }

    # version
    if versioncmp($version, '7.0.0') < 0 {
      fail('This module support GraphDB version 7.0.0 and up')
    }

    if versioncmp($version, '10') < 0 {
      if !($edition in ['se', 'ee']) {
        fail("\"${edition}\" is not a valid edition parameter value")
      }
    }

    # kernel
    $kernel = $facts['kernel']
    if !($kernel in ['Linux']) {
      fail("\"${module_name}\" provides no support for kernel \"${kernel}\"")
    }

    # os
    $operatingsystem = $facts['os']['name']
    $operatingsystemmajrelease = $facts['os']['release']['major']
    #$operatingsystem = $facts['operatingsystem'] # lint:ignore:legacy_facts
    #$operatingsystemmajrelease = $facts['operatingsystemmajrelease'] # lint:ignore:legacy_facts

    if !($operatingsystem in ['RedHat', 'CentOS', 'Debian', 'Ubuntu'])
    or  ($operatingsystem in ['RedHat', 'CentOS'] and versioncmp($operatingsystemmajrelease, '7') < 0)
    or ($operatingsystem in ['Debian'] and versioncmp($operatingsystemmajrelease, '8') < 0)
    or ($operatingsystem in ['Ubuntu'] and versioncmp($operatingsystemmajrelease, '15') < 0) {
      fail("\"${module_name}\" provides no support for \"${operatingsystem}\" \"${operatingsystemmajrelease}\"")
    }

    #basic auth credentials validation
    if ($graphdb_download_user and !$graphdb_download_password) or (!$graphdb_download_user and $graphdb_download_password) {
      fail('When using basic auth credentials you should provide both graphdb_download_user and graphdb_download_password')
    }

    if $java_home {
      $java_location = $java_home
    }
    elsif $facts['graphdb_java_home'] {
      $java_location = $facts['graphdb_java_home']
    }
    else {
      $java_location = '/usr/lib/jvm/java-8-openjdk-amd64'
    }
  }

  include graphdb::install
  include graphdb::tool_links

  #### Relationships

  if $ensure == 'present' {
    Class['graphdb::install']
    -> Class['graphdb::tool_links']
    -> Graphdb::Instance <| |>
  } else {
    Graphdb::Instance <| |> -> Class['graphdb::install']
  }
}